dws2mflibfuncs.pas

script language

{**********************************************************************}
{                                                                      }
{    dws2MFLib                                                         }
{                                                                      }
{    A function library for DWSII                                      }
{    Version 1.0 Beta                                                  }
{    July 2001                                                         }
{                                                                      }
{    This software is distributed on an "AS IS" basis,                 }
{    WITHOUT WARRANTY OF ANY KIND, either express or implied.          }
{                                                                      }
{    The Initial Developer of the Original Code is Manfred Fuchs       }
{    Portions created by Manfred Fuchs are Copyright                   }
{    (C) 2001 Manfred Fuchs, Germany. All Rights Reserved.             }
{                                                                      }
{**********************************************************************}

unit dws2MFLibFuncs;

interface

uses
  Windows, SysUtils, Controls, Forms, StdCtrls, Buttons, Classes, ShellApi,
  Dialogs, CommDlg, TLHelp32, Messages, MMSystem;

const
  SK_None = 0;
  SK_WindowNotFound = 1;
  SK_WindowNotActive = 2;

  RAS_MaxDeviceType = 16;
  RAS_MaxDeviceName = 128;
  RAS_MaxEntryName = 256;

  FILEDATE_CREATION = 1;
  FILEDATE_LASTACCESS = 2;
  FILEDATE_LASTWRITE = 3;

  VER_UNKNOWN = $0000;
  VER_WIN32S = $0001;
  VER_WIN95 = $1000;
  VER_WIN98 = $1010;
  VER_WIN98SE = $1030;
  VER_WINME = $1070;
  VER_WINNT = $2000;
  VER_WINNT4 = $2010;
  VER_WIN2000 = $2030;
  VER_WIN32 = $3000;

type
  TOpenFileNameEx = packed record
    lStructSize: DWORD;
    hWndOwner: HWND;
    hInstance: HINST;
    lpstrFilter: PAnsiChar;
    lpstrCustomFilter: PAnsiChar;
    nMaxCustFilter: DWORD;
    nFilterIndex: DWORD;
    lpstrFile: PAnsiChar;
    nMaxFile: DWORD;
    lpstrFileTitle: PAnsiChar;
    nMaxFileTitle: DWORD;
    lpstrInitialDir: PAnsiChar;
    lpstrTitle: PAnsiChar;
    Flags: DWORD;
    nFileOffset: Word;
    nFileExtension: Word;
    lpstrDefExt: PAnsiChar;
    lCustData: LPARAM;
    lpfnHook: function(Wnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): UINT
      stdcall;
    lpTemplateName: PAnsiChar;
    pvReserved: Pointer;
    dwReserved: DWORD;
    FlagsEx: DWORD;
  end;

  TExtOpenDialog = class(TOpenDialog)
  protected
    FInterceptor: Pointer;
    function IsWin2000orME: Boolean;
  public
    constructor Create(AOwner: TComponent); override;
    function Execute: Boolean; override;
  end;

  TExtSaveDialog = class(TExtOpenDialog)
  public
    constructor Create(AOwner: TComponent); override;
    function Execute: Boolean; override;
  end;

  PWinRec = ^TWinRec;
  TWinRec = record
    ClassName: string;
    WindowName: string;
    ProcID: DWord;
    Handle: HWnd;
    Child: HWnd;
    Num: Integer;
  end;
  TRasConn = record
    Size: DWORD;
    Handle: THandle;
    EntryName: array[0..RAS_MaxEntryName] of Char;
    DeviceType: array[0..RAS_MaxDeviceType] of Char;
    DeviceName: array[0..RAS_MaxDeviceName] of Char;
  end;
  TRasEnumConnections = function(RasConn: Pointer; var cb: DWORD;
    var Connections: DWORD): DWORD; stdcall;

function DescListCreate(verz: string): TStringList;
function DescListRead(list: TStringList; dat: string): string;
function DescRead(dat: string): string;
function DescWrite(dat, desc: string): Boolean;

function DirectoryExists(const Name: string): Boolean;
function FileDate(const FileName: string; Flag: Integer): TDateTime;
function FileSize(const FileName: string): Int64;
function MakePath(const Drive, Dir, Name, Ext: string): string;
function ReadOnlyPath(const Path: string): Boolean;
procedure SplitPath(const Path: string; var Drive, Dir, Name, Ext: string);
function SubdirectoryExists(const Dir: string): Boolean;
function ScanForFiles(Filename: string; Recurse, Hidden, IncludeFiles, IncludeDirs:
  Boolean): TStringList;

