npc_card_remover.txt

制作网络游戏的一个小平台

// Card removal NPC by TyrNemesis^ 日本語訳：胡蝶蘭
prontera.gat,147,110,5	script	神秘妇女	78,{
	mes "[神秘妇女]";
	mes "你好啊~~年轻人！";
	mes "想要卸除装载在装备上的卡片吗？";
	mes "我可以使用魔法来帮你这个忙！";
	mes "不过你必须支付一定的费用喔！";
	next;
	menu "好啊！看来真不错。",REMOVEMENU,
	     "你是如何收费的呀？",REMOVEPRICE,
	     "不了，谢谢。",CLOSEOUT;

REMOVEPRICE:
	mes "[神秘妇女]";
	mes "嗯....卸除一件装备需要支付^4040FF200000z^000000Zeny。";
	mes "一张卡片加收^4040FF25000z^000000Zeny。";
	mes "另外，我需要一些^4040FF星星的角^000000和";
	mes "^4040FF黄色魔力矿石^000000来辅助我的魔法。";
	next;
	menu "好啊，那帮我卸除吧。",REMOVEMENU,
	     "想想还是算了。",CLOSEOUT;

REMOVEMENU:
	mes "[神秘妇女]";
	mes "HOO~你想我帮你卸除哪一件装备呢？";
	next;
	menu "嗯..卸除..让我想想。",CLOSEOUT,
	     getequipname(1),SLOT1,
	     getequipname(2),SLOT2,
	     getequipname(3),SLOT3,
	     getequipname(4),SLOT4,
	     getequipname(5),SLOT5,
	     getequipname(6),SLOT6,
	     getequipname(7),SLOT7,
	     getequipname(8),SLOT8,
	     getequipname(9),SLOT9,
	     getequipname(10),SLOT10;

SLOT1:
	set @part,1;
	goto CARDNUMCHECK;

SLOT2:
	set @part,2;
	goto CARDNUMCHECK;

SLOT3:
	set @part,3;
	goto CARDNUMCHECK;

SLOT4:
	set @part,4;
	goto CARDNUMCHECK;

SLOT5:
	set @part,5;
	goto CARDNUMCHECK;

SLOT6:
	set @part,6;
	goto CARDNUMCHECK;

SLOT7:
	set @part,7;
	goto CARDNUMCHECK;

SLOT8:
	set @part,8;
	goto CARDNUMCHECK;

SLOT9:
	set @part,9;
	goto CARDNUMCHECK;

SLOT10:
	set @part,10;
	goto CARDNUMCHECK;

CARDNUMCHECK:
	if(getequipcardcnt(@part) == 0) goto DENYCARDCOUNT;
	set @cardcount,getequipcardcnt(@part);
	mes "[神秘妇女]";
	mes "这件装备的插槽上已经插上了" + @cardcount + "张卡片。";
	mes "你必须支付^0000FF" + (200000+(@cardcount * 25000)) + "Zeny^000000和^0000FF星星的角^000000和^0000FF黄色魔力矿石^000000。";
	next;
	menu "这些我都带来了。",REMOVECARDWARNING,
	     "我还没有准备好。",CLOSEOUT;

REMOVECARDWARNING:
	mes "[神秘妇女]";
	mes "在开始之前我得先告诉你。";
	mes "使用这种魔法万一失败，";
	mes "^FF4040可能会损坏了卡片或装备、^000000。";
	mes "万一损坏了";
	mes "我可^FF4040不会赔偿^000000给你的喔~~";
	mes "所以，你必须考虑清楚。";
	next;
	mes "[神秘妇女]";
	mes "如果损坏的话^FF4040你想保留卡片还是装备^000000呢、";
	next;
	menu "想想还是算了。",CLOSEOUT,
	     "保留装备。",PRIORITYITEM,
	     "保留卡片。",PRIORITYCARD;

PRIORITYITEM:
	set @failtype,1;
	goto REMOVECARD;

PRIORITYCARD:
	set @failtype,2;
	goto REMOVECARD;

REMOVECARD:
	mes "[神秘妇女]";
	mes "很好！那我开始了~~。";
	next;
	if((zeny < (200000+(@cardcount * 25000))) || (countitem(1000) < 1) || (countitem(715) < 1)) goto DENYMATERIAL;
	set zeny,zeny - (200000+(@cardcount * 25000));
	delitem 1000,1;
	delitem 715,1;

// Replace the constants in the next 3 lines with failure chance values defined in refine_db.txt
// First value = Total failure chance (item and cards destroyed)
// Second value = Partial failure chance (one or the other is destroyed, player decides which one is safe)
// Third value = Harmless failure chance (all that's lost is your investment)

	set @failchance,rand(100);
	if(@failchance < 2) goto FAILREMOVECARD0;
	if((@failchance < 6) && (@failtype == 1)) goto FAILREMOVECARD1;
	if((@failchance < 6) && (@failtype == 2)) goto FAILREMOVECARD2;
	if(@failchance < 10) goto FAILREMOVECARD3;
	emotion 18;
	successremovecards @part;
	mes "[神秘妇女]";
	mes "大功告成啦！";
	mes "这是你的卡片和你的道具，再见！";
	close;

FAILREMOVECARD0:
	emotion 4;
	mes "[神秘妇女]";
	mes "最担心的事情终于发生了...";
	mes "对不起，卡片坏掉了.....";
	failedremovecards @part,0;
	close;

FAILREMOVECARD1:
	emotion 4;
	mes "[神秘妇女]";
	mes "尽管我已经设法将卡片从装备的插槽中卸除、";
	mes "但它们还是被损坏了。幸好，装备还是好的。";
	failedremovecards @part,1;
	close;

FAILREMOVECARD2:
	emotion 4;
	mes "[神秘妇女]";
	mes "不幸的消息....";
	mes "卡片是卸除下来了，";
	mes "可是装备在卸除过程中被破坏了。";
	failedremovecards @part,2;
	close;

FAILREMOVECARD3:
	emotion 4;
	mes "[神秘妇女]";
	mes "不行不行，卸除失败了....";
	mes "幸好，卸除过程中卡片和装备还依然完好。";
	failedremovecards @part,3;
	close;

DENYCARDCOUNT:
	emotion 5;
	mes "[神秘妇女]";
	mes "年轻人...。";
	mes "这件装备上面并没有卡片呀~~~。";
	close;

DENYMATERIAL:
	mes "[神秘妇女]";
	mes "你并没有把我需要的材料带来呀。";
	mes "还是把东西都带齐了再来找我吧！";
	mes "再说，我的付出也应该得要有所收获嘛！";
	close;

CLOSEOUT:
	mes "[神秘妇女]";
	mes "很好，如果需要。";
	mes "我愿意随时为你服务。";
	close;

}