acinclude.m4

oracle引用库

## -*- shell-script -*-
## ocicpp.m4.in - macros for autoconf
##
## (c) 2000 Alexander I. Olefirenko
##
##
dnl ------------------------------------------------------------------------
dnl Find a file (or one of more files in a list of dirs)
dnl ------------------------------------------------------------------------
dnl
AC_DEFUN(AC_FIND_FILE,
[
$3=NO
for i in $2;do
	for j in $1;  do
		if test -r "$i/$j"; then
			$3=$i
			break 2
		fi
	done
done
]) 
dnl ------------------------------------------------------------------------
dnl OCICPPLIB_PATH([minimum_version])
dnl Try to find the ocicpplib headers and libraries.
dnl $(ocicpp_libraries) will be the ocicpplib library location (if needed)
dnl $(ocicpp_includes) will be the ocicpplib header location (if needed)
dnl $(OCICPP_LDFLAGS) will be the -L$(ocicpp_libraries) (if needed)
dnl $(OCICPP_INCLUDES) will be the -I$(ocicpp_includes) (if needed)
dnl ------------------------------------------------------------------------
dnl
AC_DEFUN(OCICPPLIB_PATH,
[
NEED_OCICPPLIB=$1
ocicpp_major_version=`echo $NEED_OCICPPLIB | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
ocicpp_minor_version=`echo $NEED_OCICPPLIB | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
ocicpp_micro_version=`echo $NEED_OCICPPLIB | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
ac_ocicpp_includes=NO ac_ocicpp_libraries=NO
AC_MSG_CHECKING([for ocicpplib >= $NEED_OCICPPLIB])
ocicpp_libraries=""
ocicpp_includes=""
AC_ARG_WITH(ocicpp-includes,
    [  --with-ocicpp-includes=DIR where the ocicpplib includes are.],
    [  ac_ocicpp_includes="$withval" ])
    
AC_ARG_WITH(ocicpp-libs,
    [  --with-ocicpp-libs=DIR     where the ocicpplib library is installed.],
    [  ac_ocicpp_libraries="$withval" ])

if test "$ac_ocicpp_includes" = NO || test "$ac_ocicpp_libraries" = NO; then

AC_CACHE_VAL(ac_cv_have_ocicpp,
[#try to guess ocicpplib locations

ocicpp_incdirs="/usr/local/include /usr/include /usr/lib/ocicpplib/include /usr/local/ocicpplib/include /usr/include/ocicpplib /usr/local/lib/ocicpplib/include"
AC_FIND_FILE(ocicpp.h, $ocicpp_incdirs, ocicpp_incdir)
ac_ocicpp_includes=$ocicpp_incdir

ocicpp_libdirs="/usr/local/lib /usr/lib /usr/lib/ocicpplib/lib /usr/local/ocicpplib/lib /usr/lib/ocicpplib"
AC_FIND_FILE(libocicpp.so libocicpp.so.$ocicpp_major_version , $ocicpp_libdirs, ocicpp_libdir)
ac_ocicpp_libraries=$ocicpp_libdir

ac_cxxflags_safe=$CXXFLAGS
ac_ldflags_safe=$LDFLAGS
ac_libs_safe=$LIBS
CXXFLAGS="$CXXFLAGS -I$ocicpp_incdir $ORACLE_INCLUDES"
LDFLAGS="$LDFLAGS -L$ocicpp_libdir"
LIBS="-locicpp"

AC_TRY_LINK([
#include "config.h"
#include <ocicpp.h>

#if !defined(OCICPPLIBMAJOR) || !defined(OCICPPLIBMINOR) || !defined(OCICPPLIBMICRO)
#error "You need ocicpplib $NEED_OCICPPLIB or greater. "
#endif

#if !((OCICPPLIBMAJOR>$ocicpp_major_version) || (OCICPPLIBMAJOR==$ocicpp_major_version && OCICPPLIBMINOR>$ocicpp_minor_version) || (OCICPPLIBMAJOR==$ocicpp_major_version && OCICPPLIBMINOR==$ocicpp_minor_version && OCICPPLIBMICRO>=$ocicpp_micro_version))
#error "You need ocicpplib $NEED_OCICPPLIB or greater. "
#endif
],
[
version();
return 0;
],,
[ ac_ocicpp_libraries="NO" ])

CXXFLAGS=$ac_cxxflags_safe
LDFLAGS=$ac_ldflags_safe
LIBS=$ac_libs_safe

if test "$ac_ocicpp_includes" = NO || test "$ac_ocicpp_libraries" = NO; then
  ac_cv_have_ocicpp="have_ocicpp=no"
  ac_ocicpp_notfound=""
  if test "$ac_ocicpp_includes" = NO; then
    if test "$ac_ocicpp_libraries" = NO; then
      ac_ocicpp_notfound="(headers and libraries)";
    else
      ac_ocicpp_notfound="(headers)";
    fi
  else
    ac_ocicpp_notfound="(libraries)";
  fi

  AC_MSG_ERROR([ocicpplib >= $NEED_OCICPPLIB not found. Please check your installation! ]);
else
  have_ocicpp="yes"
fi
])
else
  have_ocicpp="yes"
fi

eval "$ac_cv_have_ocicpp"

if test "$have_ocicpp" != yes; then
  AC_MSG_RESULT([$have_ocicpp]);
else
  ac_cv_have_ocicpp="have_ocicpp=yes \
    ac_ocicpp_includes=$ac_ocicpp_includes ac_ocicpp_libraries=$ac_ocicpp_libraries"
  AC_MSG_RESULT([libraries $ac_ocicpp_libraries, headers $ac_ocicpp_includes])
  
  ocicpp_libraries=$ac_ocicpp_libraries
  ocicpp_includes=$ac_ocicpp_includes
fi
AC_SUBST(ocicpp_libraries)
AC_SUBST(ocicpp_includes)

OCICPP_INCLUDES="-I$ocicpp_includes"
all_includes="$OCICPP_INCLUDES $all_includes"

OCICPP_LDFLAGS="-L$ocicpp_libraries"
all_libraries="$OCICPP_LDFLAGS $all_libraries"

AC_SUBST(OCICPP_INCLUDES)
AC_SUBST(OCICPP_LDFLAGS)
])

dnl ------------------------------------------------------------------------
dnl OCICPPLIB_VERSION()
dnl Generates OCICPPLIBVER, OCICPPLIBMAJOR, OCICPPLIBMINOR and OCICPPLIBMICRO constants
dnl ------------------------------------------------------------------------
dnl
AC_DEFUN(OCICPPLIB_VERSION,
[
OCICPPLIBV=`cat VERSION`
OCICPPLIBMAJOR=`echo $OCICPPLIBV | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
OCICPPLIBMINOR=`echo $OCICPPLIBV | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
OCICPPLIBMICRO=`echo $OCICPPLIBV | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
OCICPPLIBVER=`printf "0x%02i%02i%02i" $OCICPPLIBMAJOR $OCICPPLIBMINOR $OCICPPLIBMICRO`
AC_SUBST(OCICPPLIBMAJOR)
AC_SUBST(OCICPPLIBMINOR)
AC_SUBST(OCICPPLIBMICRO)
AC_SUBST(OCICPPLIBVER)
])

