idct8x8_xmm.asm

来自「这是一组DCT和iDCT的代码」· 汇编 代码 · 共 738 行 · 第 1/2 页

;
; idct8x8_xmm.asm
;
; Originally provided by Intel at AP-922
; http://developer.intel.com/vtune/cbts/strmsimd/922down.htm
; (See more app notes at http://developer.intel.com/vtune/cbts/strmsimd/appnotes.htm)
; but in a limited edition.
; New macro implements a column part for precise iDCT
; The routine precision now satisfies IEEE standard 1180-1990. 
;
; Copyright (c) 2000-2001 Peter Gubanov <[e-mail]>
; Rounding trick Copyright (c) 2000 Michel Lespinasse <[e-mail]>
;
; http://www.elecard.com/peter/idct.html
; http://www.linuxvideo.org/mpeg2dec/
;
;=============================================================================
;
; These examples contain code fragments for first stage iDCT 8x8
; (for rows) and first stage DCT 8x8 (for columns)
;
;=============================================================================
mword 	typedef qword
mptr 	equ mword ptr

BITS_INV_ACC = 5 			; 4 or 5 for IEEE
SHIFT_INV_ROW = 16 - BITS_INV_ACC
SHIFT_INV_COL = 1 + BITS_INV_ACC
RND_INV_ROW = 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1)
RND_INV_COL = 16 * (BITS_INV_ACC - 3) 	; 1 << (SHIFT_INV_COL-1)
RND_INV_CORR = RND_INV_COL - 1 		; correction -1.0 and round

BITS_FRW_ACC = 3 			; 2 or 3 for accuracy
SHIFT_FRW_COL = BITS_FRW_ACC
SHIFT_FRW_ROW = BITS_FRW_ACC + 17
RND_FRW_ROW = 262144 * (BITS_FRW_ACC - 1)	; 1 << (SHIFT_FRW_ROW-1)

_MMX = 1

.nolist

.586

if @version GE 612
.mmx
mmword	TEXTEQU	<QWORD>
else
include IAMMX.INC
endif

if @version GE 614
.xmm
mm2word	TEXTEQU	<QWORD>			; needed for Streaming SIMD Extensions macros
else
include iaxmm.inc				; Streaming SIMD Extensions Emulator Macros
endif

	.list
	.model flat

_DATA SEGMENT PARA PUBLIC USE32 'DATA'

one_corr 	sword            1,            1,            1,            1
round_inv_row	dword  RND_INV_ROW,  RND_INV_ROW
round_inv_col	sword  RND_INV_COL,  RND_INV_COL,  RND_INV_COL, RND_INV_COL
round_inv_corr	sword RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR
round_frw_row	dword  RND_FRW_ROW,  RND_FRW_ROW
  tg_1_16	sword  13036,  13036,  13036,  13036	; tg * (2<<16) + 0.5
  tg_2_16	sword  27146,  27146,  27146,  27146 	; tg * (2<<16) + 0.5
  tg_3_16	sword -21746, -21746, -21746, -21746 	; tg * (2<<16) + 0.5
 cos_4_16	sword -19195, -19195, -19195, -19195 	; cos * (2<<16) + 0.5
ocos_4_16	sword  23170,  23170,  23170,  23170 	; cos * (2<<15) + 0.5

 otg_3_16	sword  21895, 21895, 21895, 21895 	; tg * (2<<16) + 0.5

; assume SHIFT_INV_ROW == 12
;rounder_0	dword  65536, 65536
;rounder_4       dword      0,     0
;rounder_1       dword   7195,  7195
;rounder_7	dword   1024,  1024
;rounder_2	dword   4520,  4520
;rounder_6	dword   1024,  1024
;rounder_3	dword   2407,  2407
;rounder_5	dword    240,   240

; assume SHIFT_INV_ROW == 11
rounder_0	dword  65536, 65536
rounder_4       dword      0,     0
rounder_1       dword   3597,  3597
rounder_7	dword    512,   512
rounder_2	dword   2260,  2260
rounder_6	dword    512,   512
rounder_3	dword   1203,  1203
rounder_5	dword    120,   120

