npc_cartrevolution.txt

制作网络游戏的一个小平台

// Cart Revolution 手推车攻击
// Modify By Robert 蝴蝶君 2004-1-18 mailto:[e-mail]

alberta.gat,232,106,6	script	格尔思	57,{
	if ((Class == Job_Merchant) && (JobLevel < 35)) 
		goto LStartLowlv;
	if (!((Class == Job_Merchant) || (Class == Job_Blacksmith) || (Class == Job_Alchem))) 
		goto LStartOther;
	if (getskilllv(153)>0) 
		goto LStartTwice;
	if ((countitem(533)>=2) && (countitem(998)>=15) 
	&& (countitem(938)>=30) && (countitem(601)>=20) && (countitem(962)>=5)) 
		goto L3;
	Lstart:	
		mes "[格尔思]";
		mes "欢迎来到艾尔贝塔，我是这里的手推车训练员。在这里你可以学到^0033FF手推车攻击^000000的技巧，你想要学习这种技能吗？";
		next;
		menu "是的，请给予帮助",L1_1,"不，只是随便看看",L1_2;

	L1_1:
		mes "[格尔思]";
		mes "天下可没有免费的午餐，你必须支付我一些报酬，否则请你离开这里。";
		next;
		menu "是的，我愿意",L2_1,"不了，别理我",L2_2;
	
	L1_2:
		mes "[格尔思]";
		mes "你可真是小气，快走，别烦我！";
		close;
	
	L2_1:
		mes "[格尔思]";
		mes "那好吧，你需要带这些物品来给我：";
		mes "";
		mes "30 个^FF0000粘稠液体^000000";
		mes "20 个^FF0000苍蝇翅膀^000000";
		mes "15 个^FF0000铁^000000";
		mes "5  个^FF0000触须^000000";
		mes "2  个^FF0000葡萄汁^000000";
		mes "";
		mes "当你找到了这些东西再回来找我吧，祝你好运！";
		close;
	
	L2_2:
		mes "[格尔思]";
		mes "你可真是小气，快走，别再来烦我了！";
		close;
	
	L3:
		mes "[格尔思]";
		mes "喂！看来你已经完成了你的任务，看来应该祝贺你了！当然我也是个遵守诺言的人，你还想要学习^0033FF手推车攻击^000000这种技能吗？";
		next;
		menu "是的",L3_1,"不了，谢谢",L3_2;
	
	L3_1:
		mes "[格尔思]";
		mes "很好，那我就开始传授你这个技能，请稍等。";
		next;
		delitem 533,2;
		delitem 998,15;
		delitem 938,30;
		delitem 601,20;
		delitem 962,5;
		skill 153,1,0;
		mes "[格尔思]";
		mes "恭喜，你已经掌握了手推车攻击的技能，祝你好运！";
		close;
	L3_2:
		mes "[格尔思]";
		mes "真是可恶，别再来烦我了，自己保重吧！";
		close;
	LStartOther:
		mes "[格尔思]";
		mes "我是一名商人，当然我也会传授一些关于手推车的使用技巧。手推车攻击目前只有商人才可以学习，依我看你还不是一名商人吧？";
		close;
	
	LStartLowlv:
	
		mes "[格尔思]";
		mes "嘿！朋友，你的职业等级还不足以学习手推车攻击，等你有了35级的时候再来找我吧！";
		close;
	
	LStartTwice:
		mes "[格尔思]";
		mes "你已经掌握了手推车攻击的技巧，别再来烦我了！";
		close;
}