triggerdemo23.sql

来自「T-SQL示例大全」· SQL 代码 · 共 72 行

/*
文件名称: TriggerDemo23.sql
目        的: 示范如何利用 INSTEAD OF UPDATE 触发程序去更新视图的来源数据表
*/
USE 北风贸易
GO

IF exists (select * from dbo.sysobjects where id = object_id(N'dbo.BaseTable') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
    DROP TABLE dbo.BaseTable
GO

IF exists (select * from dbo.sysobjects where id = object_id(N'dbo.InsteadView') and OBJECTPROPERTY(id, N'IsView') = 1)
    DROP VIEW dbo.InsteadView
GO

-- 建立一个数据表
CREATE TABLE BaseTable
(
编号 int IDENTITY(1,1),
颜色 nvarchar(10) NOT NULL,
材质 nvarchar(10) NOT NULL,
颜色材质 AS (颜色 + 材质)
)
GO

-- 先新增一些数据记录至数据表
INSERT INTO BaseTable (颜色, 材质) VALUES (N'蓝色', N'塑胶')
INSERT INTO BaseTable (颜色, 材质) VALUES (N'红色', N'木头')
INSERT INTO BaseTable (颜色, 材质) VALUES (N'白色', N'棉花')

-- 查看数据表的数据记录
SELECT * FROM BaseTable
GO

-- 建立一个包含来源数据表所有字段的视图
CREATE VIEW InsteadView
AS
SELECT 编号, 颜色, 材质, 颜色材质 FROM BaseTable
GO

-- 为视图建立一个 INSTEAD OF UPDATE 触发程序
CREATE TRIGGER InsteadUpdateTrigger
ON InsteadView
INSTEAD OF UPDATE
AS
BEGIN
  -- 使用 UPDATE 命令将 inserted 数据表中的数据为换至
  -- 来源数据表，但是避开「inserted.编号」与「inserted.颜色材质」字段
  UPDATE BaseTable
       SET 颜色 = inserted.颜色,材质 = inserted.材质
       FROM inserted
       WHERE BaseTable.编号 = inserted.编号
END
GO

-- 更新视图的数据记录
UPDATE InsteadView
     SET 颜色 = N'Red', 材质 = N'Soft'
     WHERE 编号 = 2

-- 查看执行 UPDATE 命令后，视图的数据记录有何变化
SELECT 编号, 颜色, 材质, 颜色材质
    FROM InsteadView

GO

-- 查看执行 UPDATE 命令后，数据表的数据记录有何变化
SELECT 编号, 颜色, 材质, 颜色材质
    FROM BaseTable

GO