⭐ 欢迎来到虫虫下载站！ | 📦 资源下载 📁 资源专辑 ℹ️ 关于我们
⭐ 虫虫下载站
📤 上传资源

📄 admin_template.asp

📁 功能强大的bbs
💻 ASP
📖 第 1 页 / 共 4 页
字号:
🔍
1234 
Function IsTruePage(page)
	IsTruePage=False
	If page<>"" Then 
		page=LCase(Trim(page))
		Dim myrs
		Set Myrs=Dvbbs.Execute("Select top 1 * From [Dv_Style]")
		For i= 2 to MyRs.Fields.Count-1
			If LCase( myrs(i).name)=page Then
				 IsTruePage=True
				 Exit For
			End If
		Next
	End If
End Function

Sub DelStyle()
	'检查是否有版面使用本模版
	If StyleID=SkinID Then 
		Errmsg=ErrMsg + "<BR><li>本模板是默认模版，不允许删除。"
		Dvbbs_error()
	End If
	Set Rs=Dvbbs.Execute("select Count(*) From [Dv_Board] Where sid="&StyleID&"")
	If Rs(0)>0 Then
		Set Rs=Nothing 
		Errmsg=ErrMsg + "<BR><li>本模板尚有分论坛在使用，不能删除。"
		Dvbbs_error()
	End If
	Set rs=Nothing 
	Dvbbs.Execute("Delete From [Dv_Style] Where ID="&StyleID&"")
	Dv_suc("成功删除了一个模板。")
	Dvbbs.DelCahe("Templateslist")'删除模板列表缓存
End Sub
Sub delpage()
	Dim StylePageName
	StylePageName=Dvbbs.checkStr(request("StylePageName"))
	If StylePageName="" Then 
		Errmsg=ErrMsg + "<BR><li>请填写字段名称"
		Dvbbs_error()
	End If
	If Not IsTruePage(StylePageName) Then 
		Errmsg=ErrMsg + "<BR><li>要删除的字段不存在。"
		Dvbbs_error()
	End If
	If IsSqlDataBase = 1 Then
		Dim i,Fieldslist,Rs
		Set Rs=Dvbbs.Execute("select * from Dv_Style")
		Fieldslist="id"
		For i= 1 to Rs.Fields.Count-1
			If LCase(Rs(i).name)<> LCase (StylePageName) Then 
				Fieldslist=Fieldslist&","&Rs(i).name
			End If
		Next
		Set Rs=Nothing 
		'复制有用数据到临时表	
		Dvbbs.Execute("Select "&Fieldslist&" into Dv_tempatble From Dv_Style")
		'删除原有表
		Dvbbs.Execute("Drop table Dv_Style")
		'再把临时表中的数据复制过来.
		Dvbbs.Execute("Select "&Fieldslist&" into Dv_Style From Dv_tempatble ")
		'删除临时表
		Dvbbs.Execute("Drop table Dv_tempatble")
		'复制有用数据到临时表	
		Dvbbs.Execute("Select "&Fieldslist&" into Dv_tempatble From Dv_Stylehelp")
		'删除原有表
		Dvbbs.Execute("Drop table Dv_Stylehelp")
		'再把临时表中的数据复制过来.
		Dvbbs.Execute("Select "&Fieldslist&" into Dv_Stylehelp From Dv_tempatble ")
		'删除临时表
		Dvbbs.Execute("Drop table Dv_tempatble") 
	Else
		Dvbbs.Execute("Alter Table [Dv_Style] Drop ["&StylePageName&"]")
		Dvbbs.Execute("Alter Table [Dv_Stylehelp] Drop ["&StylePageName&"]")
	End If 
	Dv_suc("页面模板删除成功！")
