ortografia.bas

一个用vb谢的编辑文本的工具

Attribute VB_Name = "Ortografia"
Option Explicit
Dim Di As String
Public Diccionario As String
Public DiccionarioO As String
Public CancelarCorreccion As Boolean

Public Const Signos = """, .-();:"
Function AbrirDicc() As String
    On Error Resume Next
    Di = App.Path
    If Right$(Di, 1) = "\" Then
        Di = Di & "dicc.dic"
    Else
        Di = Di & "\dicc.dic"
    End If
    Open Di For Input As #1
    If Err = 53 Then
        MsgBox "Unable to find the dictionary." & Chr(10) & "Make sure the file dicc.dic is in the application folder." & Chr(10) & "(" & Di & ")", vbCritical, FOrt.Caption
        Exit Function
    End If
    AbrirDicc = Input$(LOF(1), #1)
    Close #1
End Function

Sub ActDicc()
    Open Di For Output As #1
    Print #1, Diccionario
    Close #1
End Sub

Function BuscarPal(TaBuscar As String, TBuscado As String) As Boolean
Dim I As Long
Dim D As Long
    For I = 1 To Len(TaBuscar)
        If Mid(TaBuscar, I, Len(TBuscado)) = TBuscado Then
            For D = I To Len(TaBuscar)
                If Mid(TaBuscar, D, 1) = " " Then
                    If Len(TBuscado) = D - I Then
                        BuscarPal = True
                        Exit Function
                    End If
                End If
            Next
        End If
    Next
    BuscarPal = False
End Function

Function IgnorarPal(Pal As String) As Boolean
Dim I As Integer
Dim Res As Long
    For I = 1 To Len(Pal)
        Res = InStr("0123456789", Mid(Pal, I, 1))
        If Res > 0 Then
            IgnorarPal = True
            Exit Function
        End If
    Next
    IgnorarPal = False
End Function

Sub RevisarPal(Comienzo As Long, Expresion As String)
Dim I As Long
Dim Pal As String
    For I = Comienzo To Len(Expresion)
        If Mid(Expresion, I, 1) = Chr(13) Then
            Pal = Mid(Expresion, Comienzo, I - Comienzo)
            Exit For
        End If
        If InStr(Signos, Mid(Expresion, I, 1)) > 0 Then
            Pal = Mid(Expresion, Comienzo, I - Comienzo)
            Exit For
        End If
        If I = Len(Expresion) Then Pal = Mid(Expresion, Comienzo, I - Comienzo + 1)
    Next
    If IgnorarPal(Pal) = True Then Exit Sub
    If BuscarPal(Diccionario, Pal) = False Then
        If BuscarPal(DiccionarioO, Pal) = False Then
            CorregirPal Pal, Comienzo - 1, I - Comienzo
        End If
    End If
End Sub

Sub CorregirPal(Palabra As String, ComienzoPal As Long, LengthPal As Long)
    FOrt.Label1.Caption = Palabra
    ChildForms(frm).Text1.SelStart = ComienzoPal
    ChildForms(frm).Text1.SelLength = LengthPal
    Load FOrt
    FOrt.Show 1
End Sub