userlist.asp

很好的一个论坛原代码

<!--#INCLUDE FILE="inc/db_inc.asp"-->
<!--#INCLUDE FILE="inc/char_inc.asp"-->
<!--#INCLUDE FILE="header.asp"-->
<%
dim ip, strip, killip
dim StrSql, toptext, rs, rs2, StrHtml, error

StrHtml = loadtemplate("htmltop")
StrHtml = Replace(StrHtml, "{pagetitle}", loadtemplate("userlisttitle"))
StrHtml = Replace(StrHtml, "{forumtitle}", boardtitle)
response.write StrHtml
StrHtml = loadtemplate("pagetitle")
if request.cookies("sf")("username") = "" then
	toptext = loadtemplate("toptextguest")
else
	toptext = loadtemplate("toptextuser")
end if
toptext = toptext & loadtemplate("toptext")
StrHtml = Replace(StrHtml, "{top_text}", toptext)
StrHtml = Replace(StrHtml, "{username}", request.cookies("sf")("username"))
response.write StrHtml

' 论坛关闭
StrSql = "select * from sf_setup"
Set rs2 = Conn.Execute(StrSql)
if rs2("forumclose") = 1 then
StrHtml = loadtemplate("error")
StrHtml = Replace(StrHtml, "{error_text}", rs2("forumclosehint"))
response.write StrHtml
response.end
end if	

' 禁止IP访问
if rs2("killip") = 1 then
	userip = cstr(request.ServerVariables("REMOTE_ADDR"))
	killiplist = rs2("killiplist")
	if killiplist <> "" and userip <> "" then
		killip = split(killiplist, "|")
		struserip = split(userip, ".")
		i = 0
		do until i > ubound(killip)
			strkillip = split(killip(i), ".")
			bolkill = true
			if (struserip(0) <> strkillip(0)) and (strkillip(0) <> "*") then bolkill = false
			if (struserip(1) <> strkillip(1)) and (strkillip(1) <> "*") then bolkill = false
			if (struserip(2) <> strkillip(2)) and (strkillip(2) <> "*") then bolkill = false
			if (struserip(3) <> strkillip(3)) and (strkillip(3) <> "*") then bolkill = false
			if bolkill then
				StrHtml = loadtemplate("error")
				StrHtml = Replace(StrHtml, "{error_text}", rs2("killiphint"))
				response.write StrHtml
				Response.End
			end if
			i = i + 1
		loop
	end if
end if

StrHtml = loadtemplate("pagepath")
StrHtml = Replace(StrHtml, "{path_text}", "<a href=""index.asp"">" & boardtitle & "</a> &raquo; " & loadtemplate("userlisttitle"))
response.write StrHtml

page = request("page")
' 获得当前页数
if page = "" then
	page = 1
else
	if not IsNumeric(page) then
		page = 1
	else
		page = clng(page)
	end if
end if
mode = "posts"
if request("mode") = "posts" then
	mode = "posts"
end if
if request("mode") = "rating" then
	mode = "rating"
end if
if request("mode") = "regdate" then
	mode = "regdate"
end if

i = 1
pagecount = 1
response.write loadtemplate("userlisttop")
StrHtml = loadtemplate("userlist")
strsql = "select userid, username, posts, rating, country, joindate, lastposttitle, lastpostid, lastposttime from sf_user"
if mode = "regdate" then strsql = strsql & " order by userid DESC"
if mode = "posts" then strsql = strsql & " order by posts DESC"
if mode = "rating" then strsql = strsql & " order by rating DESC"
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open strsql, Conn, 1, 1
if not (rs.bof or rs.eof) then
	' 分页处理
	rs.PageSize = forumrow
	if page > rs.PageCount then page = rs.PageCount
	rs.AbsolutePage = page
	pagecount = rs.PageCount
	do until rs.eof or i > rs.PageSize
	StrHtml2 = StrHtml
	StrHtml2 = Replace(StrHtml2, "{user_id}", rs("userid"))
	StrHtml2 = Replace(StrHtml2, "{user_name}", server.htmlencode(rs("username")))
	StrHtml2 = Replace(StrHtml2, "{user_posts}", rs("posts"))
	StrHtml2 = Replace(StrHtml2, "{user_rating}", rs("rating"))
	StrHtml2 = Replace(StrHtml2, "{user_country}", rs("country"))
	StrHtml2 = Replace(StrHtml2, "{user_joindate}", rs("joindate"))
	StrHtml2 = Replace(StrHtml2, "{user_lastposttitle}", rs("lastposttitle"))
	StrHtml2 = Replace(StrHtml2, "{user_lastpostid}", rs("lastpostid"))
	StrHtml2 = Replace(StrHtml2, "{user_lastposttime}", rs("lastposttime"))
    response.write StrHtml2
	rs.MoveNext
i = i + 1
loop
end if

StrHtml = loadtemplate("userlistbottom")
urlstr = ""
if request("mode") <> "" then urlstr = urlstr & "&mode=" & request("mode")
StrHtml2 = ""
beginpage = 1
endpage = pagecount
if pagecount >= 9 then
	if page >= 5 then
		beginpage = page - 4
		if page <= (pagecount - 4) then
			endpage = page + 4
		else
			endpage = pagecount
			beginpage = pagecount - 4
		end if
	else
		beginpage = 1
		endpage = 9
	end if
end if
		StrHtml2 = StrHtml2 & "&nbsp;<a href=""userlist.asp?page=1"& urlstr &""">&lt;&lt;</a>"
for i=beginpage to endpage
	if i = page then
		StrHtml2 = StrHtml2 & "&nbsp;<b>[" & i & "]</b>&nbsp;"
	else
		StrHtml2 = StrHtml2 & "<a href=""userlist.asp?page=" & i & urlstr &""">&nbsp;[" & i & "]&nbsp;</a>"
	end if
next
		StrHtml2 = StrHtml2 & "...&nbsp;<a href=""userlist.asp?page=" & pagecount & urlstr &"""> ["&pagecount&"] &gt;&gt;</a>"
StrHtml = Replace(StrHtml, "{page_text}", StrHtml2)
response.write StrHtml		
response.write sfcopyright
response.write loadtemplate("htmlbottom")
Conn.Close
Set Conn = nothing
Set rs = nothing
Set rs2 = nothing
set ip = nothing
set strip = nothing
set killip = nothing
%>