End Sub 
Sub addpage()
	Dim StylePageName
	StylePageName=Dvbbs.checkStr(request("StylePageName"))
	If StylePageName="" Then 
		Errmsg=ErrMsg + "<BR><li>请填写字段名称"
		Dvbbs_error()
	End If
	StylePageName="Page_"&StylePageName
	If IsTruePage(StylePageName) Then 
		Errmsg=ErrMsg + "<BR><li>您要创建的模板字段已经存在。"
		Dvbbs_error()
	End If
	Dvbbs.Execute("alter table [Dv_Stylehelp] add "&StylePageName&" text not Null default'|||@@@|||@@@|||@@@|||'")
	Dvbbs.Execute("Update [Dv_Stylehelp] Set "&StylePageName&"='|||@@@|||@@@|||@@@|||'")
	Dvbbs.Execute("alter table [Dv_Style] add "&StylePageName&" text not Null default'|||@@@|||@@@|||@@@|||'")
	Dvbbs.Execute("Update [Dv_Style] Set "&StylePageName&"='|||@@@|||@@@|||@@@|||'")
	Dv_suc("新页面模板创建成功!")
End Sub

Sub addstyle()
	Dim stylename,sql
	stylename=Dvbbs.checkStr(Request("stylename"))
	If Trim(stylename)=""  Then 
		 Errmsg=ErrMsg + "<BR><li>请输入模板名称。"
		Dvbbs_error()
	End If
	Set Rs=Dvbbs.Execute("select * From [Dv_Style] where ID="&StyleID&"")
	Dim styleFields,stylevalues
	styleFields="StyleName"
	stylevalues="'"&stylename&"'"
	For i= 2 to Rs.Fields.Count-1
		styleFields=styleFields&","&Rs(i).Name
		stylevalues=stylevalues&",'"&Dvbbs.checkStr(Rs(i))&"'"
	Next
	Set rs=Nothing
	sql="insert into [Dv_Style]("&styleFields&")values("&stylevalues&")"
	Dvbbs.Execute(SQL)
	Dv_suc("新模板创建成功!")
	Dvbbs.DelCahe("Templateslist")'删除模板列表缓存
End Sub
Sub pagerename()
	Dim oldpagename,newpagename
	oldpagename=Dvbbs.checkStr(request("oldpagename"))
	newpagename=Dvbbs.checkStr(request("newpagename"))
	If LCase(newpagename)=LCase(oldpagename) Then
		Errmsg=ErrMsg + "<BR><li>你没有更改名称"
		Dvbbs_error()
	End If
	If newpagename="" Then
		Errmsg=ErrMsg + "<BR><li>新名称不能为空"
		Dvbbs_error()
	End If
	If OLDpagename="" Then
		Errmsg=ErrMsg + "<BR><li>您提交的数据是错误的."
		Dvbbs_error()
	End If
	oldpagename="page_"&oldpagename
	newpagename="page_"&newpagename
	If Not IsTruePage(oldpagename) Then 
		Errmsg=ErrMsg + "<BR><li>要改名的字段不存在。"
		Dvbbs_error()
	End If
	If IsTruePage(newpagename) Then 
		Errmsg=ErrMsg + "<BR><li>字段名称"&newpagename&"已经被占用."
		Dvbbs_error()
	End If
		Dim i,Fieldslist,Rs
		Set Rs=Dvbbs.Execute("select * from Dv_Style")
		Fieldslist="id"
		For i= 1 to Rs.Fields.Count-1
			If LCase(Rs(i).name)<> LCase (oldpagename) Then 
				Fieldslist=Fieldslist&","&Rs(i).name
			Else
				Fieldslist=Fieldslist&","&Rs(i).name&" as "& newpagename
			End If
		Next
		Set Rs=Nothing
		'复制有用数据到临时表	
		Dvbbs.Execute("Select "&Fieldslist&" into Dv_tempatble From Dv_Style")
		'删除原有表
		Dvbbs.Execute("Drop table Dv_Style")
		'再把临时表中的数据复制过来.
		Dvbbs.Execute("Select * into Dv_Style From Dv_tempatble ")
		'删除临时表
		Dvbbs.Execute("Drop table Dv_tempatble")
		'复制有用数据到临时表	
		Dvbbs.Execute("Select "&Fieldslist&" into Dv_tempatble From Dv_Stylehelp")
		'删除原有表
		Dvbbs.Execute("Drop table Dv_Stylehelp")
		'再把临时表中的数据复制过来.
		Dvbbs.Execute("Select * into Dv_Stylehelp From Dv_tempatble ")
		'删除临时表
		Dvbbs.Execute("Drop table Dv_tempatble") 
	Dv_suc("成功把 "&oldpagename&" 字段改名为 "&newpagename&"")
