regmod.bas

一个功能强大、程序条理分明的学生学籍管理系统

Attribute VB_Name = "RegMod"
Option Explicit
'用于操作注册表的常数定义   -begin-
'预定义的根结点
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_CONFIG = &H80000005
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_DYN_DATA = &H80000006
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_PERFORMANCE_DATA = &H80000004
Public Const HKEY_USERS = &H80000003
'预定义的键值类型
Public Const REG_NONE = 0
Public Const REG_SZ = 1
Public Const REG_EXPAND_SZ = 2
Public Const REG_BINARY = 3
Public Const REG_DWORD = 4
Public Const REG_DWORD_LITTLE_ENDIAN = 4
Public Const REG_DWORD_BIG_ENDIAN = 5
Public Const REG_LINK = 6
Public Const REG_MULTI_SZ = 7
Public Const REG_RESOURCE_LIST = 8
Public Const REG_FULL_RESOURCE_DESCRIPTOR = 9
Public Const REG_RESOURCE_REQUIREMENTS_LIST = 10

'定义读写方式
Const STANDARD_RIGHTS_ALL = &H1F0000
Const SPECIFIC_RIGHTS_ALL = &HFFFF
Const SYNCHRONIZE = &H100000
Const READ_CONTROL = &H20000
Const STANDARD_RIGHTS_READ = (READ_CONTROL)
Const STANDARD_RIGHTS_WRITE = (READ_CONTROL)

Const KEY_QUERY_VALUE = &H1
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_READ = ((READ_CONTROL Or KEY_QUERY_VALUE Or KEY_ENUMERATE_SUB_KEYS Or KEY_NOTIFY) And (Not SYNCHRONIZE))
Const KEY_WRITE = ((STANDARD_RIGHTS_WRITE Or KEY_SET_VALUE Or KEY_CREATE_SUB_KEY) And (Not SYNCHRONIZE))

Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Private Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Private Declare Function RegCreateKeyEx Lib "advapi32.dll" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As Long, ByVal dwOptions As Long, ByVal samDesired As Long, ByVal lpSecurityAttributes As Long, phkResult As Long, lpdwDisposition As Long) As Long
Private Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String) As Long
Private Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long
Private Declare Function RegEnumKey Lib "advapi32.dll" Alias "RegEnumKeyA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, ByVal cbName As Long) As Long
Private Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) As Long
Private Declare Function RegEnumValue Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (dest As Any, source As Any, ByVal numBytes As Long)
Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
      
Private Declare Function RegQueryInfoKey Lib "advapi32.dll" Alias "RegQueryInfoKeyA" _
    (ByVal hKey As Long, ByVal lpClass As String, _
    lpcbClass As Long, ByVal lpReserved As Long, lpcSubKeys As Long, _
    lpcbMaxSubKeyLen As Long, lpcbMaxClassLen As Long, lpcValues As Long, _
    lpcbMaxValueNameLen As Long, lpcbMaxValueLen As Long, lpcbSecurityDescriptor As Long, _
    lpftLastWriteTime As Any) As Long

'注册文件错误描述
Const ERROR_SUCCESS = 0&
Const ERROR_BADDB = 1009&
Const ERROR_BADKEY = 1010&
Const ERROR_CANTOPEN = 1011&
Const ERROR_CANTREAD = 1012&
Const ERROR_CANTWRITE = 1013&
Const ERROR_REGISTRY_RECOVERED = 1014&
Const ERROR_REGISTRY_CORRUPT = 1015&
Const ERROR_REGISTRY_IO_FAILED = 1016&
Const ERROR_NOT_REGISTRY_FILE = 1017&
Const ERROR_KEY_DELETED = 1018&
Const ERROR_NO_LOG_SPACE = 1019&
Const ERROR_KEY_HAS_CHILDREN = 1020&
Const ERROR_CHILD_MUST_BE_VOLATILE = 1021&
Const ERROR_RXACT_INVALID_STATE = 1369&
' 自定义注册文件错误
Const REGAGENT_NOKEY = -1002
Const REGAGENT_NOSUBKEY = -1003


Public Const REG_CREATED_NEW_KEY = &H1
Public Const REG_OPENED_EXISTING_KEY = &H2

Public glStatus    As Long

'************************************************************************
'功能：判断键是否存在
'输入：
'   plKey                   Long        根键名
'   psKey                   String      主键名
'输出:  lStatus           Long        状态值
'影响:  glStatus:       Long        状态值（该变量是全局变量）
'************************************************************************
Function CheckKey(ByVal plKey As Long, ByVal psKey As String) As Long
    Dim hKey         As Long         '打开键的ID
    
    glStatus = ERROR_SUCCESS            '假设成功
    
    '确定参数有效
    If Len(psKey) = 0 Then      '主键未设置（子键未设置则读默认值）
        glStatus = REGAGENT_NOKEY
        Exit Function
    End If
    
    glStatus = RegOpenKeyEx(plKey, psKey, 0, KEY_READ, hKey)
    
    CheckKey = glStatus
    
    glStatus = RegCloseKey(hKey)
End Function

'*******************************************************************
'功能： 创建注册表中的主键
'输入:
'   plKey:  Long        根键名
'   psKey:  String      主键名
'输出:  gflCreateKey:   Long        创建的主键ID
'影响:  glStatus:       Long        状态值（该变量是全局变量）
'*******************************************************************

