showannouncement.asp

很好的一个论坛原代码

<!--#INCLUDE FILE="inc/db_inc.asp"-->
<!--#INCLUDE FILE="inc/char_inc.asp"-->
<!--#INCLUDE FILE="inc/xbcode_inc.asp"-->
<!--#INCLUDE FILE="header.asp"-->
<!--#INCLUDE FILE="user.asp"-->
<%
dim ip, strip, killip
dim StrSql, rs2, toptext, StrHtml, StrHtml2, StrHtml3, err, pagecount

error = ""
threadtitle = ""

StrHtml = loadtemplate("htmltop")
StrHtml = Replace(StrHtml, "{pagetitle}", loadtemplate("announcementtitle"))
StrHtml = Replace(StrHtml, "{forumtitle}", boardtitle)
response.write StrHtml
' 短消息提示
response.write pmpopwin
StrHtml = loadtemplate("pagetitle")
if request.cookies("sf")("username") = "" then
	toptext = loadtemplate("toptextguest")
else
	toptext = loadtemplate("toptextuser")
end if
toptext = toptext & loadtemplate("toptext")
StrHtml = Replace(StrHtml, "{top_text}", toptext)
StrHtml = Replace(StrHtml, "{username}", request.cookies("sf")("username"))
response.write StrHtml

' 论坛关闭
StrSql = "select * from sf_setup"
Set rs2 = Conn.Execute(StrSql)
if rs2("forumclose") = 1 then
StrHtml = loadtemplate("error")
StrHtml = Replace(StrHtml, "{error_text}", rs2("forumclosehint"))
response.write StrHtml
response.end
end if	

' 禁止IP访问
if rs2("killip") = 1 then
	userip = cstr(request.ServerVariables("REMOTE_ADDR"))
	killiplist = rs2("killiplist")
	if killiplist <> "" and userip <> "" then
		killip = split(killiplist, "|")
		struserip = split(userip, ".")
		i = 0
		do until i > ubound(killip)
			strkillip = split(killip(i), ".")
			bolkill = true
			if (struserip(0) <> strkillip(0)) and (strkillip(0) <> "*") then bolkill = false
			if (struserip(1) <> strkillip(1)) and (strkillip(1) <> "*") then bolkill = false
			if (struserip(2) <> strkillip(2)) and (strkillip(2) <> "*") then bolkill = false
			if (struserip(3) <> strkillip(3)) and (strkillip(3) <> "*") then bolkill = false
			if bolkill then
				StrHtml = loadtemplate("error")
				StrHtml = Replace(StrHtml, "{error_text}", rs2("killiphint"))
				response.write StrHtml
				Response.End
			end if
			i = i + 1
		loop
	end if
end if

' 如果有错误则提示
if error <> "" then
	StrHtml = loadtemplate("error")
	StrHtml = Replace(StrHtml, "{error_text}", error)
	response.write StrHtml
	response.end
end if

' 显示当前页面路径
StrHtml = loadtemplate("pagepath")
StrHtml = Replace(StrHtml, "{path_text}", "<a href=""index.asp"">" & boardtitle & "</a> &raquo; " & loadtemplate("announcementtitle"))
response.write StrHtml


page = request("page")

' 获得当前页数
if page = "" then
	page = 1
else
	if not IsNumeric(page) then
		page = 1
	else
		page = clng(page)
	end if
end if

' 显示帖子列表
pagecount = 1
response.write loadtemplate("announcementtop")
StrHtml = loadtemplate("announcement")
StrSql = "select sf_announcement.*, sf_user.* from sf_announcement left join sf_user on (sf_announcement.userid = sf_user.userid) order by announcementid DESC"
Set rs2 = server.CreateObject("ADODB.RecordSet")
rs2.Open StrSql, Conn, 1, 1
if not (rs2.bof or rs2.eof) then
	' 分页处理
	i = 1
	rs2.PageSize = postrow
	if page > rs2.PageCount then page = rs2.PageCount
	rs2.AbsolutePage = page
	pagecount = rs2.PageCount
	do until rs2.eof or i > rs2.PageSize
		StrHtml2 = StrHtml
		StrHtml2 = Replace(StrHtml2, "{announcement_id}", rs2("announcementid"))
		StrHtml2 = Replace(StrHtml2, "{title}", rs2("title"))
		StrHtml2 = Replace(StrHtml2, "{startdate}", rs2("startdate"))
		StrHtml2 = Replace(StrHtml2, "{enddate}", rs2("enddate"))
		posttext = xbcodeContent(formatstr(rs2("pagetext")), true, true, true, true)
		StrHtml2 = Replace(StrHtml2, "{text}", "<br><br>" & posttext & "<br><br>")
		StrHtml2 = Replace(StrHtml2, "{user_name}", rs2("username"))
		if rs2("usertitle") = "" then
			        StrHtml2 = Replace(StrHtml2, "{user_title}", GetTitle(rs2("posts")))
		else
			        StrHtml2 = Replace(StrHtml2, "{user_title}", rs2("usertitle"))
		end if
		select case rs2("usergroup")
			case 4
				StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/10.gif"">")
			case 3
				StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/9.gif"">")
			case 2
				StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/8.gif"">")
			case 1
				StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/8.gif"">")
			case else
			        StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/" & GetTitleImg(rs2("posts")) & ".gif"">")
		end select
		if rs2("avatar") = "" then
			StrHtml2 = Replace(StrHtml2, "{user_avatar}", "<img src=""" & rs2("defineavatar") & """ width=""" & rs2("avatarwidth") & """ height=""" & rs2("avatarheight") & """>")
		else
			StrHtml2 = Replace(StrHtml2, "{user_avatar}", "<img src=""image/avatar/" & rs2("avatar") & """>")
		end if
		response.write StrHtml2
		rs2.MoveNext
		i = i + 1
	loop
end if

StrHtml = loadtemplate("announcementbottom")

StrHtml2 = ""

beginpage = 1
endpage = pagecount
if pagecount >= 9 then
  if page >= 5 then
    beginpage = page - 4
    if page <= (pagecount - 4) then
      endpage = page + 4
    else
      endpage = pagecount
      beginpage = pagecount - 4
    end if
  else
    beginpage=1
    endpage=9
  end if
end if
		StrHtml2 = StrHtml2 & "&nbsp;<a href=""showannouncement.asp?page=1"">&lt;&lt;</a>"
for i=beginpage to endpage
	if i = page then
		StrHtml2 = StrHtml2 & "&nbsp;<b>[" & i & "]</b>&nbsp;"
	else
		StrHtml2 = StrHtml2 & "<a href=""showannouncement.asp?page=" & i & """>&nbsp;[" & i & "]&nbsp;</a>"
	end if
next
		StrHtml2 = StrHtml2 & "...&nbsp;<a href=""showannouncement.asp?page=" & pagecount & """> ["&pagecount&"] &gt;&gt;</a>"
StrHtml = Replace(StrHtml, "{page_text}", StrHtml2)
response.write StrHtml
response.write sfcopyright
response.write loadtemplate("htmlbottom")
Conn.Close
Set Conn = nothing
Set rs = nothing
Set rs2 = nothing
set ip = nothing
set strip = nothing
set killip = nothing
%>