er.l

a graphic tools for MTools

%{

/* er.l - A lexer for mtools stderr-output
 *
 * process this file with
 *   lex -Per er.l
 * to re-generate lex.er.c from er.l
 *
 */

int copyquestion (const char *, const char *);
int shallwecontinue (const char *, const char *);
void mtoolserroutput(const char *); 

%}

full Disk\ full\n
insert Can't\ open\ .+:\ Device\ not\ configured\nCannot\ initialize\ '.:'\n
lock Can't\ open\ .+:\ Read-only\ file\ system\nCannot\ initialize\ '.:'\n
mdelnf mdel:\ File\ \".+:.+\"\ not\ found\n
mrennf mren:\ File\ \".+:.+\"\ not\ found\n
nondos init\ .+:\ non\ DOS\ media\nCannot\ initialize\ '.:'\n
busy Can't\ open\ .+:\ Device\ or\ resource\ busy\nCannot\ initialize\ '.:'\n

%%
{full} { mtoolserroutput(ertext); 
         return copyquestion("Disk full",
                             "There is no space left on the target\n\
device. You can either insert\n\
a new disk, skip this file or cancel.\n\
What shall we do?"); }

({insert})+ { mtoolserroutput(ertext); 
              warnme("No floppy in drive",
                     "There is no floppy in the drive."); }

({lock})+ { mtoolserroutput(ertext); 
            warnme("Read-only drive",
                   "This floppy is read-only. If you want to\n\
write to it, remove the write-protection."); }

{mdelnf}|{mrennf} { mtoolserroutput(ertext); 
                    warnme("File not found",
                           "I was unable to locate the file\n\
on the disk. Maybe you inserted\n\
another floppy in between?"); }

({nondos})+ { mtoolserroutput(ertext); 
              warnme("Non DOS media",
                     "This does not look like a DOS floppy.\n\
Maybe it is minix, ext2 or some other format.\n\
In order to read such a floppy, you have to\n\
mount it."); }

({busy})+ { mtoolserroutput(ertext); 
            warnme("Device or resource busy",
                   "I was unable to access the floppy.\n\
This means that probably some other\n\
application is using the floppy. Perhaps\n\
the floppy is already mounted?"); }

.|\n               { mtoolserroutput(ertext); }
%%

int erwrap()
{
  return (1);
} 

int 
er_interface( FILE * infile ) 
{
  erin=infile;
  return erlex();
}