function CDClose(Drive: Integer): Boolean; overload;
function CDClose(Drive: string): Boolean; overload;
function CDOpen(Drive: Integer): Boolean; overload;
function CDOpen(Drive: string): Boolean; overload;
function DriveName(Drive: Integer): string; overload;
function DriveName(Drive: string): string; overload;
function DriveReady(Drive: Integer): Boolean; overload;
function DriveReady(Drive: string): Boolean; overload;
function DriveSerial(Drive: Integer): string; overload;
function DriveSerial(Drive: string): string; overload;
function DriveType(Drive: Integer): Integer; overload;
function DriveType(Drive: string): Integer; overload;

function GetWindowsVersion: Integer;
function IsWin2000: Boolean;
function IsWin9x: Boolean;
function IsWinNT: Boolean;
function IsWinNT4: Boolean;
function ExecAndWait(const Filename, Params, Dir: string; WindowState: Word):
  Boolean;
function GetCPUSpeed: Double;
function GetCRC32FromString(S: string): Integer;
function GetCRC32FromFile(FileName: string): Integer;

function ChangeTokenValue(str, name, value, delim: string): string;
procedure FormatColumns(sl: TStringList; delim: Char; space: string; adjust:
  Integer);
function GetStringFromList(sl: TStringList; delim: Char): string;
function GetTokenList(str, delim: string; repeater, ignorefirst, ignorelast:
  Boolean): TStringList;
function PosX(substr, s: string): Integer;

function ANSI2OEM(s: string): string;
function OEM2ANSI(s: string): string;
function Translate(s: string; tout, tin: string; fill: Char; f: Boolean): string;

function CmpWC(source, wc: string; cf: Boolean): Boolean;
function IncWC(source, wc: string; cf: Boolean; var ebene: Integer): string;
function TestWC(wc: string): Integer;

function SearchWindow(var cName, wName: string; ProcID: DWord = 0): HWnd;
function SearchWindowEx(Parent, Child: HWnd; var cName, wName: string; Num: Integer
  = 0): HWnd;
function WaitForWindow(var cName, wName: string; Timeout: DWord; ProcID: DWord =
  0): HWnd;
function WaitForWindowClose(var cName, wName: string; Timeout: DWord; ProcID: DWord
  = 0): Boolean; overload;
function WaitForWindowClose(w: HWnd; Timeout: DWord): Boolean; overload;
function WaitForWindowEnabled(var cName, wName: string; Timeout: DWord; ProcID:
  DWord = 0): Boolean; overload;
function WaitForWindowEnabled(w: HWnd; Timeout: DWord): Boolean; overload;
function WaitForWindowEx(Parent: HWnd; var cName, wName: string; Timeout: DWord;
  Num: Integer = 0): HWnd;
procedure WindowMove(w: HWnd; x, y: Integer; Abs: Boolean);
procedure WindowResize(w: HWnd; x, y: Integer; Abs: Boolean);

function SendKeysWin(w, s: string; wait: Integer = 0; back: Boolean = False):
  Integer; overload;
function SendKeysWin(w: HWnd; s: string; wait: Integer = 0; back: Boolean = False):
  Integer; overload;
procedure SendKeys(s: string; wait: Integer = 0);

function SelectStringDialog(Title: String; Strings: TStringList; Selected: Integer): Integer;

function GetOpenFileNameEx(var OpenFile: TOpenFilenameEx): Boolean; stdcall;
function GetSaveFileNameEx(var OpenFile: TOpenFilenameEx): Boolean; stdcall;

implementation

function GetOpenFileNameEx; external 'comdlg32.dll' name 'GetOpenFileNameA';
function GetSaveFileNameEx; external 'comdlg32.dll' name 'GetSaveFileNameA';

