npc_archer.txt

制作网络游戏的一个小平台

//Archer Quest for Athena by BeerNuts
//Edited by Akaru
// modify by robert 蝴蝶君 2004-2-24 Mail:[e-mail] QQ:920439

payon_in02.gat,64,71,4	script	弓箭手工会相关人员	85,{
	if(@test_AR !=0)
		goto ContM0BeArc;
	mes "[弓箭手工会相关人员]";
	mes "你好，这里是弓箭手工会，有什么可以帮您的吗？";
	next;
	menu "转职成为弓箭手",M0,"询问转职相关条件",M1,"离开",MEnd;
	M0:
		if(Class==3) goto JobArc;
		if(Class !=3 && Class !=0 )
			goto NotAny;
		goto M0BeArc;
	JobArc:
		mes "[弓箭手工会相关人员]";
		mes "你已经是弓箭手了。";
		close;

	NotAny:
		mes "[弓箭手工会相关人员]";
		mes "你的样子看来不像是初学者..你已经是选择其他职业，无法转职为弓箭手。";
		close;
	M0BeArc:
		mes "[弓箭手工会相关人员]";
		mes "你想要转职成为弓箭手吗？那么你必须通过我们的一项测试。";
		next;
		menu "参加测试",M00,"放弃",M0End;

	M0End:
		mes "[弓箭手工会相关人员]";
		mes "那你.. 多多保重。";
		close;

	M00:
		if(JobLevel < 10) goto NotLvl;
		goto M001;

	NotLvl:
		mes "[弓箭手工会相关人员]";
		mes "你的基本技能等级还不够，请你再看看转职条件，等你基本技能等级到达9级以上再来。";
		close;

			M001:
				mes "[弓箭手工会相关人员]";
				mes "请在申请书上签名，接下来若你具备好所有转职条件的话，就马上给你转职。";
				set @test_AR,1;
				next;
				mes "[弓箭手工会相关人员]";
				mes "你的大名是"+ strcharinfo(0) +"吧？现在我将为你的测试给予指导，你是否能够成功的转职成为一名弓箭手全依赖它，因此请你专心。";
				next;
				mes "[弓箭手工会相关人员]";
				mes "弓箭手的转职条件是必须带来制作弓所需要的^FF0000树枝^000000，你所带来的树枝分为4个类级後，将与其他道具数量合算在一起给你分数。";
				mes "因此，你的总点40^0000FF再加上25 点以上^000000才可以转职为弓箭手。";
				next;
				mes "[弓箭手工会相关人员]";
				mes "这里有一点提示：树枝是打赢了'树精'可以取得，虽然他不是很强的敌手，但你也不要掉以轻心。";
				close;

	ContM0BeArc:
		mes "[弓箭手工会相关人员]";
		mes "你那么快就准备好回来了？";
		next;
		menu "不是...我忘记了需要的条件",ContM0BeArcFor,"我已经把树枝带来了",ContM0BeArcCont;

	ContM0BeArcFor:
		mes "[弓箭手工会相关人员]";
		mes "你忘记了测试的条件？那好吧，我再告诉你一次。";
		next;
		mes "[弓箭手工会相关人员]";
		mes "弓箭手的转职条件是必须带来制作弓所需要的^FF0000树枝^000000，你所带来的树枝分为4个类级後，将与其他道具数量合算在一起给你分数。";
		mes "因此，你的总点40^0000FF再加上25 点以上^000000才可以转职为弓箭手。";
		next;
		mes "[弓箭手工会相关人员]";
		mes "这里有一点提示：树枝是打赢了'树精'可以取得，虽然他不是很强的敌手，但你也不要掉以轻心。";
		close;

	ContM0BeArcCont:
		mes "[弓箭手工会相关人员]";
		mes "现在我就开始为你带来的树枝评估你的分数。";
		next;
		set @Trunk1,countitem(1066);
		set @Trunk2,countitem(1067);
		set @Trunk3,countitem(1068);
		set @Trunk4,countitem(1019);
		if (@Trunk1==0 || @Trunk2==0 || @Trunk3==0 || @Trunk4==0)
			goto NoTrunk;
		goto TotalTrunk;

			NoTrunk:
				mes "[弓箭手工会相关人员]";
				mes "你没有将我们指定的四种树枝都带来！";
				close;

			TotalTrunk:
				set @archer_item1,@Trunk1*5;
				set @archer_item2,@Trunk2*3;
				set @archer_item3,@Trunk3*2;
				set @archer_item4,@Trunk4;
				set @Total_Trunk,@archer_item1+@archer_item2+@archer_item3+@archer_item4;

				mes "[弓箭手工会相关人员]";
				mes  "  等级 S :  "+@Trunk1+"  个/ 点数 :  "+@archer_item1;
				mes  "  等级 A :  "+@Trunk2+"  个/ 点数 :  "+@archer_item2;
				mes  "  等级 B :  "+@Trunk3+"  个/ 点数 :  "+@archer_item3;
				mes  "  等级 C :  "+@Trunk4+"  个/ 点数 :  "+@archer_item4;
				mes " ";

				if (@Total_Trunk > 40) goto HighTrunk;
				if (@Total_Trunk > 30) goto MediumTrunk;
				if (@Total_Trunk >= 25) goto NormalTrunk;

				mes  "  总点数 :  ^FF0000"+@Total_Trunk+"^000000 / 40";
				next;
				mes "[弓箭手工会相关人员]";
				mes "对不起，你的总点数低于25点，这项测试至少要25点才可以通过，再努力吧！";
				close;

				HighTrunk:
					mes  "  总点数 :  ^0000FF"+Total_Trunk+"^000000 / 40";
					next;
					mes "[弓箭手工会相关人员]";
					mes "哇！！40点以上！真厉害！你是合格了！";
					next;
					goto MakArc;
				MediumTrunk:
					mes  "  总点数 :  ^0000FF"+Total_Trunk+"^000000 / 40";
					next;
					mes "[弓箭手工会相关人员]";
					mes "30点以上！！你是合格了！太辛苦你了。";
					next;
					goto MakArc;
				NormalTrunk:
					mes  "  总点数 :  ^0000FF"+Total_Trunk+"^000000 / 40";
					next;
					mes "[弓箭手工会相关人员]";
					mes "哎哟~ 你的点数差点儿没法合格了，反正是辛苦你了。";
					next;
					goto MakArc;

		MakArc:
		mes "[弓箭手工会相关人员]";
		mes "由此看来，你已经完全符合弓箭手转职的条件，现在就马上给你转职。";
		next;
		JobChange 3;
		mes "[弓箭手工会相关人员]";
		mes "衷心地祝贺你转职成为弓箭手，往後请多多参与弓箭手工会的活动。";
		mes "啊, 制作部门已经东西送来了，请你点收。";
		mes "有了弓和箭後，你现在可以成为名符其实的弓箭手了。";
		getitem 1702,1;
		getitem 1750,100;
		delitem 1066;
		delitem 1067;
		delitem 1068;
		delitem 1019;
		set @Trunk1,0;
		set @Trunk2,0;
		set @Trunk3,0;
		set @Trunk4,0;
		set @archer_item1,0;
		set @archer_item2,0;
		set @archer_item3,0;
		set @archer_item4,0;
		set @Total_Trunk,0;
		next;
		mes "[弓箭手工会相关人员]";
		mes "那麽, 辛苦你了。希望你有杰出的表现。";
		close;

	M1:
		mes "[弓箭手工会相关人员]";
		if(Class !=0) 
			goto NotNov;
		mes "那，将为你说明弓箭手的转职条件。";
		goto ContM1;

			NotNov:
				if(Class==3) goto M1JobArc;
				mes "可是，你已经有其他职业了呀？";
				close;
			M1JobArc:
				mes "可是，你已经成为弓箭手了。";
				next;
				goto ContM1;
			ContM1:
				mes "[弓箭手工会相关人员]";
				mes "首先，初学者基本技能等级到达9级以上。";
				mes "另外，要成为弓箭手必备的条件是高度的集中力，所以我们弓箭手工会不收行事迷迷糊糊、搞不请楚状况的人。";
				next;
				mes "[弓箭手工会相关人员]";
				mes "弓箭手的转职条件是必须带来制作弓所需要的^FF0000树枝^000000 。";
				mes "你所带来的树枝分为4个类级後，将与其他道具数量合算在一起给你分数。";
				mes "因此，你的总点数40^0000FF再加上25点以上^000000才可以转职为弓箭手。";
				next;
				mes "[弓箭手工会相关人员]";
				mes "树枝是打赢了'树精'可以就取得，虽然他不是很强的敌手，但你也不要掉以轻心了。";
				close;
	MEnd:
		mes "[弓箭手工会相关人员]";
		mes "那好吧，欢迎你随时回到这里！";
		close;
}