txthroughputp.nc

tinyos-2.x.rar

/*
 * Copyright (c) 2005-2006 Rincon Research Corporation
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * - Redistributions of source code must retain the above copyright
 *   notice, this list of conditions and the following disclaimer.
 * - Redistributions in binary form must reproduce the above copyright
 *   notice, this list of conditions and the following disclaimer in the
 *   documentation and/or other materials provided with the
 *   distribution.
 * - Neither the name of the Rincon Research Corporation nor the names of
 *   its contributors may be used to endorse or promote products derived
 *   from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
 * ARCHED ROCK OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE
 */
 
#include "TxThroughput.h"
 
/**
 * This application is used more for characterization rather than a
 * test.  It measures the maximum radio throughput using the largest
 * message payload size, and does not use low power listening.
 *
 * @author David Moss
 */
 
module TxThroughputP {
  uses {
    interface Boot;
    interface SplitControl as SerialSplitControl;
    interface SplitControl as RadioSplitControl;
    interface AMSend as SerialAMSend;
    interface AMSend as RadioAMSend;
    interface PacketAcknowledgements;
    interface Timer<TMilli>;
    interface Leds;
  }
}

implementation {

  message_t radioMsg;
  
  message_t serialMsg;
  
  uint16_t packetsPerSecond;
  
  enum {
    MSG_DESTINATION = 1,
  };
  
  /***************** Prototypes ****************/
  task void sendRadio();
  task void sendSerial();
  
  /***************** Boot Events ****************/
  event void Boot.booted() {
    if(USE_ACKNOWLEDGEMENTS) {
      call PacketAcknowledgements.requestAck(&radioMsg);
    } else {
      call PacketAcknowledgements.noAck(&radioMsg);
    }
    
    call RadioSplitControl.start();
    call SerialSplitControl.start();
  }
  
  /***************** RadioSplitControl Events ****************/
  event void RadioSplitControl.startDone(error_t error) {
    packetsPerSecond = 0;
    post sendRadio();
  }
  
  event void RadioSplitControl.stopDone(error_t error) {
  }
  
  /***************** SerialSplitControl Events ****************/
  event void SerialSplitControl.startDone(error_t error) {
    call Timer.startPeriodic(1024);
  }
  
  event void SerialSplitControl.stopDone(error_t error) {
  }
  
  /***************** AMSend Events ****************/
  event void RadioAMSend.sendDone(message_t *msg, error_t error) {
    packetsPerSecond++;
    call Leds.led1Toggle();
    post sendRadio();
  }
  
  event void SerialAMSend.sendDone(message_t *msg, error_t error) {
  }
  
  /***************** Timer Events ***************/
  event void Timer.fired() {
    ((ThroughputMsg *) call SerialAMSend.getPayload(&serialMsg, sizeof(ThroughputMsg)))->packetsPerSecond = packetsPerSecond;
    packetsPerSecond = 0;
    post sendSerial();
  }
  
  /****************** Tasks ****************/
  task void sendRadio() {
    if(call RadioAMSend.send(MSG_DESTINATION, &radioMsg, sizeof(ThroughputMsg)) 
        != SUCCESS) {
      post sendRadio();
    }
  }
  
  task void sendSerial() {
    if(call SerialAMSend.send(0, &serialMsg, sizeof(ThroughputMsg)) 
        != SUCCESS) {
      post sendSerial();
    }
  }
}