dnl ------------------------------------------------------------------------
dnl ORACLE_PATH()
dnl Try to find the Oracle headers and libs
dnl ------------------------------------------------------------------------
dnl
AC_DEFUN(ORACLE_PATH,
[
AC_MSG_CHECKING([for Oracle home])
oracle_includes=""
oracle_home=""
AC_ARG_WITH(oracle_home,
[  --with-oracle-home=DIR  where the oracle installed.],
[  ac_oracle_home="$withval" ], [ ac_oracle_home="NO" ])
if test "$ac_oracle_home" = NO; then
	ac_oracle_home=`echo $ORACLE_HOME`
	if test -z "$ac_oracle_home"; then		
		AC_MSG_ERROR([ Oracle 8.x.x or greater installation needed.])
	fi
	oracle_inc_dirs="$ac_oracle_home/rdbms/demo $ac_oracle_home/rdbms/public $ac_oracle_home/network/public  $ac_oracle_home/plsql/public"
#	AC_FIND_FILE(oci.h , $oracle_inc_dirs , oracle_inc_dirs )
	if test "$oracle_inc_dirs" = NO; then 
		AC_MSG_ERROR([ Oracle 8.x.x or greater installation needed.])
	fi
fi
ORACLE_HOME="$ac_oracle_home"
oracle_includes="$ORACLE_HOME/rdbms/demo $ORACLE_HOME/rdbms/public $ORACLE_HOME/plsql/public $ORACLE_HOME/network/public"
ORACLE_INCLUDES="-I$ORACLE_HOME/rdbms/demo -I$ORACLE_HOME/rdbms/public -I$ORACLE_HOME/plsql/public -I$ORACLE_HOME/network/public"
all_includes="$ORACLE_INCLUDES $all_includes"
AC_FIND_FILE(libclntsh.so.8.0, "$ORACLE_HOME/lib" ,ora_lib)
if test x"$ora_lib" = x"NO"; then
	AC_FIND_FILE(libclntsh.so.1.0, "$ORACLE_HOME/lib" ,ora_lib)
	if test $ora_lib = NO; then
		AC_MSG_ERROR([ Cannot determine Oracle version only supported are 8.0.x and 8.1.x ])
	else
		ORACLE_VER="8.0"
		ORACLE_LIBDIR="$ORACLE_HOME/lib"
		ORACLE_LIBS="-lclntsh -lcommon -lcore4 -lnlsrtl3"
		ORACLE_VER_MAJOR="8";
		ORACLE_VER_MINOR="0";
	fi
else
	ORACLE_VER="8.1"
	ORACLE_LIBDIR="$ORACLE_HOME/lib"
	ORACLE_LIBS="-lclntsh"
	ORACLE_VER_MAJOR="8";
	ORACLE_VER_MINOR="1";
fi
AC_MSG_RESULT([ Oracle Location: $ORACLE_HOME , Version: $ORACLE_VER. ])
AC_SUBST(ORACLE_HOME)
AC_SUBST(ORACLE_VER)
AC_SUBST(ORACLE_INCLUDES)
AC_SUBST(ORACLE_LIBS)
AC_SUBST(ORACLE_LIBDIR)
AC_SUBST(ORACLE_VER_MAJOR)
AC_SUBST(ORACLE_VER_MINOR)
])


AC_DEFUN(OCICPP_DEBUG_LEVEL,
[
AC_MSG_CHECKING([for debug level])
AC_ARG_WITH(debug_level,
[  --with-debug_level=level     Debug level.],
[  ac_debug_level="$withval" ],
[  ac_debug_level="DLEV_FATAL"])
DEBUG_LEVEL="$ac_debug_level"
AC_MSG_RESULT([ Debug level is $DEBUG_LEVEL. ])
AC_SUBST(DEBUG_LEVEL)
])