poll_select.asp

基于ASP开发的聊天室源码

<%
Response.Expires=0
Response.ExpiresAbsolute = Now() - 1
Response.AddHeader "Pragma","No-Cache"
Response.AddHeader "Cache-Control","Private"
Response.CacheControl = "No-Cache"
If not IsArray(Session("info")) Then Response.Redirect "err1.asp?kind=01"
info=Session("info")
If InStr(Application("maninfo"),"," & info(0) & ",")<>0 Then Response.Redirect "manyou.asp"
pollinfo=Application("pollinfo")
If Ubound(pollinfo,1)=0 Then Response.Redirect "err.asp?kind=102"
id=Trim(Request.Form("id"))
v=Trim(Request.Form("v"))
id=Replace(id," ","")
v=Replace(v," ","")
If id="" or v="" Then Response.Redirect "err.asp?kind=103"
If not (IsNumeric(id) and IsNumeric(v)) Then Response.Redirect "err.asp?kind=104"
id=Int(id)
v=Int(v)
If info(1) < Int(pollinfo(id,4)) or info(1) > Int(pollinfo(id,5)) Then Response.Redirect "err.asp?kind=109"
If InStr(pollinfo(id,3),"," & info(0) & ",")<>0 Then Response.Redirect "err.asp?kind=105"
If InStr("|" & pollinfo(id,6) & "|","|" & info(0) & "|")<>0 Then Response.Redirect "err.asp?kind=106"
Set Conn=server.createobject("ADODB.CONNECTION")
Conn.Open Application("zzbird_conn")
Set Rs=Server.CreateObject("ADODB.RECORDSET")
SQL="select * from poll where id=" & pollinfo(id,0)
Rs.open SQL,Conn,1,3
If Rs.EOF and Rs.BOF Then
 Rs.Close
 Set Rs=Nothing
 Conn.Close
 Set Conn=Nothing
 Response.Redirect "err.asp?kind=107"
End If
If InStr(Rs("pollman"),"," & info(0) & ",")<>0 Then
 Rs.Close
 Set Rs=Nothing
 Conn.Close
 Set Conn=Nothing
 Response.Redirect "err.asp?kind=105"
End If
If InStr("|" & Rs("dis_user") & "|","|" & info(0) & "|")<>0 Then
 Rs.Close
 Set Rs=Nothing
 Conn.Close
 Set Conn=Nothing
 Response.Redirect "err.asp?kind=106"
End If
mycounts = Rs("counts")
mypollman = Rs("pollman")
countlist = Split(mycounts,"|")
pollmanlist = Split(mypollman,"|")
countlist(v) = CStr(Int(countlist(v)) + 1)
pollmanlist(v) = pollmanlist(v) & info(0) & ","
mycounts = Join(countlist,"|")
mypollman = Join(pollmanlist,"|")
Rs("counts") = mycounts
Rs("pollman") = mypollman
pollinfo(id,8) = mycounts
pollinfo(id,3) = mypollman
Rs.UpDate
Rs.Close
Set Rs = Nothing
Conn.Close
Set Conn = Nothing
Application.Lock
 Application("pollinfo") = pollinfo
Application.UnLock
%>
<Script Language="JavaScript">
if(confirm("感谢您的投票！点击确定关闭投票窗口，点击取消返回投票中心。"))
{
window.close();
}
else
{
location.href="poll.asp";
}
</Script>