npc_energycoat.txt

制作网络游戏的一个小平台

//Energy Coat 能量外套
// Modify By Robert 蝴蝶君 2004-1-17 Mailto:[e-mail]

geffen_in.gat,151,119,4	script	大魔法师	64,{
	if ((Class == Job_Mage) && (JobLevel < 35)) 
		goto LStartLowlv;
	if (!((Class == Job_Mage) || (Class == Job_Wizard) || (Class == Job_Sage))) 
		goto LStartOther;
	if (getskilllv(157)>0) 
		goto LStartTwice;
	if (((countitem(746)>=3) && (countitem(730)>=1) && (countitem(935)>=5) && (countitem(943)>=1))) 
		goto L3;
	Lstart:
		mes "[大魔法师]";
		mes "你好，年轻的魔法师，欢迎光临魔法师公会。我有个提议，如果你给我带来一些特殊的东西，我将告诉你使用能量外套的技巧。这将对你以后会有很大的帮助，你愿意吗？";
		next;
		menu "好啊，请说",L1,"不了，谢谢",L2;
	L1:
		mes "[大魔法师]";
		mes "好，学习能量外套，你需要：";
		mes "";
		mes "5 ^FF0000坚硬外壳^000000";
		mes "3 ^FF0000玻璃珠^000000";
		mes "1 ^FF00001克拉钻石^000000";
		mes "1 ^FF0000坚硬外皮^000000";
		mes "";
		mes "将这些物品收集完整后带来，我再教你如何使用能量外套，祝你好运！";
		close;
	
	L2:
		mes "[大魔法师]";
		mes "那好吧，希望下次再见，祝你好运！";
		close;
	
	L3:
		mes "[大魔法师]";
		mes "噢，看来你已经把我需要的东西都带来了，如果你愿意的话，我愿意以^0033FF能量外套^000000来和你交换！";
		next;
		menu "是的，我愿意",L3_1,"不，还是算了",L3_2;
	
	L3_1:
			mes "[大魔法师]";
			mes "那太好了！谢谢！";
	 		next;
			delitem 746,3;
			delitem 730,1;
			delitem 935,5;
			delitem 943,1;
			skill 157,1,0;
	 		mes "[大魔法师]";
	 		mes "你现在已经掌握了能量外套的技巧，祝你好运，我的朋友！";
	 		close;
	
	L3_2:
			mes "噢，那算了，祝你好运！";
			close;
	 		
	LStartOther:
		mes "[大魔法师]";
		mes "你好，我是魔法公会的大魔法师，是的，我可以教你使用能量外套这门技巧，前提是你必须是魔法师或是巫师。";
		close;
	
	LStartLowlv:
		mes "[大魔法师]";
		mes "嗯，依我看你现在还不能学习能量外套这门技巧，还是等你的职业等级达到35级的时候再来找我吧！";
		close;
	
	LStartTwice:
		mes "[大魔法师]";
		mes "你已经掌握了能量外套的技巧，希望你好好利用它！";
		close;
}