;=============================================================================
;
; The first stage iDCT 8x8 - inverse DCTs of rows
;
;-----------------------------------------------------------------------------
; The 8-point inverse DCT direct algorithm
;-----------------------------------------------------------------------------
;
; static const short w[32] = {
;	FIX(cos_4_16),  FIX(cos_2_16),  FIX(cos_4_16),  FIX(cos_6_16),
;	FIX(cos_4_16),  FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16),
;	FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16),  FIX(cos_2_16),
;	FIX(cos_4_16), -FIX(cos_2_16),  FIX(cos_4_16), -FIX(cos_6_16),
;	FIX(cos_1_16),  FIX(cos_3_16),  FIX(cos_5_16),  FIX(cos_7_16),
;	FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16),
;	FIX(cos_5_16), -FIX(cos_1_16),  FIX(cos_7_16),  FIX(cos_3_16),
;	FIX(cos_7_16), -FIX(cos_5_16),  FIX(cos_3_16), -FIX(cos_1_16) };
;
; #define DCT_8_INV_ROW(x, y)
; {
; 	int a0, a1, a2, a3, b0, b1, b2, b3;
;
; 	a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3];
; 	a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7];
; 	a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11];
; 	a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15];
; 	b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19];
; 	b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23];
; 	b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27];
; 	b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31];
;
; 	y[0] = SHIFT_ROUND ( a0 + b0 );
; 	y[1] = SHIFT_ROUND ( a1 + b1 );
; 	y[2] = SHIFT_ROUND ( a2 + b2 );
; 	y[3] = SHIFT_ROUND ( a3 + b3 );
; 	y[4] = SHIFT_ROUND ( a3 - b3 );
; 	y[5] = SHIFT_ROUND ( a2 - b2 );
; 	y[6] = SHIFT_ROUND ( a1 - b1 );
; 	y[7] = SHIFT_ROUND ( a0 - b0 );
; }
;
;-----------------------------------------------------------------------------
;
; In this implementation the outputs of the iDCT-1D are multiplied
; 	for rows 0,4 - by cos_4_16,
; 	for rows 1,7 - by cos_1_16,
; 	for rows 2,6 - by cos_2_16,
; 	for rows 3,5 - by cos_3_16
; and are shifted to the left for better accuracy
;
; For the constants used,
; 	FIX(float_const) = (short) (float_const * (1<<15) + 0.5)
;
;=============================================================================

;=============================================================================
; MMX code
;=============================================================================

; Table for rows 0,4 - constants are multiplied by cos_4_16

tab_i_04 	sword  16384,  16384,  16384, -16384	; movq-> w06 w04 w02 w00
		sword  21407,   8867,   8867, -21407	; w07 w05 w03 w01
		sword  16384, -16384,  16384,  16384	; w14 w12 w10 w08
		sword  -8867,  21407, -21407,  -8867	; w15 w13 w11 w09
		sword  22725,  12873,  19266, -22725	; w22 w20 w18 w16
		sword  19266,   4520,  -4520, -12873	; w23 w21 w19 w17
		sword  12873,   4520,   4520,  19266	; w30 w28 w26 w24
		sword -22725,  19266, -12873, -22725	; w31 w29 w27 w25

; Table for rows 1,7 - constants are multiplied by cos_1_16

tab_i_17	sword  22725,  22725,  22725, -22725	; movq-> w06 w04 w02 w00
		sword  29692,  12299,  12299, -29692	; w07 w05 w03 w01
		sword  22725, -22725,  22725,  22725	; w14 w12 w10 w08
		sword -12299,  29692, -29692, -12299	; w15 w13 w11 w09
		sword  31521,  17855,  26722, -31521	; w22 w20 w18 w16
		sword  26722,   6270,  -6270, -17855	; w23 w21 w19 w17
		sword  17855,   6270,   6270,  26722	; w30 w28 w26 w24
		sword -31521,  26722, -17855, -31521	; w31 w29 w27 w25

; Table for rows 2,6 - constants are multiplied by cos_2_16

tab_i_26	sword  21407,  21407,  21407, -21407	; movq-> w06 w04 w02 w00
		sword  27969,  11585,  11585, -27969	; w07 w05 w03 w01
		sword  21407, -21407,  21407,  21407	; w14 w12 w10 w08
		sword -11585,  27969, -27969, -11585	; w15 w13 w11 w09
		sword  29692,  16819,  25172, -29692	; w22 w20 w18 w16
		sword  25172,   5906,  -5906, -16819	; w23 w21 w19 w17
		sword  16819,   5906,   5906,  25172	; w30 w28 w26 w24
		sword -29692,  25172, -16819, -29692	; w31 w29 w27 w25

; Table for rows 3,5 - constants are multiplied by cos_3_16

tab_i_35	sword  19266,  19266,  19266, -19266	; movq-> w06 w04 w02 w00
		sword  25172,  10426,  10426, -25172	; w07 w05 w03 w01
		sword  19266, -19266,  19266,  19266	; w14 w12 w10 w08
		sword -10426,  25172, -25172, -10426	; w15 w13 w11 w09
		sword  26722,  15137,  22654, -26722	; w22 w20 w18 w16
		sword  22654,   5315,  -5315, -15137	; w23 w21 w19 w17
		sword  15137,   5315,   5315,  22654	; w30 w28 w26 w24
		sword -26722,  22654, -15137, -26722	; w31 w29 w27 w25

;-----------------------------------------------------------------------------

DCT_8_INV_ROW_1 MACRO INP:REQ, OUT:REQ, TABLE:REQ, ROUNDER:REQ

	movq mm0, mptr [INP] 		; 0	; x3 x2 x1 x0

	movq mm1, mptr [INP+8]		; 1	; x7 x6 x5 x4
	movq mm2, mm0 			; 2	; x3 x2 x1 x0

	movq mm3, mptr [TABLE]		; 3	; w06 w04 w02 w00
	punpcklwd mm0, mm1 			; x5 x1 x4 x0

	movq mm5, mm0 			; 5	; x5 x1 x4 x0
	punpckldq mm0, mm0 			; x4 x0 x4 x0

	movq mm4, mptr [TABLE+8] 	; 4	; w07 w05 w03 w01
	punpckhwd mm2, mm1		; 1	; x7 x3 x6 x2

	pmaddwd mm3, mm0 			; x4*w06+x0*w04 x4*w02+x0*w00
	movq mm6, mm2 			; 6 	; x7 x3 x6 x2

	movq mm1, mptr [TABLE+32] 	; 1 	; w22 w20 w18 w16
	punpckldq mm2, mm2 			; x6 x2 x6 x2

	pmaddwd mm4, mm2 			; x6*w07+x2*w05 x6*w03+x2*w01
	punpckhdq mm5, mm5 			; x5 x1 x5 x1

	pmaddwd mm0, mptr [TABLE+16] 		; x4*w14+x0*w12 x4*w10+x0*w08
	punpckhdq mm6, mm6 			; x7 x3 x7 x3

	movq mm7, mptr [TABLE+40] 	; 7 	; w23 w21 w19 w17
	pmaddwd mm1, mm5 			; x5*w22+x1*w20 x5*w18+x1*w16

	paddd mm3, mptr [ROUNDER] 		; +rounder
	pmaddwd mm7, mm6 			; x7*w23+x3*w21 x7*w19+x3*w17

	pmaddwd mm2, mptr [TABLE+24] 		; x6*w15+x2*w13 x6*w11+x2*w09
	paddd mm3, mm4 			; 4 	; a1=sum(even1) a0=sum(even0)

	pmaddwd mm5, mptr [TABLE+48] 		; x5*w30+x1*w28 x5*w26+x1*w24
	movq mm4, mm3 			; 4 	; a1 a0

	pmaddwd mm6, mptr [TABLE+56] 		; x7*w31+x3*w29 x7*w27+x3*w25
	paddd mm1, mm7 			; 7 	; b1=sum(odd1) b0=sum(odd0)

	paddd mm0, mptr [ROUNDER]		; +rounder
	psubd mm3, mm1 				; a1-b1 a0-b0

	psrad mm3, SHIFT_INV_ROW 		; y6=a1-b1 y7=a0-b0
	paddd mm1, mm4 			; 4 	; a1+b1 a0+b0

	paddd mm0, mm2 			; 2 	; a3=sum(even3) a2=sum(even2)
	psrad mm1, SHIFT_INV_ROW 		; y1=a1+b1 y0=a0+b0

	paddd mm5, mm6 			; 6 	; b3=sum(odd3) b2=sum(odd2)
	movq mm4, mm0 			; 4 	; a3 a2

	paddd mm0, mm5 				; a3+b3 a2+b2
	psubd mm4, mm5 			; 5 	; a3-b3 a2-b2

	psrad mm0, SHIFT_INV_ROW 		; y3=a3+b3 y2=a2+b2
	psrad mm4, SHIFT_INV_ROW 		; y4=a3-b3 y5=a2-b2

	packssdw mm1, mm0 		; 0 	; y3 y2 y1 y0
	packssdw mm4, mm3 		; 3 	; y6 y7 y4 y5

	movq mm7, mm4 			; 7 	; y6 y7 y4 y5
	psrld mm4, 16 				; 0 y6 0 y4

	pslld mm7, 16 				; y7 0 y5 0
	movq mptr [OUT], mm1 		; 1 	; save y3 y2 y1 y0
                             	
	por mm7, mm4 			; 4 	; y7 y6 y5 y4
	movq mptr [OUT+8], mm7 		; 7 	; save y7 y6 y5 y4
