configure.in

模糊聚类分析的源程序！

dnl
dnl	This file is an input file used by the GNU "autoconf" program to
dnl	generate the file "configure", which is run during installation
dnl	to configure the system for the local environment.
dnl
dnl configure.in:					Jan 1996
dnl ([e-mail]-bs,de)
dnl
dnl This is for the Fuzzy Clustering Analysis tool ``fcluster''.
dnl
AC_INIT(fuzzy.cc)

dnl default installation path:
ac_default_prefix=/usr/local

AC_PROG_INSTALL

##
## --with-debug: debug version wanted ?
##
AC_ARG_WITH(debug, [  --with-debug            create a -g compiled binary],
	DEBUG='-DDEBUG -g', DEBUG='-O')
AC_ARG_WITH(optdebug, [  --with-optdebug         create a -g -O compiled binary],
	DEBUG='-Wall -Wno-unused -DDEBUG -O -g')
AC_SUBST(DEBUG)

#----------------------------------------------------------------------------
#	Check for the existence of various libraries.
#----------------------------------------------------------------------------

AC_CHECK_LIB(ieee, main, [LIBS="$LIBS -lieee"])
AC_SUBST(LIBS)

#-------------------------------------------------------------------------
#      Check to use dbmalloc (optional and only recommended for debugging)
#               --with-dbmalloc
#-------------------------------------------------------------------------

AC_ARG_WITH(dbmalloc, [  --with-dbmalloc         add dbmalloc library (internal use - not recomended)],
	dm=1, dm=0)
if test $dm = 1  ; then
    ### XXX: fix me (check paths...):
    DBMALLOC_INC="-I/usr/local/include/dbmalloc"
    DBMALLOC_LIB="-ldbmalloc"
fi
AC_SUBST(DBMALLOC_INC)
AC_SUBST(DBMALLOC_LIB)


#--------------------------------------------------------------------
#	Locate the X11 header files and the X11 library archive.  Try
#	the ac_find_x macro first, but if it doesn't find the X stuff
#	(e.g. because there's no xmkmf program) then check through
#	a list of possible directories.
#--------------------------------------------------------------------

AC_CHECK_PROG(xmkmf_ok, xmkmf, 1, 0)
if test $xmkmf_ok = 1; then
    AC_PATH_X
fi
if test "$XINCLUDE_DIR" != ""; then
    x_includes="$XINCLUDE_DIR"
fi
if test "$x_includes" = /usr/include; then
    XINCLUDES="# no special path needed"
elif test "$x_includes" != ""; then
    XINCLUDES=" -I$x_includes"
else
    AC_CHECKING(for X11 header files)
    XINCLUDES="# no special path needed"
    AC_TRY_CPP([#include <X11/Intrinsic.h>], , XINCLUDES="nope")
    if test "$XINCLUDES" = nope; then
        dirs="/usr/unsupported/include /usr/local/include /usr/X11R6/include /usr/X386/include /usr/include/X11R4 /usr/X11R5/include /usr/include/X11R5 /usr/openwin/include /usr/X11/include"
        for i in $dirs ; do
	    if test -r $i/X11/Intrinsic.h; then
	        XINCLUDES=" -I$i"
	    fi
        done
    fi
fi
if test "$XINCLUDES" = nope; then
  AC_WARN(Couldn't find any X11 include files)
  XINCLUDES="# no include files found"
fi
AC_SUBST(XINCLUDES)

if test "$XLIBRARY_DIR" != ""; then
    x_libraries="$XLIBRARY_DIR"
fi
if test "$x_libraries" = /usr/lib; then
    XLIBSW=-lX11
elif test "$x_libraries" != ""; then
    XLIBSW="-L$x_libraries -lX11"
else
    AC_CHECKING(for X11 library archive)
    AC_CHECK_LIB(X11, main, XLIBSW="-lX11", XLIBSW=nope)
    if test "$XLIBSW" = nope; then
	dirs="/usr/unsupported/lib /usr/local/lib /usr/X11R6/lib /usr/X386/lib /usr/lib/X11R4 /usr/X11R5/lib /usr/lib/X11R5 /usr/openwin/lib /usr/X11/lib"
	for i in $dirs ; do
	    if test -r $i/libX11.a; then
		XLIBSW="-L$i -lX11"
	    fi
	done
    fi
fi
if test "$XLIBSW" = nope ; then
    AC_CHECK_LIB(Xwindow, main, XLIBSW=-lXwindow)
fi
if test "$XLIBSW" = nope ; then
    AC_WARN(Couldn't find the X11 library archive. Using -lX11.)
    XLIBSW=-lX11
fi
AC_SUBST(XLIBSW)

## create the Makefile:

AC_OUTPUT(Makefile)