📄 +
字号:
**************************************************************
* 记账主程序.PRG *
**************************************************************
CLOSE DATA && 关闭数据库
CLEAR && 清工作台面或自定义窗口
SET DATE ANSI && 设置日期格式为yy.mm.dd
SET CENT ON && 设置世纪格式为yyyy
SET ESCAPE OFF && Esc键失效
public zza(300,10) && 定维数组ZZA,总帐数组
PUBLIC a(300),b(85,5),b1(85),zka(85,7) && 定维公共数组
STORE 0 TO a && 初始化数组
SELECT 3 && 选择工作区
USE 科目总控!zk85 && 打开表‘zk85’（总控85,内含85个科目）
COPY TO ARRAY zka && 复制到数组zka
COPY TO ARRAY b && 复制到数组b1
FOR i=1 TO 85 && 循环
b1(i)=b(i,2) && 把科目名称赋值给数组b
NEXT && 下一个FOR循环
DO win && 运行win过程，定义一些窗口和一些公共变量
PUBL k,s,h,BEGIN,the_end && 定义公共变量
STORE 0 TO k,s,h && 初始化变量
DO FORM 表单1 NAME 主表 LINK && 执行表单，输入密码
READ EVENTS && 激活事件
DO FORM 表单2 NAME 记账开始结束时间 LINK && 执行表单
READ EVENTS && 激活事件
DO WHILE .T. && 循环
DO FORM 表单3 && 命令按钮组 1转账凭证 2收款凭证 3付款凭证 4退出
READ EVENTS && 激活事件
DEAC WINDOW ALL && 挂起所有窗口
STORE 0 TO fudanjzs,bianhao && 附单据张数，编号
DO CASE && 根据情况判断执行
CASE s=1 && 当选择了转账凭证
DO 转账凭证登录 && 运行转帐记帐凭证登录子程序，参见第二十四章
* DO zzpzdy && 运行转帐记帐凭证打印子程序
CASE s=2 && 当选择了收款凭证
DO 收款记账凭证登录 && 运行收款记帐凭证登录子程序，参见第二十五章
* DO SKPZDY && 运行收款记帐凭证打印子程序
CASE s=3 && 当选择了付款凭证
DO 付款记账凭证登录 && 运行付款记帐凭证登录子程序，参见第二十六章
* DO FKPZDY && 运行收款记帐凭证打印子程序
CASE s=4 && 当选择了退出
CLEAR ALL && 释放变量、窗口，关闭表
CANCEL && 停止当前程序的执行
ENDCASE
DO 栏目填写 && 运行栏目填写子程序，参见第二十七章
************ 凭证分录 **********
DEAC WINDOW ALL && 挂起所有窗口
ACTI WINDOW jz && 激活jz窗口
CLEAR && 清洁窗口
@ 1,5 SAY '请慎重考虑究竟(分录)上帐不上帐?' COLOR RGB(255,128,0,255,255,255) && 提示信息
STORE 2 TO qzz && 初始化变量
@ 3,1 GET qzz DEFA 2 FUNCTION '*hT 确 认;取 销' SIZE 2,8,22 && 两个命令按钮
READ && 激活对象
DO rk && 键控过程，按Ctrl+End结束程序
IF qzz=1 && 如果选择了确认
DEAC WINDOW jz && 挂起jz窗口
DO 凭证分录 && 运行凭证分录子程序
DO 凭证登帐 && 运行凭证登帐子程序
ELSE && 否则
CLEAR && 清洁窗口
@ 1,8 SAY '已经取消分录,请重新开始.' COLOR RGB(255,255,0,0,0,255) && 提示信息
ENDIF
ENDDO
CLOSE DATA && 关闭数据库
CLEAR ALL && 释放变量、窗口，关闭表
CANCEL && 停止当前程序的执行
RETURN && 主程序结束
PROC rk && 键控过程
IF READKEY()=270 && 如果按了Ctrl+End 结束程序
CLEAR ALL && 释放变量、窗口，关闭表
CANCEL && 停止当前程序的执行
ENDIF
RETURN && 返回调用程序
PROCEDURE win && 过程，定义一些窗口和一些公共变量
DEFINE WINDOW fkjzpz FROM INT((SROW()-24)/2),INT((SCOL()-77)/2) ;
TO INT((SROW()-24)/2)+24,INT((SCOL()-77)/2)+76 TITLE "付款记帐凭证" ;
NOFLOAT CLOSE SHADOW NOMINIMIZE PANEL && 定义窗口，下同
DEFINE WINDOW skjzpz FROM INT((SROW()-24)/2),INT((SCOL()-77)/2) ;
TO INT((SROW()-24)/2)+24,INT((SCOL()-77)/2)+76 TITLE "收款记帐凭证" ;
NOFLOAT CLOSE SHADOW NOMINIMIZE PANEL
DEFI WINDOW fwj FROM 0,0 TO 26,90 TITLE "付款 借方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFI WINDOW fwd FROM 6,67 TO 15,100 title "付款 贷方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFI WINDOW swj FROM 3,0 TO 14,24 TITLE "收款 借方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFI WINDOW swd FROM 0,17 TO 26,100 TITLE "收款 贷方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFI WINDOW zwj FROM 0,0 TO 26,90 TITLE "转账 借方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFI WINDOW zwd FROM 0,17 TO 26,100 TITLE "转账 贷方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFI WINDOW zwd1 FROM 0,60 TO 26,100 TITLE "转账 贷方科目 " ZOOM MINIMIZE FLOAT DOUB CLOSE
DEFINE WINDOW jz FROM 1,30 TO 20,76 TITLE ' 记帐子系统 ' CLOSE COLOR RGB(255,0,255,100,255,128)
DEFINE WINDOW zzpz FROM INT((SROW()-24)/2),INT((SCOL()-77)/2) ;
TO INT((SROW()-24)/2)+24,INT((SCOL()-77)/2)+76 TITLE " 转 帐 凭 证 " ;
FLOAT CLOSE SHADOW NOMINIMIZE PANEL
PUBLIC riqi,bianhao,kuaijizg,jizhang,jihe,zhidan,chuna && 定义公共变量，下同
PUBLIC chunabh,lingkr,fudanjzs,pingzlb,jehj_m
STORE ' ' TO kuaijizg && 初始化变量，下同
STORE 0 TO fudanjzs,bianhao,jehj_m && 附单据张数，编号，金额合计
STORE '钟惠民' TO jizhang,jihe && 记账，稽核
STORE ' ' TO chuna,lingkr,chunabh,zhidan && 出纳，领款人，出纳编号，制单
STORE 0 TO fudanjzs,bianhao && 附单据张数，编号
PUBLIC jsfs(6) && 定维公共数组，结算方式
jsfs(1)='现金支票' && 给数组元素赋值，下同
jsfs(2)='转账支票'
jsfs(3)='汇票'
jsfs(4)='信汇'
jsfs(5)='电汇'
jsfs(6)='现金'
PUBLIC ccpshuliang(7),ccpdj(7),ccpxh(7),cpxh(11) && 定维数组，产成品数量单价序号
STORE 0 TO ccpshuliang && 初始化，下同
STORE 0.00 TO ccpdj
STORE ' ' TO ccpxh
cpxh(1)='1' && 给数组元素赋值,产品型号，下同
cpxh(2)='1A'
cpxh(3)='1B'
cpxh(4)='1BQ'
cpxh(5)='1C'
cpxh(6)='2'
cpxh(7)='2B'
cpxh(8)='48-6'
cpxh(9)='48A'
cpxh(10)='30-80'
cpxh(11)='U'
PUBLIC cbfyfield(300,30),cbfyend(300) && 成本费用 字段，尾
PUBLIC cbfyxh(300,30),cbfyfieldje(300,30) && 序号，金额
STORE 0 TO cbfyxh,cbfyfield,cbfyend && 初始化数组，下同
STORE 0.00 TO cbfyfieldje
PUBL zhai(20,1),zhai1(20) && 定维数组
STORE ' ' TO zhai1,zhai1 && 初始化数组
SELECT 5 && 选择工作区
USE zy && 打开表，摘要
COPY TO ARRAY zhai && 复制到数组
FOR win=1 TO 20 && 循环
zhai1(win)=zhai(win,1) && 赋值
NEXT && 下一个循环
PUBLIC mxj(300,2),mxj1(300),ax(300) && 定维公共数组
PUBLIC riqi,kmmxgs && 定义公共变量
STORE { . . } TO riqi && 初始化日期为空
STORE 0 TO kmmxgs && 初始化科目明细个数
RETURN && 过程结束，返回主程序
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -