aard.ddl

<B>Digital的Unix操作系统VAX 4.2源码</B>

"There is a large wooly mammoth blocking the path to the south.\n");
mammoth(SDESC) = ($say "mammoth");
elephant = mammoth;
pachyderm = mammoth;

NOUN feet;

NOUN diamond(prm12);
diamond(movbl) = 1;
diamond(weight) = 1;
diamond(LDESC) = ($say "There is a small diamond here.\n");
diamond(SDESC) = ($say "diamond");
diamond(rarea) = 2;
diamond(pfound) = 7;
diamond(pplace) = 8;

NOUN ivory(prm15);
ivory(movbl) = 1;
ivory(weight) = 2;
ivory(LDESC) = ($say "There is a piece of ivory here.\n");
ivory(SDESC) = ($say "ivory");
ivory(rarea) = 2;
ivory(pfound) = 9;
ivory(pplace) = 8;

NOUN pendant;
pendant(movbl) = 1;
pendant(weight) = 2;
pendant(LDESC) = ($say "There is a ancient pendant here.\n");
pendant(SDESC) = ($say "pendant");
pendant(rarea) = 2;
pendant(pfound) = 14;
pendant(pplace) = 4;

NOUN cairn;
skulls = cairn;

NOUN bear(prm19);
bear(LDESC) = ($say "There is a ferocious cave bear blocking your path to the
north.\n");
bear(SDESC) = ($say "cave bear");

NOUN necklace(prm20);
necklace(movbl) = 1;
necklace(weight) = 1;
necklace(LDESC) = ($say "There is a pearl necklace here.\n");
necklace(SDESC) = ($say "necklace");
necklace(rarea) = 2;
necklace(pfound) = 13;
necklace(pplace) = 6;

NOUN Tyranosaur;
Tyran = Tyranosaur;

NOUN ring(prm23);
ring(movbl) = 1;
ring(weight) = 1;
ring(LDESC) = ($say "There is a large diamond ring here.\n");
ring(SDESC) = ($say "ring");
ring(rarea) = 2;
ring(pfound) = 13;
ring(pplace) = 10;

NOUN hole;

NOUN newspaper(mrm1);
newspaper(movbl) = 1;
newspaper(weight) = 1;
newspaper(LDESC) = ($say "There is a copy of a newspaper here.\n");
newspaper(SDESC) = ($say "newspaper");

NOUN crack;
NOUN shaft;

{*** VERBS ***}

VERB sign;
VERB read;
VERB throw;
VERB drop;
VERB take;
VERB play;
VERB quit;
VERB look;
VERB inven;
i=inven;l=look;
VERB touch;
VERB eat;
VERB swim;
VERB feed;
VERB score;
VERB abracadabra;
VERB dig;
VERB cut;
VERB plug;
VERB tie;
VERB untie;
VERB on;
VERB off;
VERB light;
VERB open;
VERB close;
VERB wipe;
VERB shake;
VERB xyzzy;
VERB jamb;
plugh = xyzzy;
clean = wipe;
shut = close;
peruse = read;
chuck = throw;
hurl = throw;
toss = throw;
heave = throw;
put = drop;
discard = drop;
get = take;
grab = take;
push = touch;
pet = touch;
devour = eat;
consume = eat;
wade = swim;
ford = swim;
shazam = abracadabra;
hocus = abracadabra;
abra = abracadabra;
excavate = dig;
remove = cut;
end = quit;
bye = quit;

{*** FUNNY OBJECT ROUTINES ***}

paper(ACTION) = (($eq ($verb) sign) :
		(($eq ($prop paper signed) 1) :
		($say "You already signed it.\n")
		($exit 1))
		(($ne ($loc pen) .ME) :
		($say "You don't have anything to write with.\n")
		($exit 1))
		(($ne ($loc paper) .ME) :
		($say "You don't have the release with you.\n")
		($exit 1))
		($setp paper signed 1)
		(($eq ($loc .ME) mrm3) : ($say 
"In a blinding flash of light, a stone archway appears in the east wall!\n")
		($exit 1))
		(($eq ($loc .ME) mrm5) :
		($say "The grate magically disappears into thin air.\n")
		($exit 1))
		($say "You hear strange noises in the nearby rooms.\n")
		($exit 1))
	(($eq ($verb) read) :
		(($ne ($loc paper) .ME) :
		($say "You don't have the paper with you.\n")
		($exit 1))
		($say
"                   THIS CONTRACT LIMITS OUR LIABILITY
                                READ IT

I, the undersigned, will not hold the AARDVARK, the UCLA Computer Sciences
Department, the UCLA Computer Club, Bell Labs, or the Digital Equipment
Corporation responsible for any injuries or deaths due to my executing
this program.\n")
		($setp paper readl 1)($exit 1));

spices(ACTION) = (($and ($eq ($verb) throw) ($eq ($loc .ME) irm8)) :
		($say "The bag of spices lands on the other side of the river.
")
		($move spices irm9)($exit 1))
		(($eq ($verb) eat) :
		($say "Munch, Munch Munch.  It needed a little more salt.\n")
		($move spices .ALL)
		($exit 1) )
		(($and ($eq ($verb) throw) ($eq ($loc .ME) irm9)) :
		($say "The bag of spices gets intercepted by one of the
crocodiles, who promptly swallows it.\n")($move spices .ALL) 
		($exit 1));

rupees(ACTION) = (($and ($eq ($verb) throw)
			($or ($eq ($loc .ME) irm8) ($eq ($loc .ME) irm9))) :
			($say
"The bag is too heavy to throw across the river.  It lands in the middle
of the river and sinks to the bottom.\n")($move rupees .ALL)
			($exit 1));

coconut(ACTION) = (($and ($eq ($loc .ME) irm19) ($eq ($verb) drop)) :
		(($ne ($loc coconut) .ME) :($exit 0))
		(($eq ($prop rupees wellbt) 0) :
		($say "The water in the well rises.\n")
		($move coconut irm19) ($exit 1))
		($say "The water level in the well slowly rises.
Magically floating on the water is a bag of rupees.\n")
		($setp rupees wellbt 0)
		($move rupees irm19)
		($move coconut irm19) ($exit 1))
		(($and ($eq ($verb) eat) ($eq ($loc coconut) .ME)) :
		($say "The coconut is too large for you to consume.\n")
		($exit 1) );

clarinet(ACTION) = (($and ($eq ($verb) play) ($eq ($loc clarinet) .ME)) :
		(($eq ($loc .ME) irm22) :
		(($eq ($loc cobra) irm22) :
		($say "Your clarinet playing sounds so poor that the cobra
slithers off in terror.\n")
		($move cobra .ALL) ($exit 1)))
		(($eq ($loc .ME) irm16) :
		(($eq ($loc rope) irm16) :
		(($eq ($prop rope ropstf) 0) :
		($say "The rope magically extends itself up into the air.\n")
		($setp rope ropstf 1)($exit 1))))
		($say "Benny Goodman you ain't.\n")
		($exit 1));

rope(ACTION) = (($eq ($prop rope ropstf) 1) :
		(($eq ($verb) take) :
		($setp rope ropstf 0))($exit 0))
		(($or ($eq ($loc .ME) prm2) ($eq ($loc .ME) prm3)) :
		(($eq ($prop rope rtied) 1) :
		(($eq ($verb) take) :
		($say "You have to untie the rope first.\n") ($exit 1))
		(($eq ($verb) tie) :
		($say "It's already tied, turkey.\n") ($exit 1))
		(($eq ($verb) untie) :
		(($eq ($loc .ME) prm2) :
		($move rope .ME) ($setp rope rtied 0)
		($say "You untie the rope and coil it up.\n"))
		(($eq ($loc .ME) prm3) :
		($say "It's tied down at the other end.\n"))
		($exit 1)))
		(($eq ($prop rope rtied) 0) :
		(($eq ($verb) tie) :
		(($eq ($loc .ME) prm2) :
		($say "You tie one end of the rope around the pole, the other
end dangles down into the canyon.\n")
		($move rope .ALL)
		($setp rope rtied 1) ($exit 1))
		($say "I see nothing to tie it onto.\n") ($exit 1))
		(($eq ($verb) untie) :
		($say "It's already untied.\n"))))
		(($eq ($loc .ME) prm3) :
		(($eq ($verb) take) : ($say
"You can't take it, the other end is tied down.\n") ($exit 1))
		(($eq ($verb) untie) : ($say
"the knot is on the other end.\n") ($exit 1)));

river(ACTION) = (($and ($ne ($loc .ME) irm8) ($ne ($loc .ME) irm9)) :
		($say "I see no river here.\n")($exit 1))
		(($eq ($verb) take) :
		($say "I can't do that.\n") ($exit 1));

cobra(ACTION) = (($and ($eq ($verb) take) ($eq ($loc .ME) ($loc cobra))) :
		($say "That would be a poor idea.\n")($exit 1));

crocodile(ACTION) = (($eq ($verb) take) :
		($say "I can't get to any crocodiles from here.\n")
		($exit 1));

cmara = (($eq ($verb) take) :
	($say "The statue is too heavy for you to carry.\n")
	($exit 1));
claks = (($and ($or ($eq ($verb) take) ($eq ($verb) touch))
	($eq ($prop statue tlakst) 0)) :
	($say
"The statue slides away very easily, revealing a secret passage.\n")
		($setp statue tlakst 1)($exit 1));
mara(ACTION) = (($eq ($loc .ME) irm10) : (cmara));
vishnu(ACTION) = (($eq ($loc .ME) irm11) : (cmara));
lakshmi(ACTION) = (($eq ($loc .ME) irm12) : (claks));
statue(ACTION) = (($or ($eq ($loc .ME) irm10) ($eq ($loc .ME) irm11)) :
		(cmara)
		($say "That won't accomplish anything.\n")
		($exit 1))
		(($eq ($loc .ME) irm12) : (claks)
		($say "I don't see how you can do that to a statue.\n")
		($exit 1));

banana(ACTION) = (($eq ($loc banana) .ME) :
		(($eq ($verb) eat) :
		($say "You eat the banana, peel and all.\n")
		($move banana .ALL)
		($exit 1)))
		(($eq ($loc .ME) irm20) :
		(($eq ($verb) drop) :
		($say "The monkey picks up the banana, eats it, and discards
the banana-peel.  As soon as the monkey finishes eating
the banana, a bolt of lighting hits the stone slab and 
cracks it open.\n")
		($setp monkey fedmky 1)
		($move banana .ALL)
		($move peel irm20) ($exit 1)));

horn(ACTION) = (($eq ($prop rhino cutflg) 1) : ($exit 0))
		(($eq ($loc .ME) irm13) : 
		(($eq ($verb) take) :
		($say "It is still attached to the rhino.\n")
		($exit 1))
		(($eq ($verb) cut) :
		(($ne ($loc saw) .ME) :
		($say "You don't have something to cut the horn with.\n")
		($exit 1))
		(($eq ($prop rhino earplg) 1) :
		($say "You cut the horn off without waking up the rhino.\n")
		($setp rhino cutflg 1)
		($move horn irm13) ($exit 1))
		($say "The noise of the sawing wakes up the rhinoceros who
tramples you to death because you disturbed his beauty sleep.\n")
		(exitg)));

lattice(ACTION) = (($eq ($loc .ME) irm13) :
		(($eq ($verb) take) :
		(($eq ($prop rhino earplg) 1) :
		($say "You successfully take the lattice without waking the
rhino.  Unfortunately, the lattice was the structure which supported the roof
of the room, and the ceiling comes crashing down upon you and breaks every 
bone in your body.\n"))
		(($eq ($prop rhino earplg) 0) :
		($say "As you take the lattice, a large part of the bamboo
falls down.  The noise caused by the falling bamboo scares the sleeping
rhinoceros who tramples you in his panicked exit from the room.\n"))
		(exitg)));

monkey(ACTION) = (($eq ($loc .ME) irm20) :
		(($eq ($verb) feed) :
		(($eq ($loc banana) .ME) :
		($say "The monkey takes your banana, peels it, eats it,
and throws away the banana peel.  As soon as he finishes eating
the banana, there is a rumble from the depths of the earth and 
a crack appears in the stone slab.\n")
		($setp monkey fedmky 1)
		($move banana .ALL)
		($move peel irm20) ($exit 1))));

cotton(ACTION) = (($eq ($loc .ME) irm13) :
		(($and ($eq ($verb) drop) ($eq ($iobj) ears)) :
		($say
"You stick the wads of cotton into the rhino's ears.\n")
		($move cotton .ALL)
		($setp rhino earplg 1)
		($exit 1)))
		(($eq ($loc cotton) .ALL):
		(($eq ($loc .ME) irm13):
		(($eq ($verb) take) :
		($say "OK\n")
		($move cotton .ME)
		($setp rhino earplg 0)
		($exit 1))));

pole(ACTION) = (($and ($eq ($loc .ME) prm2) ($eq ($verb) take)) :
		($say "The pole is firmly cemented into the ground.\n")
		($exit 1));

lamp(ACTION) = (($eq ($verb) light) : (onlmp) ($exit 1));

oven(ACTION) = (($and ($eq ($loc .ME) irm4) ($eq ($verb) open)) :
		($say "The door of the oven doesn't budge.\n")
		($exit 1));

grate(ACTION) = (($and ($eq ($prop paper signed) 0)
			($eq ($loc .ME) mrm5)) :
		(($or ($eq ($verb) open) ($eq ($verb) take)) :
			($say
"The grate appears to be firmly cemented into the wall.\n")
		($exit 1))
		(($eq ($verb) shut) :
		($say "The grate is already shut.\n")($exit 1)));

weapo = (($eq ($verb) throw) :
	(($and ($eq ($prop bear hitbr) 0) ($eq ($loc .ME) prm19)) :
	($say "The axe bounces harmlessly off of the bear.\n")
	($move axe prm19) ($exit 1))
	(($eq ($loc .ME) prm14) :
	($say "The weapon that you just threw imbeds itself deep into the 
skull of the mammoth and is covered by the mammoth's long fur so that it
can't be seen.  The mammoth just stares back at you blankly.\n")
	($move ($dobj) .ALL) ($exit 1))
	(($or ($eq ($loc .ME) irm8) ($eq ($loc .ME) irm9)) :
	($say "You miss the crocodile and your weapon sinks into the river.\n")
	($move ($dobj) .ALL) ($exit 1))
	(($eq ($loc .ME) irm13):
	($say "Your weapon bounces harmlessly off of the rhino.\n")
	($move ($dobj) irm13) ($exit 1))
	(($and ($eq ($loc .ME) prm6) ($eq ($prop smilo stond) 0)) :
	($say "The sabre-tooth catches your weapon in its mouth and promptly
swallows it.\n") ($move ($dobj) .ALL) ($exit 1))
	(($and ($eq ($loc .ME) prm8) ($eq ($prop trogl killd) 0)) :
	($say "You hit the troglodyte, who, screaming in pain, drops the
gold nugget and falls over the cliff.\n") ($setp trogl killd 1)
	($move ($dobj) .ALL)
	($move nugget prm8) ($exit 1)));

spear(ACTION) = (($eq ($loc spear) .ME) : 
		(($ne ($loc .ME) prm19) :
		(weapo))
		(($eq ($loc .ME) prm19) :
		(($eq ($verb) throw) :
		($say
"You repeatedly throw your spear at the bear.  Eventually, he gets
bored and wanders off.\n")
		($move bear .ALL)
		($move spear prm19)
		($setp bear hitbr 1) ($exit 1) )))
		(($eq ($loc .ME) prm17) :