aclocal.m4

linux pritner GUI

# generated automatically by aclocal 1.7.7 -*- Autoconf -*-

# Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002
# Free Software Foundation, Inc.
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY, to the extent permitted by law; without
# even the implied warranty of MERCHANTABILITY or FITNESS FOR A
# PARTICULAR PURPOSE.

dnl aclocal.m4 -- various bits of this have been borrowed from the m4
dnl configuration files for KDE and GNOME

AC_DEFUN(AC_INSTALL_DIRS,
[
AC_MSG_CHECKING(the fax spool directory)
dnl set up the defaults

SPOOLDIR="/var/spool/fax"
AC_ARG_WITH(spooldir,
  [  --with-spooldir=DIR     Where fax printer filter is installed (default is /var/spool/fax)],
[
if test "$withval" != "no"; dnl 
  then SPOOLDIR="$withval"
fi
])
AC_MSG_RESULT([SPOOLDIR is $SPOOLDIR])

AC_SUBST(SPOOLDIR)
])

AC_DEFUN(AC_CHECK_HAVE_IOS_NOCREATE,
[
  AC_MSG_CHECKING(for fstream ios::nocreate flag)
  AC_CACHE_VAL(ac_cv_have_ios_nocreate,
  [
    AC_LANG_CPLUSPLUS
    AC_TRY_COMPILE([
#include <fstream>
    ],
    [
      std::fstream strm("dummy.txt", std::ios::in | std::ios::nocreate);
      strm << 'a';
    ],
    [ac_cv_have_ios_nocreate="yes"],
    [ac_cv_have_ios_nocreate="no"
    ]) dnl end AC_TRY_COMPILE
  ])
  AC_MSG_RESULT([$ac_cv_have_ios_nocreate])
  if test "$ac_cv_have_ios_nocreate" = "yes" ; then
     AC_DEFINE(HAVE_IOS_NOCREATE, 1, [ Define if the C++ fstream object has ios::nocreate ])
  fi 
])

AC_DEFUN(AC_CHECK_HAVE_PTHREAD_SIGMASK,
[
  AC_MSG_CHECKING(for pthread_sigmask)
  AC_CACHE_VAL(ac_cv_have_pthread_sigmask,
  [
    AC_LANG_CPLUSPLUS
    AC_TRY_COMPILE([
#include <signal.h>
#include <pthread.h>
    ],
    [
      sigset_t sig_mask;
      sigemptyset(&sig_mask);
      sigaddset(&sig_mask, SIGCHLD);
      pthread_sigmask(SIG_BLOCK, &sig_mask, 0);
    ],
    [ac_cv_have_pthread_sigmask="yes"],
    [ac_cv_have_pthread_sigmask="no"
    ]) dnl end AC_TRY_COMPILE
  ])
  AC_MSG_RESULT([$ac_cv_have_pthread_sigmask])
  if test "$ac_cv_have_pthread_sigmask" = "yes" ; then
     AC_DEFINE(HAVE_PTHREAD_SIGMASK, 1, [ Define if signal.h declares pthread_sigmask ])
  fi 
])

AC_DEFUN(AC_CHECK_HAVE_STRINGSTREAM,
[
  AC_MSG_CHECKING(for std::stringstream)
  AC_CACHE_VAL(ac_cv_have_stringstream,
  [
    AC_LANG_CPLUSPLUS
    AC_TRY_COMPILE([
#include <sstream>
    ],
    [
      std::ostringstream strm;;
      strm << 'a';
    ],
    [ac_cv_have_stringstream="yes"],
    [ac_cv_have_stringstream="no"
    ]) dnl end AC_TRY_COMPILE
  ])
  AC_MSG_RESULT([$ac_cv_have_stringstream])
  if test "$ac_cv_have_stringstream" = "yes" ; then
     AC_DEFINE(HAVE_STRINGSTREAM, 1, [ Define if the C++ library contains std::stringstream ])
  fi 
])

AC_DEFUN(AC_CHECK_BOOL,
[
  AC_MSG_CHECKING(for bool)
  AC_CACHE_VAL(ac_cv_have_bool,
  [
    AC_LANG_CPLUSPLUS
    AC_TRY_COMPILE([],
      [bool aBool = true;],
      [ac_cv_have_bool="yes"],
      [ac_cv_have_bool="no"])
  ]) dnl end AC_CHECK_VAL
    AC_MSG_RESULT($ac_cv_have_bool)
    if test "$ac_cv_have_bool" = "yes"; then
      AC_DEFINE(HAVE_BOOL, 1, [
typedef int bool;
const bool false = 0;
const bool true = 1;
    ]) 
    fi 
])

AC_DEFUN(AC_CHECK_SOCKLEN_T,
[
  AC_CHECK_TYPES(socklen_t, , ,
  [
#include <unistd.h>
#include <sys/types.h>
#include <sys/socket.h>
#include <netdb.h>
  ])
])