ENDM

;=============================================================================
; code for Pentium III
;=============================================================================

; Table for rows 0,4 - constants are multiplied by cos_4_16

tab_i_04_s 	sword 16384, 21407, 16384, 8867 ; movq-> w05 w04 w01 w00
		sword 16384, 8867, -16384, -21407 ; w07 w06 w03 w02
		sword 16384, -8867, 16384, -21407 ; w13 w12 w09 w08
		sword -16384, 21407, 16384, -8867 ; w15 w14 w11 w10
		sword 22725, 19266, 19266, -4520 ; w21 w20 w17 w16
		sword 12873, 4520, -22725, -12873 ; w23 w22 w19 w18
		sword 12873, -22725, 4520, -12873 ; w29 w28 w25 w24
		sword 4520, 19266, 19266, -22725 ; w31 w30 w27 w26

; Table for rows 1,7 - constants are multiplied by cos_1_16

tab_i_17_s	sword 22725, 29692, 22725, 12299 ; movq-> w05 w04 w01 w00
		sword 22725, 12299, -22725, -29692 ; w07 w06 w03 w02
		sword 22725, -12299, 22725, -29692 ; w13 w12 w09 w08
		sword -22725, 29692, 22725, -12299 ; w15 w14 w11 w10
		sword 31521, 26722, 26722, -6270 ; w21 w20 w17 w16
		sword 17855, 6270, -31521, -17855 ; w23 w22 w19 w18
		sword 17855, -31521, 6270, -17855 ; w29 w28 w25 w24
		sword 6270, 26722, 26722, -31521 ; w31 w30 w27 w26

; Table for rows 2,6 - constants are multiplied by cos_2_16

tab_i_26_s	sword 21407, 27969, 21407, 11585 ; movq-> w05 w04 w01 w00
		sword 21407, 11585, -21407, -27969 ; w07 w06 w03 w02
		sword 21407, -11585, 21407, -27969 ; w13 w12 w09 w08
		sword -21407, 27969, 21407, -11585 ; w15 w14 w11 w10
		sword 29692, 25172, 25172, -5906 ; w21 w20 w17 w16
		sword 16819, 5906, -29692, -16819 ; w23 w22 w19 w18
		sword 16819, -29692, 5906, -16819 ; w29 w28 w25 w24
		sword 5906, 25172, 25172, -29692 ; w31 w30 w27 w26