End Sub
Sub rename()
	Dim stylename
	stylename=Dvbbs.checkStr(Request("stylename"))
	If Trim(stylename)=""  Then 
		Errmsg=ErrMsg + "<BR><li>修改名称请输入新的模板名称。"
		Dvbbs_error()
	End If
	Dvbbs.Execute("update [Dv_Style] set StyleName='"&StyleName&"' where id="&StyleID&"")
	Dv_suc("模板名修改成功!")
	Dvbbs.DelCahe("Templateslist")'删除模板列表缓存
End Sub

'//编辑修改CSS模板
'CSS风格名称@@@CSS风格内容@@@CSS风格图片包路径	（用@@@分类，用|||分隔内容.）
Sub EditCss()
Dim CssName,CssContent,CssPicUrl,MainStyleName,k,CssCount
Dim TempCssStyle,LockID
Set Rs=Dvbbs.Execute("Select Forum_CSS,StyleName From [Dv_Style] Where ID="&StyleID)
	TempCssStyle=Split(Server.htmlencode(Rs(0)),"@@@")
	MainStyleName=Rs(1)
Rs.close

CssName=Split(TempCssStyle(0),"|||")	'CSS风格名称
CssCount=Ubound(CssName)
If Ubound(TempCssStyle)<1 Then
Redim CssContent(CssCount)
Else
CssContent=Split(TempCssStyle(1),"|||")	'CSS风格内容
End If
If Ubound(TempCssStyle)<2 Then
Redim CssPicUrl(CssCount)
Else
CssPicUrl=Split(TempCssStyle(2),"|||")	'CSS风格图片包路径
End IF

Response.Write "<br><table width=""95%"" border=""0"" cellspacing=""1"" cellpadding=""3"" align=center class=""tableBorder"">"
Response.Write "<tr>"
Response.Write "<th width=""100%"" class=""tableHeaderText"" colspan=2 height=25>（"
Response.Write MainStyleName
Response.Write "）-CSS样式管理"
Response.Write "</th></tr></table>"
%>
<SCRIPT LANGUAGE="JavaScript">
<!--
function EditCss(n)
{
	var trid=document.getElementsByName('CssTR');
	 for (var i=0;i<trid.length;i++)    {
		if (i!=n){
		trid[i].style.display="none";
		}
	   }
	EditTextarea.style.display = '';
	document.cssform.CssContent.value = document.cssform.CssBody[n].value;
	document.cssform.TempID.value = n;
	document.cssform.CssEdit[n].disabled=true;
}

function DllData(n){
	if (document.cssform.DelCss[n].checked==true){
	document.cssform.CssName[n].value = '计划将删除...';
	document.cssform.CssBody[n].disabled = true;
	document.cssform.CssPicUrl[n].disabled = true;
	document.cssform.CssEdit[n].disabled=true;
	}else{
	document.cssform.CssName[n].value = '请重新输入新的风格名称!!';
	document.cssform.CssBody[n].disabled = false;
	document.cssform.CssPicUrl[n].disabled = false;
	document.cssform.CssEdit[n].disabled=false;
	}
}

