semaphorep.nc

tinyos-2.x.rar

/*
 * Copyright (c) 2008 Stanford University.
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * - Redistributions of source code must retain the above copyright
 *   notice, this list of conditions and the following disclaimer.
 * - Redistributions in binary form must reproduce the above copyright
 *   notice, this list of conditions and the following disclaimer in the
 *   documentation and/or other materials provided with the
 *   distribution.
 * - Neither the name of the Stanford University nor the names of
 *   its contributors may be used to endorse or promote products derived
 *   from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL STANFORD
 * UNIVERSITY OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE.
 */
 
/**
 * @author Kevin Klues <[e-mail]>
 * @author Chieh-Jan Mike Liang <[e-mail]>
 */

module SemaphoreP {
  provides {
    interface Semaphore;
  }
  uses {
    interface ThreadScheduler;
    interface Mutex;
    interface ConditionVariable;
    interface Leds;
  }
}

implementation {
  command void Semaphore.reset(semaphore_t* s, uint8_t v) {
    s->s = 0;
    s->v = v;
    call Mutex.init(&(s->lock));  
    call ConditionVariable.init(&(s->condvar));
  }
  command error_t Semaphore.acquire(semaphore_t* s) {
    atomic {
    call Mutex.lock(&(s->lock));
      s->s++;
      while (s->v == 0) {
        call ConditionVariable.wait(&(s->condvar), &(s->lock));
        s->v++;
      }
      s->s--;
      s->v--;  
    call Mutex.unlock(&(s->lock));
    }
    return SUCCESS;
  }
  command error_t Semaphore.release(semaphore_t* s) {
    atomic {
    call Mutex.lock(&(s->lock));
      if(s->s > 0)
        call ConditionVariable.signalNext(&(s->condvar));
      else s->v++;
    call Mutex.unlock(&(s->lock));
    }
    return SUCCESS;
  }
}