; Table for rows 3,5 - constants are multiplied by cos_3_16

tab_i_35_s	sword 19266, 25172, 19266, 10426 ; movq-> w05 w04 w01 w00
		sword 19266, 10426, -19266, -25172 ; w07 w06 w03 w02
		sword 19266, -10426, 19266, -25172 ; w13 w12 w09 w08
		sword -19266, 25172, 19266, -10426 ; w15 w14 w11 w10
		sword 26722, 22654, 22654, -5315 ; w21 w20 w17 w16
		sword 15137, 5315, -26722, -15137 ; w23 w22 w19 w18
		sword 15137, -26722, 5315, -15137 ; w29 w28 w25 w24
		sword 5315, 22654, 22654, -26722 ; w31 w30 w27 w26

;-----------------------------------------------------------------------------

DCT_8_INV_ROW_1_s MACRO INP:REQ, OUT:REQ, TABLE:REQ, ROUNDER:REQ

	movq 	mm0, mptr [INP] 	; 0 	; x3 x2 x1 x0

	movq 	mm1, mptr [INP+8]	; 1 	; x7 x6 x5 x4
	movq 	mm2, mm0 		; 2 	; x3 x2 x1 x0

	movq 	mm3, mptr [TABLE] 	; 3 	; w05 w04 w01 w00
	pshufw	mm0, mm0, 10001000b 	; x2 x0 x2 x0

	movq 	mm4, mptr [TABLE+8] 	; 4 	; w07 w06 w03 w02
	movq 	mm5, mm1		; 5 	; x7 x6 x5 x4
	pmaddwd mm3, mm0 		; x2*w05+x0*w04 x2*w01+x0*w00

	movq 	mm6, mptr [TABLE+32] 	; 6 	; w21 w20 w17 w16
	pshufw 	mm1, mm1, 10001000b 		; x6 x4 x6 x4
	pmaddwd mm4, mm1 			; x6*w07+x4*w06 x6*w03+x4*w02

	movq 	mm7, mptr [TABLE+40] 	; 7 	; w23 w22 w19 w18
	pshufw 	mm2, mm2, 11011101b 		; x3 x1 x3 x1
	pmaddwd mm6, mm2 			; x3*w21+x1*w20 x3*w17+x1*w16

	pshufw 	mm5, mm5, 11011101b 		; x7 x5 x7 x5
	pmaddwd mm7, mm5 			; x7*w23+x5*w22 x7*w19+x5*w18

	paddd 	mm3, mptr [ROUNDER] 		; +rounder

	pmaddwd mm0, mptr [TABLE+16] 		; x2*w13+x0*w12 x2*w09+x0*w08
	paddd 	mm3, mm4 		; 4 	; a1=sum(even1) a0=sum(even0)

	pmaddwd mm1, mptr [TABLE+24] 		; x6*w15+x4*w14 x6*w11+x4*w10
	movq 	mm4, mm3 		; 4 	; a1 a0

	pmaddwd mm2, mptr [TABLE+48] 		; x3*w29+x1*w28 x3*w25+x1*w24
	paddd 	mm6, mm7 		; 7 	; b1=sum(odd1) b0=sum(odd0)

	pmaddwd mm5, mptr [TABLE+56] 		; x7*w31+x5*w30 x7*w27+x5*w26
	paddd mm3, mm6 				; a1+b1 a0+b0

	paddd mm0, mptr [ROUNDER] 		; +rounder
	psrad mm3, SHIFT_INV_ROW 		; y1=a1+b1 y0=a0+b0

	paddd mm0, mm1 			; 1 	; a3=sum(even3) a2=sum(even2)
	psubd mm4, mm6 			; 6 	; a1-b1 a0-b0