const
  BUFLEN = 65536;
{$WARNINGS OFF}
  aTableCRC32: array[0..255] of LongInt = (
    {;           $}
    $00000000, $77073096, $EE0E612C, $990951BA,
    $076DC419, $706AF48F, $E963A535, $9E6495A3,
    $0EDB8832, $79DCB8A4, $E0D5E91E, $97D2D988,
    $09B64C2B, $7EB17CBD, $E7B82D07, $90BF1D91,
    {;            1}
    $1DB71064, $6AB020F2, $F3B97148, $84BE41DE,
    $1ADAD47D, $6DDDE4EB, $F4D4B551, $83D385C7,
    $136C9856, $646BA8C0, $FD62F97A, $8A65C9EC,
    $14015C4F, $63066CD9, $FA0F3D63, $8D080DF5,
    {;            2}
    $3B6E20C8, $4C69105E, $D56041E4, $A2677172,
    $3C03E4D1, $4B04D447, $D20D85FD, $A50AB56B,
    $35B5A8FA, $42B2986C, $DBBBC9D6, $ACBCF940,
    $32D86CE3, $45DF5C75, $DCD60DCF, $ABD13D59,
    {;            3}
    $26D930AC, $51DE003A, $C8D75180, $BFD06116,
    $21B4F4B5, $56B3C423, $CFBA9599, $B8BDA50F,
    $2802B89E, $5F058808, $C60CD9B2, $B10BE924,
    $2F6F7C87, $58684C11, $C1611DAB, $B6662D3D,
    {;            4}
    $76DC4190, $01DB7106, $98D220BC, $EFD5102A,
    $71B18589, $06B6B51F, $9FBFE4A5, $E8B8D433,
    $7807C9A2, $0F00F934, $9609A88E, $E10E9818,
    $7F6A0DBB, $086D3D2D, $91646C97, $E6635C01,
    {;            5}
    $6B6B51F4, $1C6C6162, $856530D8, $F262004E,
    $6C0695ED, $1B01A57B, $8208F4C1, $F50FC457,
    $65B0D9C6, $12B7E950, $8BBEB8EA, $FCB9887C,
    $62DD1DDF, $15DA2D49, $8CD37CF3, $FBD44C65,
    {;            6}
    $4DB26158, $3AB551CE, $A3BC0074, $D4BB30E2,
    $4ADFA541, $3DD895D7, $A4D1C46D, $D3D6F4FB,
    $4369E96A, $346ED9FC, $AD678846, $DA60B8D0,
    $44042D73, $33031DE5, $AA0A4C5F, $DD0D7CC9,
    {;            7}
    $5005713C, $270241AA, $BE0B1010, $C90C2086,
    $5768B525, $206F85B3, $B966D409, $CE61E49F,
    $5EDEF90E, $29D9C998, $B0D09822, $C7D7A8B4,
    $59B33D17, $2EB40D81, $B7BD5C3B, $C0BA6CAD,
    {;            8}
    $EDB88320, $9ABFB3B6, $03B6E20C, $74B1D29A,
    $EAD54739, $9DD277AF, $04DB2615, $73DC1683,
    $E3630B12, $94643B84, $0D6D6A3E, $7A6A5AA8,
    $E40ECF0B, $9309FF9D, $0A00AE27, $7D079EB1,
    {;            9}
    $F00F9344, $8708A3D2, $1E01F268, $6906C2FE,
    $F762575D, $806567CB, $196C3671, $6E6B06E7,
    $FED41B76, $89D32BE0, $10DA7A5A, $67DD4ACC,
    $F9B9DF6F, $8EBEEFF9, $17B7BE43, $60B08ED5,
    {;            A}
    $D6D6A3E8, $A1D1937E, $38D8C2C4, $4FDFF252,
    $D1BB67F1, $A6BC5767, $3FB506DD, $48B2364B,
    $D80D2BDA, $AF0A1B4C, $36034AF6, $41047A60,
    $DF60EFC3, $A867DF55, $316E8EEF, $4669BE79,
    {;            B}
    $CB61B38C, $BC66831A, $256FD2A0, $5268E236,
    $CC0C7795, $BB0B4703, $220216B9, $5505262F,
    $C5BA3BBE, $B2BD0B28, $2BB45A92, $5CB36A04,
    $C2D7FFA7, $B5D0CF31, $2CD99E8B, $5BDEAE1D,
    {;            C}
    $9B64C2B0, $EC63F226, $756AA39C, $026D930A,
    $9C0906A9, $EB0E363F, $72076785, $05005713,
    $95BF4A82, $E2B87A14, $7BB12BAE, $0CB61B38,
    $92D28E9B, $E5D5BE0D, $7CDCEFB7, $0BDBDF21,
    {;            D}
    $86D3D2D4, $F1D4E242, $68DDB3F8, $1FDA836E,
    $81BE16CD, $F6B9265B, $6FB077E1, $18B74777,
    $88085AE6, $FF0F6A70, $66063BCA, $11010B5C,
    $8F659EFF, $F862AE69, $616BFFD3, $166CCF45,
    {;            E}
    $A00AE278, $D70DD2EE, $4E048354, $3903B3C2,
    $A7672661, $D06016F7, $4969474D, $3E6E77DB,
    $AED16A4A, $D9D65ADC, $40DF0B66, $37D83BF0,
    $A9BCAE53, $DEBB9EC5, $47B2CF7F, $30B5FFE9,
    {;            F}
    $BDBDF21C, $CABAC28A, $53B39330, $24B4A3A6,
    $BAD03605, $CDD70693, $54DE5729, $23D967BF,
    $B3667A2E, $C4614AB8, $5D681B02, $2A6F2B94,
    $B40BBE37, $C30C8EA1, $5A05DF1B, $2D02EF8D
    );
{$WARNINGS ON}