AC_DEFUN(AC_CHECK_COMPILERS,
[
  AC_ARG_ENABLE(debug,[  --enable-debug 	  creates debugging code [default=no]],
  [ 
   if test $enableval = "no"; dnl 
     then ac_use_debug_code="no"
     else ac_use_debug_code="yes"
   fi
  ], [ac_use_debug_code="no"])

  dnl Just for configure --help

  dnl this prevents stupid AC_PROG_CC from adding "-g" to the default CFLAGS
  c_flags_in=$CFLAGS

  AC_PROG_CC
  AC_PROG_CPP

  CFLAGS=$c_flags_in

  if test -z "$CFLAGS"; then 
    if test "$GCC" = "yes"; then
      if test "$ac_use_debug_code" = "yes"; then
        CFLAGS="-g $CFLAGS"
      else
        CFLAGS="-O2 $CFLAGS"
      fi
    else 
      if test "$ac_use_debug_code" = "yes"; then
        AC_CHECK_COMPILER_FLAG(g,
          [
            CFLAGS="-g $CFLAGS"
        ])
      else 
        AC_CHECK_COMPILER_FLAG(O2,
          [
            CFLAGS="-O2 $CFLAGS"
        ])
      fi
    fi
    if test "$GCC" = "yes"; then
       CFLAGS="$CFLAGS -Wall"
    fi
  fi

  dnl this prevents stupid AC_PROG_CXX from adding "-g" to the default CXXFLAGS
  cxx_flags_in=$CXXFLAGS

  AC_PROG_CXX
  AC_PROG_CXXCPP

  CXXFLAGS=$cxx_flags_in

  if test -z "$CXXFLAGS"; then 
    if test "$GXX" = "yes"; then
      if test "$ac_use_debug_code" = "yes"; then
        CXXFLAGS="-g $CXXFLAGS"
      else
        CXXFLAGS="-O2 $CXXFLAGS"
        if test -z "$LDLFLAGS"; then 
          LDFLAGS="-s"
        fi
      fi
    else 
      if test "$ac_use_debug_code" = "yes"; then
        AC_CHECK_COMPILER_FLAG(g,
          [
            CXXFLAGS="-g $CXXFLAGS"
        ])
      else 
        AC_CHECK_COMPILER_FLAG(O2,
          [
            CXXFLAGS="-O2 $CXXFLAGS"
        ])
      fi
    fi

    AC_CHECK_COMPILER_FLAG(fexceptions,
      [
        CXXFLAGS="$CXXFLAGS -fexceptions"
    ])

    AC_CHECK_COMPILER_FLAG(frtti,
      [
        CXXFLAGS="$CXXFLAGS -frtti"
    ])

    AC_CHECK_COMPILER_FLAG(fsigned-char,
      [
        CXXFLAGS="$CXXFLAGS -fsigned-char"
    ])

    AC_CHECK_COMPILER_FLAG(fno-check-new,
      [
        CXXFLAGS="$CXXFLAGS -fno-check-new"
    ])

    if test "$GXX" = "yes"; then
       CXXFLAGS="$CXXFLAGS -Wall"
    fi
  fi  
])

AC_DEFUN(AC_CHECK_COMPILER_FLAG,
[
AC_MSG_CHECKING(whether $CXX supports -$1)
flag_cache=`echo $1 | sed 'y%.=/+-%___p_%'`
AC_CACHE_VAL(ac_cv_prog_cxx_$flag_cache,
[
echo 'int main() { return 0; }' >conftest.cc
eval "ac_cv_prog_cxx_$flag_cache=no"
if test -z "`$CXX -$1 -c conftest.cc 2>&1`"; then
  if test -z "`$CXX -$1 -o conftest conftest.o 2>&1`"; then
    eval "ac_cv_prog_cxx_$flag_cache=yes"
  fi
fi
rm -f conftest*
])
if eval "test \"`echo '$ac_cv_prog_cxx_'$flag_cache`\" = yes"; then
 AC_MSG_RESULT(yes)
 :
 $2
else
 AC_MSG_RESULT(no)
 :
 $3
fi
])

AC_DEFUN(AC_CHECK_MKSTEMP,
[
  AC_LANG_C
  ac_cflags_safe=$CFLAGS
  ac_ldflags_safe=$LDFLAGS
  ac_libs_safe=$LIBS
  CFLAGS=""
  LDFLAGS=""
  LIBS=""
  AC_CHECK_FUNCS(mkstemp,,
    AC_MSG_ERROR([Library function mkstemp is required and cannot be found]))
  CFLAGS=$ac_cflags_safe
  LDFLAGS=$ac_ldflags_safe
  LIBS=$ac_libs_safe
])

AC_DEFUN(AC_CLOSING_MESSAGE,
[
echo
echo "    Configuration complete."
echo
echo "    To compile, enter \`make', and then enter \`make install'"
echo "      -- \`make install' must be run as root."
echo
echo "    To reconfigure, enter \`make clean' and then run \`./configure' again."
echo
])

dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
dnl also defines GSTUFF_PKG_ERRORS on error
AC_DEFUN(PKG_CHECK_MODULES, [
  succeeded=no

  if test -z "$PKG_CONFIG"; then
    AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  fi

  if test "$PKG_CONFIG" = "no" ; then
     echo "*** The pkg-config script could not be found. Make sure it is"
     echo "*** in your path, or set the PKG_CONFIG environment variable"
     echo "*** to the full path to pkg-config."
     echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  else
     PKG_CONFIG_MIN_VERSION=0.9.0
     if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
        AC_MSG_CHECKING(for $2)

        if $PKG_CONFIG --exists "$2" ; then
            AC_MSG_RESULT(yes)
            succeeded=yes

            AC_MSG_CHECKING($1_CFLAGS)
            $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
            AC_MSG_RESULT($$1_CFLAGS)

            AC_MSG_CHECKING($1_LIBS)
            $1_LIBS=`$PKG_CONFIG --libs "$2"`
            AC_MSG_RESULT($$1_LIBS)
        else
            $1_CFLAGS=""
            $1_LIBS=""
            AC_MSG_RESULT([no])
        fi

        AC_SUBST($1_CFLAGS)
        AC_SUBST($1_LIBS)
     else
        echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
        echo "*** See http://www.freedesktop.org/software/pkgconfig"
     fi
  fi

  if test $succeeded = yes; then
     ifelse([$3], , :, [$3])
  else
     ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
  fi
])

dnl ----------------------------------------------------------
dnl the macros in the rest of this file come from GNU gettext
dnl and are for internationalisation support
dnl ----------------------------------------------------------