votein.asp

电子商务网络购物系统

<% Option Explicit %>
<!--#include file="conn.asp" -->
<%
Response.Buffer = True

Dim intForumID
Dim lngTopicID
Dim lngPollID
Dim lngPollVoteChoice
Dim blnForumLocked
Dim lngTotalChoiceVote
Dim blnMultipleVotes		
Dim lngLastVoteUserID
Dim blnAlreadyVoted
Dim intResponseNum

If bannedIP() Then
	Set rsConn = Nothing
	adoCon.Close
	Set adoCon = Nothing
	Response.Redirect("nopermission.asp?M=IP")
End If

If Request.Form("pid") = "" OR Request.Form("tid") = "" Then Response.Redirect("index.asp")
blnForumLocked = True
blnAlreadyVoted = False
intForumID = CInt(Request.Form("fid"))
lngTopicID = CLng(Request.Form("tid"))
lngPollID = CLng(Request.Form("pid"))
lngPollVoteChoice = CLng(Request.Form("voteChoice"))
strSQL = "SELECT timesbbs.* FROM timesbbs WHERE timesbbs.bbsid = " & intForumID & ";"
rsConn.Open strSQL, adoCon
If NOT rsConn.EOF Then
	blnForumLocked = CBool(rsConn("Locked"))
	Call forumPermisisons(intForumID, intGroupID, 0, 0, 0, 0, 0, 0, 0, CInt(rsConn("Vote")), 0, 0)
End If
rsConn.Close
If blnForumLocked = False AND blnVote = True AND lngPollVoteChoice <> "" AND lngPollVoteChoice > 0 Then
	strSQL = "SELECT timespoll.multi, timespoll.userid FROM timespoll WHERE timespoll.pollid = " & lngPollID & ";"
	rsConn.CursorType = 2
	rsConn.LockType = 3
	rsConn.Open strSQL, adoCon
	If NOT rsConn.EOF Then
		blnMultipleVotes = CBool(rsConn("multi"))
		If blnMultipleVotes = False Then
			lngLastVoteUserID = rsConn("userid")
			If lngLastVoteUserID = lngLoggedInUserID AND lngLoggedInUserID <> 2 Then blnAlreadyVoted = True
			If CInt(Request.Cookies("FPLL")("pid" & lngPollID)) = lngPollID Then blnAlreadyVoted = True
			If blnAlreadyVoted = False Then
				rsConn.Fields("userid") = lngLoggedInUserID
				rsConn.Update
				Response.Cookies("FPLL")("pid" & lngPollID) = lngPollID
				Response.Cookies("FPLL").Expires = Now() + 360
			End If
		End If
	End If
	rsConn.Close
	If blnAlreadyVoted = False Then
		strSQL = "SELECT timeschoice.Votes FROM timeschoice WHERE timeschoice.Choice_ID = " & lngPollVoteChoice & ";"
		rsConn.CursorType = 2
		rsConn.LockType = 3
		rsConn.Open strSQL, adoCon
		If NOT rsConn.EOF Then
			lngTotalChoiceVote = CLng(rsConn("Votes"))
			lngTotalChoiceVote = lngTotalChoiceVote + 1
			rsConn.Fields("Votes") = lngTotalChoiceVote
			rsConn.Update
			intResponseNum = 1
		End If
		rsConn.Close
	End If
End If
Set rsConn = Nothing
adoCon.Close
Set adoCon = Nothing
If lngPollVoteChoice = 0 Then intResponseNum = 2
Response.Redirect("post.asp?tid=" & lngTopicID & "&pn=" & Request.Form("pn") & "&tpn=" & Request.Form("tpn") & "&RN=" & intResponseNum)
%>