var
  start: string;

function OpenInterceptor(var DialogData: TOpenFileName): Boolean; stdcall;
var
  DialogDataEx: TOpenFileNameEx;
begin
  Move(DialogData, DialogDataEx, Sizeof(DialogData));
  DialogDataEx.FlagsEx := 0;
  DialogDataEx.lStructSize := Sizeof(TOpenFileNameEx);
  Result := GetOpenFileNameEx(DialogDataEx);
end;

function SaveInterceptor(var DialogData: TOpenFileName): Boolean; stdcall;
var
  DialogDataEx: TOpenFileNameEx;
begin
  Move(DialogData, DialogDataEx, Sizeof(DialogData));
  DialogDataEx.FlagsEx := 0;
  DialogDataEx.lStructSize := Sizeof(TOpenFileNameEx);
  Result := GetSaveFileNameEx(DialogDataEx);
end;

constructor TExtOpenDialog.Create(AOwner: TComponent);
begin
  inherited;
  FInterceptor := @OpenInterceptor;
end;

function TExtOpenDialog.Execute: Boolean;
begin
  if IsWin2000orME then
  begin
    Result := DoExecute(FInterceptor);
  end
  else
    Result := inherited Execute;
end;

function TExtOpenDialog.IsWin2000orME: Boolean;
var
  Ver: TOSVersionInfo;
begin
  Result := False;
  Ver.dwOSVersionInfoSize := Sizeof(TOSVersionInfo);
  if not GetVersionEx(Ver) then
    Exit;
  if (Ver.dwPlatformId = VER_PLATFORM_WIN32_NT) then
  begin
    if (Ver.dwMajorVersion >= 5) then
      Result := True;
  end
  else if ((Ver.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS) and
    (Ver.dwMajorVersion >= 4) and
    (Ver.dwMinorVersion >= 90)) then
    Result := True;
end;

constructor TExtSaveDialog.Create(AOwner: TComponent);
begin
  inherited;
  FInterceptor := @SaveInterceptor;
end;

function TExtSaveDialog.Execute: Boolean;
begin
  if IsWin2000orME then
    Result := inherited Execute
  else
    Result := DoExecute(@GetSaveFileName);
end;

// ****************************************************************************

function CRC32Calc(var Buf; CRC: Integer; BufSize: Integer): Integer; assembler;
asm
    push esi
    mov esi,Buf
@1:
    movzx eax,byte ptr [esi]
    inc ESI
    xor al,dl
    shr edx,8
    xor edx,dword ptr [atablecrc32+eax*4]
    Loop @1
    mov eax,edx
    pop esi
end;

function EnumWindowsProc(w: HWnd; lp: LParam): Boolean; stdcall;
var
  cn: array[0..1023] of Char;
  wn: array[0..1023] of Char;
  id: DWord;
  Found: Boolean;
  p: PWinRec;
begin
  Result := True;
  p := PWinRec(lp);

  if p^.Child <> 0 then
  begin
    if w = p^.Child then
      p^.Child := 0;
    Exit;
  end;

  wn[0] := #0;
  GetWindowText(w, wn, 1023);
  if (GetClassName(w, cn, 1023) = 0) or
    (GetWindowThreadProcessId(w, @id) = 0) then
    Exit;

  Found := True;

  if (p^.ClassName <> '') and
    not CmpWC(string(cn), p^.ClassName, True) then
    Found := False;

  if Found then
    if (p^.WindowName <> '') and
      not CmpWC(string(wn), p^.WindowName, True) then
      Found := False;

  if Found then
    if (p^.ProcID <> 0) and
      (id <> p^.ProcID) then
      Found := False;

  if Found then
  begin
    if p^.Num > 0 then
      Dec(p^.Num)
    else
    begin
      p^.Handle := w;
      p^.ClassName := string(cn);
      p^.WindowName := string(wn);
      p^.ProcID := id;
      Result := False;
    end;
  end;
