extflashp.nc

tinyos-2.x.rar

// $Id: ExtFlashP.nc,v 1.1 2009/09/23 18:29:22 razvanm Exp $

/*
 * "Copyright (c) 2000-2005 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 */

/**
 * @author Jonathan Hui <[e-mail]>
 * @author Razvan Musaloiu-E. <[e-mail]>
 */

module ExtFlashP {
  provides {
    interface StdControl;
    interface Init;
    interface ExtFlash;
  }
  uses {
    interface HplUsartControl as UsartControl;
  }
}

implementation {

  uint32_t addr;

  command error_t Init.init() {
    TOSH_MAKE_FLASH_CS_OUTPUT();
    TOSH_SET_FLASH_CS_PIN();
    call UsartControl.setModeSPI();
    return SUCCESS;
  }

  command error_t StdControl.start() { 
    return SUCCESS; 
  }

  command error_t StdControl.stop() { 
    call UsartControl.disableSPI();
    return SUCCESS; 
  }

  command void ExtFlash.startRead(uint32_t newAddr) {

    uint8_t cmd[4];
    uint8_t i;
    uint32_t page = newAddr / 512;
    uint32_t offset = newAddr % 512;

    addr = newAddr;

    cmd[0] = 0x03;
    cmd[1] = page >> 6;
    cmd[2] = (page << 2) | (offset >> 8);
    cmd[3] = offset;

    TOSH_CLR_FLASH_CS_PIN();

    for ( i = 0; i < sizeof(cmd); i++ ) {
      call UsartControl.tx(cmd[i]);
      while(call UsartControl.isTxEmpty() != SUCCESS);
    }
  }

  command uint8_t ExtFlash.readByte() {
    if (!(addr & 0x1ff)) {
      call ExtFlash.stopRead();
      call ExtFlash.startRead(addr);
    }
    addr++;
    call UsartControl.rx();
    call UsartControl.tx(0);
    while(call UsartControl.isRxIntrPending() != SUCCESS);
    return call UsartControl.rx();
  }

  command void ExtFlash.stopRead() {
    TOSH_SET_FLASH_CS_PIN();
  }

}