Function CreateKey(ByVal plKey As Long, ByVal psKey As String) As Long

    Dim hKey     As Long     '键ID
    
    glStatus = ERROR_SUCCESS       '假设成功
    
    '确定参数有效
    If Len(psKey) = 0 Then      '主键未设置
        glStatus = REGAGENT_NOKEY
        Exit Function
    End If
        
    '创建主键
    glStatus = RegCreateKey(plKey, psKey, hKey)
    If glStatus = ERROR_SUCCESS Then
        CreateKey = hKey
    End If
    
End Function

'*****************************************************************
'功能：删除注册表中的主键
'输入:
'   plKey       Long        根键名
'   psKey       String      主键名
'   psSubKey    String      子键名
'输出:    无
'影响:    glStatus                Long        状态值
'*****************************************************************
Sub DeleteKey(ByVal plKey As Long, ByVal psKey As String, ByVal psSubKey As String)
    Dim hKey     As Long     '键ID
    
    glStatus = ERROR_SUCCESS        '假设成功
    
    '确定参数有效
    If Len(psKey) = 0 Then      '主键未设置
        glStatus = REGAGENT_NOKEY
        Exit Sub
    End If
        
    '利用创建主键判断是否存在主键
    glStatus = RegCreateKey(plKey, psKey, hKey)
    glStatus = RegDeleteKey(hKey, ByVal psSubKey)
        
End Sub

'**************************************************************
'功能：删除注册表中的键值
'输入:
'   plKey       Long        根键名
'   psKey       String      主键名
'   psSubKey        String      子键名
'输出:    无
'影响:    glStatus                Long        状态值
'*****************************************************************
Sub DeleteKeyValue(ByVal plKey As Long, ByVal psKey As String, _
    ByVal psSubKey As String)
    Dim hKey     As Long     '键ID
    
    glStatus = ERROR_SUCCESS        '假设成功
    
    '确定参数有效
    If Len(psKey) = 0 Then      '主键未设置
        glStatus = REGAGENT_NOKEY
        Exit Sub
    End If
        
    '利用创建主键判断是否存在主键
    glStatus = RegCreateKey(plKey, psKey, hKey)
    glStatus = RegDeleteValue(hKey, ByVal psSubKey)
        
End Sub

'*****************************************************************
'功能：从注册表中取得键值
'输入：
'   plKey                   Long        根键名
'   psKey                   String      主键名
'   ValueName                String      子键名
'   输出:    GetValue                String      取得的注册表键值
'说明： 仅仅支持 DWORD, SZ, 和 BINARY value 这三种类型.
'******************************************************************
Function GetValue(ByVal plKey As Long, ByVal psKey As String, _
    ByVal ValueName As String, ByVal KeyType As Integer, _
    Optional DefaultValue As Variant = Empty) As Variant
    
    Dim hKey As Long, resLong As Long
    Dim resString As String, length As Long
    Dim resBinary() As Byte
    
    '先赋值为默认值.
    GetValue = DefaultValue
    '打开键，如果没有找到则退出
    If RegOpenKeyEx(plKey, psKey, 0, KEY_READ, hKey) Then Exit Function
    
    Select Case KeyType
        Case REG_DWORD
            '读出键值，如果没有找到则用默认值
            If RegQueryValueEx(hKey, ValueName, 0, REG_DWORD, _
                resLong, 4) = 0 Then
                GetValue = resLong
            End If
        Case REG_SZ
            length = 1024: resString = Space$(length)
            If RegQueryValueEx(hKey, ValueName, 0, REG_SZ, _
                ByVal resString, length) = 0 Then
                ' 如果找到了值，去掉字符串尾部的字符串结尾标志符Chr（0）
                GetValue = Left$(resString, length - 1)
            End If
        Case REG_BINARY
            length = 4096
            ReDim resBinary(length - 1) As Byte
            If RegQueryValueEx(hKey, ValueName, 0, REG_BINARY, _
                resBinary(0), length) = 0 Then
                ReDim Preserve resBinary(length - 1) As Byte
                GetValue = resBinary()
            End If
        Case Else
            err.Raise 1001, , "Unsupported value type"
    End Select
    
    RegCloseKey hKey
End Function

'******************************************************************
'功能：设置注册表中的键值
'输入：
'   plKey                   Long        根键名
'   psKey                   String      主键名
'   ValueName                String      子键名
'   KeyType                  Integer    要设置键的类型
'   value              Long        要设置的值
'   输出:    无
'说明： 仅仅支持 DWORD, SZ, 和 BINARY value 这三种类型.
'******************************************************************
Sub SetValue(ByVal plKey As Long, ByVal psKey As String, ByVal ValueName As String, _
    ByVal KeyType As Integer, value As Variant)

    Dim hKey As Long, lngValue As Long
    Dim strValue As String
    Dim binValue() As Byte, length As Long
    
    '打开键，如果没有找到则推出
    If RegOpenKeyEx(plKey, psKey, 0, KEY_WRITE, hKey) Then Exit Sub
    
    Select Case KeyType
        Case REG_DWORD
            lngValue = value
            RegSetValueEx hKey, ValueName, 0, KeyType, lngValue, 4
        Case REG_SZ
            strValue = value
            RegSetValueEx hKey, ValueName, 0, KeyType, ByVal strValue, Len(strValue)
        Case REG_BINARY
            binValue = value
            length = UBound(binValue) - LBound(binValue) + 1
            RegSetValueEx hKey, ValueName, 0, KeyType, binValue(LBound(binValue)), length