dspsec.asm

一个微型操作系统源码

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Project 			:DSKEDT-FDOS 0.0.7
;; Author 			:Ottonello, Santiago
;; E-Mail				:[e-mail]
;; Webpage 			:http://www.visual-opal.de
;; Date	 			:22.8.2003
;; Caption	 		:Disk Editor
;; Filename			:DSPSEC.ASM
;; Function			:Display Sector Routines
;; Notes				:Shamelesly stolen fron Peter Norton and
;;				 Jhon Socha. Thank you Guys...
;;				 Adapted to FDOS by me...
;; Compile Syntax	 		:nasm DSKEDT.ASM -f bin  -o DSKEDT.BIN
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

BEGSR	DSPLIN
	SAVREG	BX,CX,DX
	

	mov	BX,	DX	
	push	BX
	
	mov	dl,	' '
	mov	CX,	3
	EXSR	RPTCHR
	
	cmp	bx,	100h
	IF	b
	PRTCHR	' '
	ELSE
	PRTCHR	'1'
	ENDIF
	mov	dl,	bl
	EXSR	WRTHEX
	PRTCHR	' '
	PRTCHR	verbar
	PRTCHR	' '
	mov	CX,	16
  .HEXLOP:
	mov	dl,	[sector+bx]
	EXSR	WRTHEX
	PRTCHR	' '	
	inc	BX
	loop	.HEXLOP	
	PRTCHR	verbar
	PRTCHR	' '	
	mov	CX,	16
	pop	BX
  .ASCLOP:
  	mov	dl,	[sector+bx]
  	EXSR	WRTCHR
  	inc	BX
  	loop	.ASCLOP
  	PRTCHR	' '
  	PRTCHR	verbar
  	RSTREG	BX,CX,DX
ENDSR

BEGSR	DSPHSE
	SAVREG	CX,DX
	mov	CX,	16
  .HALSEC:
  	EXSR	DSPLIN
  	PRTSTR	CRLF
  	add	DX,	16
  	loop	.HALSEC
  	RSTREG	CX,DX
ENDSR

BEGSR	INZSED
	SAVREG	DX
	xor	dl,	dl
	mov	dh,	[linbse]
	EXSR	GOTOXY
	EXSR	WRTTON
	mov	DX,	toppat
	EXSR	WRTPAT
	PRTSTR	CRLF
	xor	DX,	DX
	mov	[secoff],	DX
	EXSR	DSPHSE
	mov	DX,	botpat
	EXSR	WRTPAT
	EXSR	WRTPHA
	RSTREG	DX	
ENDSR

BEGSR	WRTTON
	SAVREG	CX,DX
	mov	dl,	' '
	mov	CX,	9
	EXSR	RPTCHR
	xor	dh,	dh
  .HEXLOP:
  	mov	dl,	dh	
  	EXSR	WRTHEX
  	mov	dl,	' '
  	EXSR	WRTCHR
  	inc	dh	
  	cmp	dh,	10H
  	jb	.HEXLOP
  	mov	dl,	' '
  	mov	CX,	2
  	EXSR	RPTCHR
  	xor	dl,	dl
  .HEXDIG:
  	EXSR	WRTHED
  	inc	dl
  	cmp	dl,	10H
  	jb	.HEXDIG
  	PRTSTR	CRLF  	  	
	RSTREG	CX,DX
ENDSR

BEGSR	WRTHDR
	SAVREG	DX
	xor	dl,	dl
	mov	dh,	[hdrlin]
	EXSR	GOTOXY
	PRTSTR	pgmcap
	PRTSTR	hdrtx1
	mov	dl,	[dskdrv]
	add	dl,	'A'
	EXSR	WRTCHR
	PRTSTR	hdrtx2
	mov	dx,	[cursec]
	EXSR	WRTDEC
	EXSR	CLREOL
	RSTREG	DX
ENDSR

BEGSR	WRTPRO
	SAVREG	DX
	xor	dl,	dl
	mov	dh,	[prolin]
	EXSR	GOTOXY
	PRTSTR	edipro
	EXSR	CLREOL
	RSTREG	DX
ENDSR

BEGSR	SECDSP
	CLRSCR
	EXSR	WRTHDR
	EXSR	REDSEC
	EXSR	INZSED
	EXSR	WRTPRO
ENDSR