triggerdemo22.sql

T-SQL示例大全

/*
文件名称: TriggerDemo22.sql
目        的: 示范如何利用 INSTEAD OF INSERT触发程序将数据新增至视图的来源数据表
*/
USE 北风贸易
GO

IF exists (select * from dbo.sysobjects where id = object_id(N'dbo.BaseTable') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
    DROP TABLE dbo.BaseTable
GO

IF exists (select * from dbo.sysobjects where id = object_id(N'dbo.InsteadView') and OBJECTPROPERTY(id, N'IsView') = 1)
    DROP VIEW dbo.InsteadView
GO

-- 建立一个数据表
CREATE TABLE BaseTable
(
编号 int IDENTITY(1,1),
颜色 nvarchar(10) NOT NULL,
材质 nvarchar(10) NOT NULL,
颜色材质 AS (颜色 + 材质)
)
GO

-- 建立一个包含来源数据表所有字段的视图
CREATE VIEW InsteadView
AS
SELECT 编号, 颜色, 材质, 颜色材质 FROM BaseTable
GO

-- 为视图建立一个 INSTEAD OF INSERT 触发程序
CREATE TRIGGER InsteadInsertTrigger
ON InsteadView
INSTEAD OF INSERT
AS
BEGIN
  -- 使用 INSERT 命令将 inserted 数据表中的数据记录新增至
  -- 来源数据表,但是避开「inserted.编号」与「inserted.颜色材质」字段
  INSERT BaseTable
       SELECT 颜色,材质 FROM inserted
END
GO

-- 将数据记录新增至视图，若未指定「编号」与「颜色材质」
-- 字段将会出现错误。
INSERT InsteadView (编号,颜色, 材质, 颜色材质)
       VALUES (999,N'白色', N'棉花', N'XXXXXX')
GO

-- 将数据记录新增至视图，若未指定「编号」与「颜色材质」
-- 字段将会出现错误。
INSERT InsteadView (编号, 颜色, 材质, 颜色材质)
       VALUES (999, N'蓝色', N'塑胶', N'XXXXXX')
GO

-- 查阅视图的数据内容
SELECT 编号, 颜色, 材质, 颜色材质
    FROM InsteadView

GO

-- 查阅数据表的数据内容
SELECT 编号, 颜色, 材质, 颜色材质
    FROM BaseTable

GO