configure.ac

Intercom 是一个 Unix系统上灵活的语音传输软件。支持标准音频压缩比如GSM, G.711, and G.72x和其他音频编码。Intercom专为高速网络设计来传输高品质的语音

dnl configure.in -- Automatically configure Intercom
dnl Copyright (C) 2001-2003  Shane Wegner
dnl This file is part of Intercom.
dnl
dnl Intercom is free software; you can redistribute it and/or modify it
dnl under the terms of version 2 of the GNU General Public License as
dnl published by the Free Software Foundation.
dnl
dnl Intercom is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl General Public License for more details.
dnl
dnl You should have received a copy of version 2 of the GNU General Public
dnl License along with Intercom; if not, write to the Free Software
dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
dnl
dnl To contact the author, please send email to [e-mail].

dnl $Id: configure.ac,v 1.9 2003/02/13 20:25:30 shane Exp $

AC_INIT
AC_CONFIG_SRCDIR([intercom.c])
AC_PREREQ(2.54)
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(intercom, 0.15)
AC_CANONICAL_HOST

# options
AC_ARG_WITH([included-getopt],
AC_HELP_STRING([--with-included-getopt],[Always use included getopt library.]),
ic_cv_included_getopt=$withval,ic_cv_included_getopt=no)
AC_ARG_WITH([included-gsm],
AC_HELP_STRING([--with-included-gsm],[Always use included GSM library.]),
ic_cv_included_gsm=$withval,ic_cv_included_gsm=no)
IC_ARG_WITH(readline, [--without-readline], [Disable readline support], yes)
IC_ARG_WITH(history, [--without-history], [Disable use of the GNU history library], yes)
dnl IC_ARG_WITH(gettext, [--with-gettext], [Build with gettext support], no)
IC_ARG_ENABLE(debug, [--enable-debug=level], [Set debugging level (0 = off)], 0)
IC_ARG_ENABLE(cpu, [--with-cpu=type], [Optimize for specified cpu type], none)
IC_ARG_ENABLE(optimize, [--enable-optimize], [Use compiler optimizations (makes debugging difficult)], no)
IC_ARG_ENABLE(g72x, [--disable-g72x], [Do not build G.721 and G.723 codecs], yes)
IC_ARG_ENABLE(gsm, [--disable-gsm], [Build without GSM support.], yes)
IC_ARG_ENABLE(crypto, [--disable-crypto], [Do not include support for encrypted audio], yes)
AM_MAINTAINER_MODE
if test "$USE_MAINTAINER_MODE" = yes; then
ic_cv_included_getopt=yes
ic_cv_included_gsm=yes
dnl kludge to force old openssl des_ routines off
AC_DEFINE(OPENSSL_DISABLE_OLD_DES_SUPPORT, 1, disable old openssl des_ routines)
fi

# Defines
AC_DEFINE(_GNU_SOURCE, 1, Enable some GNU extensions)
AC_DEFINE_UNQUOTED(DEBUG, $ic_cv_debug, Intercom debugging level)
if test "$ic_cv_g72x" = yes; then
AC_DEFINE(HAVE_G72X, 1, Define to use the G.721 and G.723 codecs)
fi

# Checks for programs.
AC_PROG_CC
AC_PROG_GCC_TRADITIONAL
AM_SANITY_CHECK
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB

AC_SUBST(IC_SUBDIRS)
AC_SUBST(IC_LIBS)
AC_CONFIG_LIBOBJ_DIR(subst)

dnl Checks for gettext
ALL_LINGUAS=""
dnl if test "$ic_cv_gettext" = yes; then
dnl AM_GNU_GETTEXT
dnl AC_DEFINE(USE_GETTEXT, 1, Define if using the gettext library.)
dnl AC_CONFIG_FILES([intl/Makefile po/Makefile.in])
dnl IC_SUBDIRS="$IC_SUBDIRS intl \po"
dnl fi

dnl Cpu-specific optimizations
if test $ic_cv_cpu != "none"; then
AC_MSG_CHECKING(Whether $CC accepts -march=$ic_cv_cpu)
old_cflags=${CFLAGS}
CFLAGS="${CFLAGS} -march=$ic_cv_cpu"
AC_TRY_COMPILE([], [], [cpu_is_ok=yes], [cpu_is_ok=no])
AC_MSG_RESULT($cpu_is_ok)
if test $cpu_is_ok = no; then
AC_MSG_WARN(--with-cpu has no effect as $CC does not accept -march=$ic_cv_cpu)
CFLAGS=${old_cflags}
fi
fi
dnl General compiler optimizations
if test $ic_cv_optimize = "yes"; then
if test $GCC = "yes"; then
optim="-pipe -O3 -fomit-frame-pointer -ffast-math -funroll-loops"
gcc_version=`${CC} --version`
case $gcc_version in
3.*)
optim="${optim} -maccumulate-outgoing-args"
;;
esac
case $gcc_version in
2.9*|3.*)
case $ic_cv_cpu in
i486|i586|pentium|i686|pentiumpro)
optim="${optim} -mfancy-math-387"
;;
esac
;;
esac
AC_MSG_CHECKING(Whether $CC accepts ${optim})
old_cflags=${CFLAGS}
CFLAGS="${CFLAGS} ${optim}"
AC_TRY_COMPILE([], [], [opt_is_ok=yes], [opt_is_ok=no])
AC_MSG_RESULT($opt_is_ok)
if test $opt_is_ok = "no"; then
CFLAGS=${old_cflags}
fi
fi
if test "$ic_cv_gsm" = yes; then
ic_cv_included_gsm=yes
fi
fi

# Checks for libraries.
AC_CHECK_LIB([m], [pow])
# Needed for some BSD systems
AC_CHECK_LIB([ossaudio], [_oss_ioctl])
if test "$ic_cv_gsm" = yes; then
if test "$ic_cv_included_gsm" = no; then
ic_cv_included_gsm=yes
AC_CHECK_LIB(gsm, gsm_decode,[
AC_CHECK_HEADERS([gsm/gsm.h gsm.h],[
ic_cv_included_gsm=no
LIBS="${LIBS} -lgsm"
break
])])
if test "$ic_cv_included_gsm" = yes; then
AC_MSG_WARN(GSM library found but no gsm.h.)
AC_MSG_WARN(Will continue with included GSM library.)
fi
fi
if test "$ic_cv_included_gsm" = yes; then
IC_SUBDIRS="$IC_SUBDIRS gsm"
IC_LIBS="$IC_LIBS gsm/libgsm.a"
AC_DEFINE(HAVE_LIBGSM, 1, Define if you have the gsm library)
AC_DEFINE(HAVE_GSM_GSM_H, 1, Define if you have gsm/gsm.h)
fi
fi

if test "$ic_cv_readline" = yes; then
ic_cv_readline=no
AC_CHECK_HEADERS([readline.h readline/readline.h],[
ic_cv_readline=yes
break])
if test "$ic_cv_readline" = yes; then
AC_CHECK_LIB([curses], [tgetstr])
AC_CHECK_LIB([readline], [rl_callback_handler_install])
fi
fi
if test "$ic_cv_history" = yes; then
ic_cv_history=no
AC_CHECK_HEADERS([history.h readline/history.h],[
AC_CHECK_LIB([history], [add_history])
ic_cv_history=yes
break
])
fi
if test $ic_cv_crypto = "yes"; then
ic_cv_crypto=no
AC_CHECK_LIB([crypto], [DES_ncbc_encrypt],[
AC_CHECK_HEADERS([openssl/des.h],[
AC_DEFINE(USE_CRYPTO, 1, Define if crypto support is enabled.)
LIBS="${LIBS} -lcrypto"
ic_cv_crypto=yes
])])
if test $ic_cv_crypto = "no"; then
dnl check for old des_ openssl routines
AC_CHECK_LIB([crypto], [des_ncbc_encrypt],[
AC_CHECK_HEADERS([openssl/des.h],[
AC_DEFINE(USE_CRYPTO, 1, Define if crypto support is enabled.)
AC_DEFINE(CRYPTO_OLD_DES, 1, Define if using old des_ crypto routines)
LIBS="${LIBS} -lcrypto"
ic_cv_crypto=yes
])])
fi
if test "$USE_MAINTAINER_MODE" = yes; then
dnl force crypto on as if the checks fail over here,
dnl I want to know about it.
ic_cv_crypto=yes
fi
fi
if test $ic_cv_included_getopt = "no"; then
ic_cv_included_getopt=yes
AC_CHECK_FUNC(getopt_long,[
AC_CHECK_HEADERS([getopt.h],[
ic_cv_included_getopt=no
break
])])
fi
if test $ic_cv_included_getopt = "yes"; then
AC_LIBOBJ(getopt)
AC_LIBOBJ(getopt1)
fi
AC_FUNC_STRNLEN
AC_FUNC_STRTOD
AC_FUNC_MEMCMP
AC_FUNC_SELECT_ARGTYPES
AC_TYPE_SIGNAL
AC_FUNC_STRFTIME
AC_FUNC_STRNLEN
AC_FUNC_STRTOD
AC_REPLACE_FUNCS([mempcpy])
AC_REPLACE_FNMATCH

# Checks for header files.
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([arpa/inet.h errno.h fcntl.h netdb.h netinet/in.h \
netinet/ip.h netinet/in_systm.h stdlib.h string.h malloc.h sys/ioctl.h \
sys/socket.h sys/time.h unistd.h sys/soundcard.h \
machine/soundcard.h soundcard.h stdint.h inttypes.h features.h float.h \
paths.h stddef.h sys/param.h wchar.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_UID_T
AC_CHECK_TYPE(socklen_t, break,
AC_DEFINE(socklen_t, int, Define if the socklen_t type is not defined))
AC_HEADER_TIME
AC_CHECK_SIZEOF(void *)
AC_CHECK_SIZEOF(size_t)
AC_STRUCT_TM

# Checks for library functions.
AC_FUNC_ALLOCA
AC_HEADER_STDC
AC_TYPE_SIGNAL
AC_CHECK_FUNCS([gethostbyname gethostbyaddr gettimeofday pow socket dup2 \
getpass inet_ntoa inet_aton select setenv \
memset strcasecmp strchr strcspn strdup strerror strspn strtol atexit])

AM_CONDITIONAL(ic_cv_g72x, test "$ic_cv_g72x" = yes)
AM_CONDITIONAL(ic_cv_crypto, test "$ic_cv_crypto" = yes)
test "x$prefix" = xNONE && prefix=$ac_default_prefix
AC_DEFINE_UNQUOTED(SYSCONFDIR,
"`eval echo "${sysconfdir}" | sed "s/\/\$//"`",
Where config files are located)
AC_DEFINE_UNQUOTED(LOCALEDIR,
"`eval echo "${datadir}/locale" | sed "s/\/\//\//g"`",
Where locale files are located)
IC_SUBDIRS="$IC_SUBDIRS subst"
IC_LIBS="$IC_LIBS subst/libsubst.a"
AC_CONFIG_FILES([Makefile doc/Makefile doc/sgml/Makefile gsm/Makefile \
subst/Makefile])
AC_OUTPUT