📄 processgb.asp

📁 网页留言簿源代码
💻 ASP
字号:
<html>

<%
'
' ProcessGB.ASP
'
' Chris Eastwood, 2000
'
' http://www.vbcodelibrary.com
'


'
' Variables from Guest Book HTML form
'
  Dim sName
  Dim sEmail
  Dim sHomePage
  Dim sCountry
  Dim sComment
'
' Our XML DOM Variables
'
  Dim oDOM
  Dim oRootNode
  Dim oEntryNode
  Dim oDetailsNode
'
' Get the values from the http header
'
  sName=Request("NAME")
  sEmail=Request("EMAIL")
  sHomePage=Request("HOMEPAGE")
  sCountry=Request("COUNTRY")
  sComment=Request("MESSAGE")
'
' Create our DOM Document Objects
'
  Set oDOM = Server.CreateObject("Microsoft.XMLDOM")
  oDOM.async = false
  oDOM.load server.mappath("gbook.xml")
'
' Check if it wasn't found
'
  If oDOM.parseError.ErrorCode <> 0 Then ' not found! create an empty document
    oDOM.loadXML "<guestbook/>"
  End If
'
' Create an entry node in the guestbook xml document
'
  Set oEntryNode = oDOM.documentElement.AppendChild(oDOM.createElement("entry"))
  oEntryNode.setAttribute "date", now()
'
' Create a 'name' node in the XML document
'
  Set oDetailsNode = oEntryNode.appendChild(oDOM.createElement("name"))
  oDetailsNode.Text = sName
'
' Create an 'email' node in the XML document
'
  Set oDetailsNode = oEntryNode.appendChild(oDOM.createElement("email"))
  oDetailsNode.Text = sEmail
'
' Create a 'Date' node in the XML document
'
'  Set oDetailsNode = oEntryNode.appendChild(oDOM.createElement("date"))
'  oDetailsNode.Text = Now()
'
' Create a 'homepage' node in the XML document
'
  Set oDetailsNode = oEntryNode.appendChild(oDOM.createElement("homepage"))
  oDetailsNode.Text = sHomePage
'
' Create a Country Node in the XML document
'
  Set oDetailsNode = oEntryNode.appendChild(oDOM.createElement("country"))
  oDetailsNode.Text = sCountry
'
' Create a 'Comment' Node in the XML Document - set it to be a 'cdata' section
'
  Set oDetailsNode = oEntryNode.appendChild(oDOM.createElement("comment"))
  oDetailsNode.appendChild oDOM.createCDATASection(sComment)
'
' Now save the XML document 
' - NOTE !
'     The directory to save it to must have write permissions enabled!
'
  oDOM.Save Server.MapPath("gbook.xml")
'
' Quit processing
'
%>

<h2> Thanks <%= sName %></h2>

<p>
<b>Your message : </b>
<p>
<pre>
<%= sComment %>
</pre>

<p><b>Has been entered</p>

<p>Click <a href="viewguestbook.asp">Here</a> To View the GuestBook</p>

</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -