sendmail.asp

电子商务网络购物系统

<%
Function SendMail(ByVal strEmailBodyMessage, ByVal strRecipientName, ByVal strRecipientEmailAddress, ByVal strFromEmailName, ByVal strFromEmailAddress, ByVal strSubject, strMailComponent, blnHTML)

	Dim objCDOSYSMail
	Dim objCDOMail
	Dim objJMail
	Dim objAspEmail
	Dim objAspMail
	Dim strEmailBodyAppendMessage

	If blnLCode = True Then
		If blnHTML = True Then
			strEmailBodyAppendMessage = "<br /><br /><br /><hr />Powered by <a href=""http://www.TimesBoard.com"">TimesBoard</a> version " & strVersion & "<br />Free ASP Bulletin Board System"
		Else
			strEmailBodyAppendMessage = VbCrLf & VbCrLf & "---------------------------------------------------------------------------------------"
			strEmailBodyAppendMessage = strEmailBodyAppendMessage & VbCrLf & "Powered by TimesBoard version " & strVersion & " - http://www.timesboard.com"
			strEmailBodyAppendMessage = strEmailBodyAppendMessage & VbCrLf & "Free ASP Bulletin Board System"
		End If
	End If

	Select Case strMailComponent

		Case "CDOSYS"
			Dim objCDOSYSCon
			Set objCDOSYSMail = Server.CreateObject("CDO.Message")
		    	Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")
		    	With objCDOSYSCon
		        	.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strIncomingMailServer
		        	'SMTP port
		        	.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport")  = 25
		        	'CDO Port
		        	.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
		        	'Timeout
		        	.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
	        		.Fields.Update
	        	End With
				Set objCDOSYSMail.Configuration = objCDOSYSCon

			With objCDOSYSMail
				.From = strFromEmailName & " <" & strFromEmailAddress & ">"
				.To = strRecipientName & " <" & strRecipientEmailAddress & ">"
				.Subject = strSubject
				If blnHTML = True Then
				 	.HTMLBody = strEmailBodyMessage & strEmailBodyAppendMessage
				Else
					.TextBody = strEmailBodyMessage & strEmailBodyAppendMessage
				End If
				If NOT strIncomingMailServer = "" Then .Send
			End with
			Set objCDOSYSMail = Nothing

		Case "CDONTS"
			Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
			With objCDOMail
				.From = strFromEmailName & " <" & strFromEmailAddress & ">"
				.To = strRecipientName & " <" & strRecipientEmailAddress & ">"
				.Subject = strSubject
				.Body = strEmailBodyMessage & strEmailBodyAppendMessage
				If blnHTML = True Then
					.BodyFormat = 0
				Else
					.BodyFormat = 1
				End If
				.MailFormat = 0
				.Importance = 1
				.Send
			End With
			Set objCDOMail = Nothing

		Case "Jmail"
			Set objJMail = Server.CreateObject("JMail.SMTPMail")
			With objJMail
				.ServerAddress = strIncomingMailServer
				.Sender = strFromEmailAddress
				.SenderName = strFromEmailName
				.AddRecipient strRecipientEmailAddress
				.Subject = strSubject
				If blnHTML = True Then
					.HTMLBody = strEmailBodyMessage & strEmailBodyAppendMessage
				Else
					.Body = strEmailBodyMessage & strEmailBodyAppendMessage
				End If
				.Priority = 3
				If NOT strIncomingMailServer = "" Then .Execute
			End With
			Set objJMail = Nothing

		Case "AspEmail"
			Set objAspEmail = Server.CreateObject("Persits.MailSender")
			With objAspEmail
				.Host = strIncomingMailServer
				.From = strFromEmailAddress
				.FromName = strFromEmailName
				.AddAddress strRecipientEmailAddress
				.Subject = strSubject
				If blnHTML = True Then
					.IsHTML = True
				End If
				.Body = strEmailBodyMessage & strEmailBodyAppendMessage
				If NOT strIncomingMailServer = "" Then .Send
			End With
			Set objAspEmail = Nothing

		Case "AspMail"
		   	Set objAspMail = Server.CreateObject("SMTPsvg.Mailer")
		   	With objAspMail
			   	.RemoteHost = strIncomingMailServer
			   	.FromAddress = strFromEmailAddress
			   	.FromName = strFromEmailName
			   	.AddRecipient " ", strRecipientEmailAddress
			   	.Subject = strSubject
			   	If blnHTML = True Then
			    		.ContentType = "text/HTML"
			   	End If
			   	.BodyText = strEmailBodyMessage & strEmailBodyAppendMessage
			   	If NOT strIncomingMailServer = "" Then .SendMail
			   End With
		   	Set objAspMail = Nothing
	End Select
	SendMail = True
End Function
%>