end;

// ****************************************************************************

function DescListCreate(verz: string): TStringList;
var
  Pfad: string;
  Liste: TStringList;
  Laenge: Integer;
begin
  Liste := TStringList.Create;
  Pfad := verz;
  Laenge := Length(Pfad);
  if (Laenge > 0) and (Pfad[Laenge] <> ':') and (Pfad[Laenge] <> '\') then
    Pfad := Pfad + '\';
  Pfad := Pfad + 'DESCRIPT.ION';
  if FileExists(Pfad) then
    Liste.LoadFromFile(Pfad);
  Result := Liste;
end;

function DescListRead(list: TStringList; dat: string): string;
var
  Datei: string;
  Anzahl: Integer;
  Loop: Integer;
  Laenge: Integer;
begin
  Result := '';

  Anzahl := list.Count;
  if Anzahl = 0 then
    Exit
  else
  begin
    Datei := ExtractFileName(dat);
    if Pos(' ', Datei) > 0 then
      Datei := '"' + Datei + '"';
    Laenge := Length(Datei);

    for Loop := 0 to (Anzahl - 1) do
    begin
      if (AnsiCompareText(Datei, Copy(list[Loop], 1, Laenge)) = 0) and
        (list[Loop][Laenge + 1] = ' ') then
      begin
        Result := OEM2ANSI(Copy(list[Loop], Laenge + 2, 1024));
        Exit;
      end;
    end;
  end;
end;

function DescRead(dat: string): string;
var
  DatIn: TextFile;
  Pfad: string;
  Datei: string;
  Zeile: string;
  Laenge: Integer;
begin
  Result := '';

  Pfad := ExtractFilePath(dat) + 'DESCRIPT.ION';

  Datei := ExtractFileName(dat);
  if Pos(' ', Datei) > 0 then
    Datei := '"' + Datei + '"';
  Laenge := Length(Datei);

  if FileExists(Pfad) then
  begin
    AssignFile(DatIn, Pfad);
    Reset(DatIn);
    while not SeekEof(DatIn) do
    begin
      ReadLn(DatIn, Zeile);
      if (AnsiCompareText(Datei, Copy(Zeile, 1, Laenge)) = 0) and
        (Zeile[Laenge + 1] = ' ') then
      begin
        CloseFile(DatIn);
        Result := OEM2ANSI(Copy(Zeile, Laenge + 2, 1024));
        Exit;
      end;
    end;
    CloseFile(DatIn);
  end;
end;

function DescWrite(dat, desc: string): Boolean;
var
  Pfad: string;
  Datei: string;
  Liste: TStringList;
  Anzahl: Integer;
  Loop: Integer;
  Laenge: Integer;
  InList: Boolean;
  CPfad: array[0..MAX_PATH] of char;
begin
  try
    Liste := TStringList.Create;

    Pfad := ExtractFilePath(dat) + 'DESCRIPT.ION';
    StrPCopy(CPfad, Pfad);
    desc := ANSI2OEM(desc);

    Datei := UpperCase(ExtractFileName(dat));
    if Pos(' ', Datei) > 0 then
      Datei := '"' + Datei + '"';
    Laenge := Length(Datei);

    SetFileAttributes(CPfad, FILE_ATTRIBUTE_NORMAL);

    if FileExists(Pfad) then
      Liste.LoadFromFile(Pfad);

    InList := False;

    Anzahl := Liste.Count;
    if Anzahl > 0 then
    begin
      for Loop := 0 to (Anzahl - 1) do
      begin
        if (AnsiCompareText(Datei, Copy(Liste[loop], 1, Laenge)) = 0) and
          (Liste[loop][Laenge + 1] = ' ') then
        begin
          if desc = '' then
            Liste.Delete(loop)
          else
            Liste[loop] := Datei + ' ' + desc;
          InList := True;
          Break;
        end;
      end;
    end;

    if (InList = False) and