ad_tab_import.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE AD_Tab_Import
(
	p_PInstance_ID    		IN NUMBER,
	p_AD_Tab_ID				IN NUMBER 	--	DEFAULT NULL
)
/*************************************************************************
 * The contents of this file are subject to the Compiere License.  You may
 * obtain a copy of the License at    http://www.compiere.org/license.html 
 * Software is on an  "AS IS" basis,  WITHOUT WARRANTY OF ANY KIND, either 
 * express or implied. See the License for details. Code: Compiere ERP+CPM
 * Copyright (C) 1999-2001 Jorg Janke, ComPiere, Inc. All Rights Reserved.
 *************************************************************************
 * $Id: AD_Tab_Import.sql,v 1.4 2002/11/18 06:11:18 jjanke Exp $
 ***
 * Title:	Import Field Definitions
 * Description:
 *			Import the Fields of the Tab not existing yet
 ************************************************************************/
AS
	--	Logistice
	v_ResultStr						VARCHAR2(2000);
	v_Message						VARCHAR2(2000);
	v_Result						NUMBER := 1;	-- 0=failure
	v_Record_ID						NUMBER;
	v_AD_User_ID					NUMBER := 0;
	--	Parameter
	CURSOR Cur_Parameter (pp_PInstance NUMBER) IS
		SELECT i.Record_ID, i.AD_User_ID,
			p.ParameterName, p.P_String, p.P_Number, p.P_Date
		FROM AD_PInstance i, AD_PInstance_Para p
		WHERE i.AD_PInstance_ID=pp_PInstance
		AND i.AD_PInstance_ID=p.AD_PInstance_ID(+)
		ORDER BY p.SeqNo;
	--	Parameter Variables
	--	Variables
	CURSOR  Cur_Column (Tab NUMBER, TableID NUMBER)  IS
		SELECT  Name, Description, AD_Column_ID, FieldLength, EntityType 
		FROM    AD_Column c
		WHERE NOT EXISTS 
			(SELECT * FROM AD_Field f 
			WHERE c.AD_Column_ID=f.AD_Column_ID
			AND c.AD_Table_ID=TableID
			AND f.AD_Tab_ID=Tab) 
		AND AD_Table_ID=TableID
		AND NOT (UPPER(Name) LIKE 'CREATED%' OR UPPER(Name) LIKE 'UPDATED%')
		AND IsActive='Y';
	--
	v_NextNo		NUMBER(10);
	v_AD_Table_ID	NUMBER(10);
	v_count			NUMBER(10) := 0;

BEGIN
	IF (p_PInstance_ID IS NOT NULL) THEN
	    --  Update AD_PInstance
		DBMS_OUTPUT.PUT_LINE('Updating PInstance - Processing ' || p_PInstance_ID);
		v_ResultStr := 'PInstanceNotFound';
    	UPDATE AD_PInstance
	    SET Created = SysDate,
    	    IsProcessing = 'Y'
	    WHERE AD_PInstance_ID=p_PInstance_ID;
    	COMMIT;
		--	Get Parameters
		v_ResultStr := 'ReadingParameters';
		FOR p IN Cur_Parameter (p_PInstance_ID) LOOP
			v_Record_ID := p.Record_ID;
			v_AD_User_ID := p.AD_User_ID;
		END LOOP;	--	Get Parameter
	ELSE
		v_Record_ID := p_AD_Tab_ID;
	END IF;
	DBMS_OUTPUT.PUT_LINE('  Record_ID=' || v_Record_ID);

	SELECT	AD_Table_ID
	  INTO	v_AD_Table_ID
	FROM	AD_Tab
	WHERE	AD_Tab_ID = v_Record_ID
	  AND	AD_Table_ID != 291;	-- C_BPartner (multiple tabs)

	FOR CC IN Cur_Column (v_Record_ID, v_AD_Table_ID) LOOP
		AD_Sequence_Next('AD_Field', 0, v_NextNo);	--	get ID
		INSERT INTO AD_Field
			(ad_field_id, ad_client_id, ad_org_id,
			isactive, created, createdby, updated, updatedby,
			name, description, 
			seqno, AD_Tab_ID, AD_Column_ID, DisplayLength, 
			IsCentrallyMaintained, EntityType)
		VALUES
			(v_NextNo, 0, 0,
			'Y', SysDate, 0, SysDate, 0,
			CC.Name, CC.Description,
			0, v_Record_ID, CC.AD_Column_ID, CC.FieldLength, 
			'Y', CC.EntityType);
		--
		v_count := v_count + 1;
		IF (p_PInstance_ID IS NOT NULL) THEN
			INSERT INTO AD_PInstance_Log (AD_PInstance_ID, Log_ID, 
				P_Msg)
			  VALUES (p_PInstance_ID, AD_PInstance_Seq.NextVal, 
			  	'@Created@ @AD_Field_ID@ ' || CC.Name);
		ELSE
			DBMS_OUTPUT.PUT_LINE(' adding ' || CC.Name);
		END IF;
	END LOOP;   --  for all columns

	--	Summary info
	v_Message := '@Created@ = ' || v_count;


<<FINISH_PROCESS>>
	IF (p_PInstance_ID IS NOT NULL) THEN
		--  Update AD_PInstance
		DBMS_OUTPUT.PUT_LINE('Updating PInstance - Finished ' || v_Message);
    	UPDATE  AD_PInstance
	    SET Updated = SysDate,
    	    IsProcessing = 'N',
	        Result = v_Result,			-- 1=success
    	    ErrorMsg = v_Message
	    WHERE   AD_PInstance_ID=p_PInstance_ID;
	ELSE
		DBMS_OUTPUT.PUT_LINE('Finished ' || v_Message);
	END IF;
    COMMIT;
    RETURN;

EXCEPTION
    WHEN  OTHERS THEN
		v_ResultStr := v_ResultStr || ': ' || SQLERRM || ' - ' || v_Message;
		DBMS_OUTPUT.PUT_LINE(v_ResultStr);
		ROLLBACK;
		IF (p_PInstance_ID IS NOT NULL) THEN
    	    UPDATE  AD_PInstance
        	SET Updated = SysDate,
            	IsProcessing = 'N',
	            Result = 0,             -- failure
    	        ErrorMsg = v_ResultStr
        	WHERE   AD_PInstance_ID=p_PInstance_ID;
			COMMIT;
		END IF;
        RETURN;

END AD_Tab_Import;
/