changezt.asp

基于ASP开发的聊天室源码

<%
Response.Expires=0
Response.ExpiresAbsolute=Now()-1
Response.AddHeader "Pragma","No-Cache"
Response.AddHeader "Cache-Control","Private"
Response.CacheControl = "No-Cache"
Dim myonline,id,w1,w2,w3,w4,w5,i,j,newline,nowline
%>
<!--#INCLUDE FILE="function.asp" -->
<%
if not IsArray(Session("info")) then Response.Redirect "err.asp?kind=20"
info=Session("info")
if InStr(Application("maninfo"),"," & info(0) & ",")<>0 then Response.Redirect "manyou.asp"
id=Trim(Request("id"))
if (id="1" and info(4)>84) or (id<>"1" and info(4)<=84) then
Response.Write "<Script>alert('并没有对状态进行更该，操作未执行。');</Script>"
Response.End
end if
 If DateDiff("s",info(9),now) < 3 Then
  info(9)=now
  Session("info")=info
  Response.Write "<script language='javascript'>alert('服务器忙！请3秒钟后重新进行操作！');</script>"
  Response.End
 End If
info(9)=now
oldico=info(4)
if id="1" then
info(4)=int(info(4))+85
else
info(4)=int(info(4))-85
end if
myonline = info(0) & "|" & info(4) & "|" & info(5) & "|" & info(1) & "|" & info(9) & "|" & info(12)
Application.Lock
 online=Application("online" & info(7))
 onno=ubound(online)
 for i=1 to onno
   if InStr(online(i),info(0) & "|")=1 then
     online(i)=myonline
     Application("online" & info(7))=online
   exit for
  end if
 next
Application.UnLock

 w1=info(0)
 w2=myonline
 w3="changeinfo"
 if id="1" then
  w4="[状态]<a target='l3' href=javascript:parent.l3.selectuser('[" & info(0) & "]');><font color='#d90000'>" & info(0) & "</font></a> 把状态从 <img src='images/ico/" & oldico & "-2.gif' height='16'>(在线) 调整为 <img src='images/ico/" & info(4) & "-2.gif' height='16' width='16'>(离开)。<font style='font-size: 8pt' color='#808080'>(" & CStr(time) & ")</font>"
 else
  w4="[状态]<a target='l3' href=javascript:parent.l3.selectuser('[" & info(0) & "]');><font color='#d90000'>" & info(0) & "</font></a> 把状态从 <img src='images/ico/" & oldico & "-2.gif' height='16'>(离开) 调整为 <img src='images/ico/" & info(4) & "-2.gif' height='16' width='16'>(在线)。<font style='font-size: 8pt' color='#808080'>(" & CStr(time) & ")</font>"
 end if
 w5=info(6)
saveword w1,w2,w3,w4,w5
newsay=Application("zzbird_words")
nowline=info(8)
dim show()
Redim Preserve show(0)
j=1
newline=0
for i=1 to 240 step 6
 newline=newsay(i)
 if newline>nowline and newline>0 and not (newsay(i+3)="onlysay" and newsay(i+2)<>info(0) and newsay(i+1)<>info(0) or newsay(i+3)="callyou" and instr(newsay(i+2),info(0)&"|")<>1) then
  Redim Preserve show(j+4)
  show(j)=newsay(i+1)
  show(j+1)=newsay(i+2)
  show(j+2)=newsay(i+3)
  show(j+3)=newsay(i+4)
  show(j+4)=newsay(i+5)
  j=j+5
 end if
next
Response.Write "<script Language=JavaScript>"
for i=1 to UBound(show) step 5
Response.Write "parent.w(" & chr(34) & show(i) & chr(34) & "," & chr(34) & show(i+1) & chr(34) & "," & chr(34) & show(i+2) & chr(34) & "," & chr(34) & show(i+3) & chr(34) & "," & chr(34) & show(i+4) & chr(34) & ");" & chr(13) & chr(10)
next
Response.Write "</script>"
if newline>nowline then info(8)=newline
Session("info")=info%>
<script language="javascript">
parent.l3.document.allsay.myico.src="images/ico/<%=info(4)%>-2.gif";
<%
if Int(info(4))>84 then
%>
parent.l3.document.allsay.saysword.value="你好，我现在有事不在，一会儿再联系。";
parent.l3.document.allsay.send.disabled=1;
parent.l3.document.allsay.ztt.checked=1;
alert("已经将当前状态设置为“离开”");
<%
else
%>
parent.l3.document.allsay.saysword.value="";
parent.l3.document.allsay.send.disabled=0;
parent.l3.document.allsay.ztt.checked=0;
alert("已经将当前状态设置为“在线”");
<%
end if
%>
</script>