function SubmitData(){
	var NewData,UpObject
	var e = document.cssform;
	NewData=e.CssContent.value;
	UpObject=e.TempID.value;
	if (NewData!=''){
		e.CssBody[UpObject].value=NewData;
	}
	for (var i=0;i<e.CssName.length;i++){
		if (e.CssName[i].value == '计划将删除...' || e.CssName[i].value == ''){
		e.CssName[i].value = '';
		e.CssBody[i].value = '';
		e.CssPicUrl[i].value = '';
		}
	}
}
//-->
</SCRIPT>
<table width="95%" border="0" cellspacing="1" cellpadding="3" align=center class="tableBorder" >
<form action="?action=savecss&StyleID=<%=StyleID%>" method="post" name="cssform" onsubmit="SubmitData();">
<tr>
<td width="10%" class="bodytitle" align=center>ID</td>
<td width="30%" class="bodytitle" align=center>名称</td>
<td width="30%" class="bodytitle" align=center>图片包路径(请以“/”结束)</td>
<td width="20%" class="bodytitle" align=center>操作</td>
<td width="10%" class="bodytitle" align=center>删除</td>
</tr>
<tr><td height=1 class="tableBorder1" colspan=5></td></tr>
<%
For k=0 To Ubound(CssName)
%>
<tr Name="CssTR" id="CssTR">
<td class="forumRowHighlight" align=center><%=k%></td>
<td class="forumRow" align=center><input type=text value="<%=CssName(k)%>" name="CssName"></td>
<td class="forumRowHighlight" align=center>
<%
Response.Write "<input name=""CssPicUrl"" size=30 type=text value="""
if CssPicUrl(k)="" and k<>Ubound(CssName) Then Response.Write "Skins/Default/" Else Response.Write CssPicUrl(k)
Response.Write """>"
%>
</td>
<td class="forumRow" align=center>
<input type="button" value="修改Css内容" name="CssEdit" onclick="EditCss(<%=k%>)">
<div style="display:none">
<textarea name="CssBody" id="CssBody" style="width:0;height=0" rows="0" ><%=CssContent(k)%></textarea>
</div>
</td>
<td class="forumRowHighlight" align=center><INPUT TYPE="checkbox" NAME="DelCss" onclick="DllData(<%=k%>)" ></td>
</tr>
<%
Next
%>
<tr id="EditTextarea" style="display:none">
<INPUT TYPE="hidden" NAME="TempID">
<td height=400 class="forumRowHighlight" colspan=5>
<textarea id="CssContent" style="width:100%" rows="30" ></textarea>
</td>
</tr>
<%
Response.Write "<tr><td class=""forumRowHighlight"" height=""25"" align=""center"" colspan=5>"
Response.Write "<input type=""submit"" name=""B1"" value=""提 交"">&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;"
Response.Write "<input type=""button"" value=""返 回"" onclick=""location.reload('admin_template.asp?action=editcss&StyleID="&StyleID&"')"">"
Response.Write "</td></tr>"
%>
</form></table>
<%
End Sub

'//保存修改CSS模板
Sub savecss()
	If StyleID="" or not isnumeric(StyleID) Then
		Errmsg=ErrMsg + "<BR><li>请选择您要修改的CSS样式!"
		Dvbbs_error()
		Exit Sub 
	End If
	Dim TempStr,LockID
	Dim TempStr1,TempStr2,TempStr3
	Dim CssName,CssContent,CssPicUrl,TempCssStyle
	LockID=1
	'提取CSS风格名的数据
	For Each TempStr in Request.Form("CssName")
		If TempStr<>"" Then 
			CssName=CssName&Replace(TempStr,"|||","")&"|||"
		End If
	Next
	'提取图片包的数据
	For Each TempStr in Request.Form("CssPicUrl")
		If TempStr<>"" Then 
			CssPicUrl=CssPicUrl&Replace(TempStr,"|||","")&"|||"
		End If
	Next
	'提取风格内容的数据
	For Each TempStr in Request.Form("CssBody")
		If TempStr<>"" Then 
			CssContent=CssContent&Replace(TempStr,"|||","")&"|||"
		End If
	Next
	CssName=Replace(CssName,"@@@","")
	CssContent=Replace(CssContent,"@@@","")
	CssPicUrl=Replace(CssPicUrl,"@@@","")
	TempStr1=ubound(Split(CssName,"|||"))
	TempStr2=ubound(Split(CssContent,"|||"))
	TempStr3=ubound(Split(CssPicUrl,"|||"))
1234

⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -