showannouncement.asp

苹果风格的论坛 asp编写

<!--#INCLUDE FILE="inc/db_inc.asp"-->
<!--#INCLUDE FILE="inc/char_inc.asp"-->
<!--#INCLUDE FILE="inc/xbcode_inc.asp"-->
<!--#INCLUDE FILE="header.asp"-->
<!--#INCLUDE FILE="user.asp"-->
<%
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'	Snowman Forum v2.0
'
'	Copyright(C) Snowman, All rights reserved.
'
'	http://www.xinboard.net
'
'	Access版本免费, 欲使用SQL Server商业版本请购买使用权
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

dim StrSql, rs2, toptext, StrHtml, StrHtml2, StrHtml3, err, pagecount

error = ""
threadtitle = ""

StrHtml = loadtemplate("htmltop")
StrHtml = Replace(StrHtml, "{pagetitle}", loadtemplate("announcementtitle"))
StrHtml = Replace(StrHtml, "{style_path}", loadtemplate("path"))
StrHtml = Replace(StrHtml, "{forumtitle}", boardtitle)
response.write StrHtml
response.write pmpopwin
StrHtml = loadtemplate("pagetitle")
StrHtml = Replace(StrHtml, "{title_img}", "<img src=""style/" & loadtemplate("path") & "/image/title.gif"">")

if request.cookies("sf")("username") = "" then
	toptext = loadtemplate("toptextguest")
else
	toptext = loadtemplate("toptextuser")
end if
toptext = toptext & loadtemplate("toptext")
StrHtml = Replace(StrHtml, "{top_text}", toptext)
StrHtml = Replace(StrHtml, "{username}", request.cookies("sf")("username"))
response.write StrHtml

' 如果有错误则提示
if error <> "" then
	StrHtml = loadtemplate("error")
	StrHtml = Replace(StrHtml, "{error_text}", error)
	response.write StrHtml
	response.end
end if

' 显示当前页面路径
StrHtml = loadtemplate("pagepath")
StrHtml = Replace(StrHtml, "{path_text}", "<img src=""style/" & loadtemplate("path") & "/image/home.gif""><a href=index.asp>" & boardtitle & "</a> &raquo; " & loadtemplate("announcementtitle"))
response.write StrHtml



page = request("page")

' 获得当前页数
if page = "" then
	page = 1
else
	if not IsNumeric(page) then
		page = 1
	else
		page = clng(page)
	end if
end if

' 显示帖子列表
pagecount = 1
StrHtml = loadtemplate("announcement")
StrSql = "select sf_announcement.*, sf_user.* from sf_announcement left join sf_user on (sf_announcement.userid = sf_user.userid) order by announcementid DESC"
Set rs2 = server.CreateObject("ADODB.RecordSet")
rs2.Open StrSql, Conn, 1, 1
if not (rs2.bof or rs2.eof) then
	' 分页处理
	i = 1
	rs2.PageSize = postrow
	if page > rs2.PageCount then page = rs2.PageCount
	rs2.AbsolutePage = page
	pagecount = rs2.PageCount
	do until rs2.eof or i > rs2.PageSize
		StrHtml2 = StrHtml
		StrHtml2 = Replace(StrHtml2, "{title}", rs2("title"))
		StrHtml2 = Replace(StrHtml2, "{startdate}", rs2("startdate"))
		StrHtml2 = Replace(StrHtml2, "{enddate}", rs2("enddate"))
		posttext = xbcodeContent(formatstr(rs2("pagetext")), true, true, true, true)
		StrHtml2 = Replace(StrHtml2, "{text}", "<br><br>" & posttext & "<br><br>")
		StrHtml3 = "<b>" & rs2("username") & "</b><br><br>"
		if rs2("avatar") = "" then
			StrHtml3 = StrHtml3 & "<img src=""" & rs2("defineavatar") & """ width=""" & rs2("avatarwidth") & """ height=""" & rs2("avatarheight") & """>"
		else
			StrHtml3 = StrHtml3 & "<img src=""image/face/" & rs2("avatar") & """>"
		end if
		StrHtml3 = StrHtml3 & "<br><br>"
		if rs2("usertitle") = "" then
			StrHtml3 = StrHtml3 & GetTitle(rs2("posts"))
		else
			StrHtml3 = StrHtml3 & rs2("usertitle")
		end if
		StrHtml3 = StrHtml3 & "<br>"
		select case rs2("usergroup")
			case 4
				StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/admin.gif"">")
			case 3
				StrHtml2 = Replace(StrHtml2, "{user_titleimg}", "<img src=""image/title/supermoder.gif"">")
			case else
				StrHtml3 = StrHtml3 & "<img src=""image/title/" & GetTitleImg(rs2("posts")) & ".gif"">"
		end select
		StrHtml2 = Replace(StrHtml2, "{user_info}", StrHtml3)
		response.write StrHtml2
		rs2.MoveNext
		i = i + 1
	loop
end if

StrHtml = loadtemplate("announcementbottom")

StrHtml2 = "<img src=""style/" & loadtemplate("path") & "/image/page.gif""> " & pagecount & ": "

beginpage = 1
endpage = pagecount
if pagecount >= 9 then
  if page >= 5 then
    beginpage = page - 4
    if page <= (pagecount - 4) then
      endpage = page + 4
    else
      endpage = pagecount
      beginpage = pagecount - 4
    end if
  else
    beginpage=1
    endpage=9
  end if
end if
if beginpage>1 then StrHtml2 = StrHtml2 & "&nbsp;<a href=""showannouncement.asp"">&laquo;</a>"
for i=beginpage to endpage
  if i=page then
    StrHtml2 = StrHtml2 & "&nbsp;<b>" & i & "</b>&nbsp;"
  else
    StrHtml2 = StrHtml2 & "<a href=""showannouncement.asp?page=" & i & """>&nbsp;" & i & "&nbsp;</a>"
  end if
next
if endpage < pagecount then StrHtml2 = StrHtml2 & "&nbsp;<a href=""showannouncement.asp?page=" & pagecount & """>&raquo;</a>"

StrHtml = Replace(StrHtml, "{page_text}", StrHtml2)
response.write StrHtml
response.write sfcopyright
response.write loadtemplate("htmlbottom")
Conn.Close
Set Conn = nothing
Set rs = nothing
Set rs2 = nothing
%>