c_project_copy.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE C_Project_Copy
(
	p_PInstance_ID    		IN NUMBER
)
/*************************************************************************
 * The contents of this file are subject to the Compiere License.  You may
 * obtain a copy of the License at    http://www.compiere.org/license.html
 * Software is on an  "AS IS" basis,  WITHOUT WARRANTY OF ANY KIND, either
 * express or implied. See the License for details. Code: Compiere ERP+CRM
 * Copyright (C) 1999-2001 Jorg Janke, ComPiere, Inc. All Rights Reserved.
 *************************************************************************
 * $Id: C_Project_Copy.sql,v 1.2 2002/05/22 02:48:28 jjanke Exp $
 ***
 * Title:	Copy lines from another Project
 * Description:
 ************************************************************************/
AS
	--	Logistice
	v_ResultStr						VARCHAR2(2000);
	v_Message						VARCHAR2(2000);
	v_Record_ID						NUMBER;
	--	Parameter
	CURSOR Cur_Parameter (pp_PInstance NUMBER) IS
		SELECT i.Record_ID, p.ParameterName, p.P_String, p.P_Number, p.P_Date
		FROM AD_PInstance i, AD_PInstance_Para p
		WHERE i.AD_PInstance_ID=pp_PInstance
		AND i.AD_PInstance_ID=p.AD_PInstance_ID(+)
		ORDER BY p.SeqNo;
	--	Parameter Variables
	p_C_Project_ID					NUMBER;

BEGIN
    --  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Processing ' || p_PInstance_ID);
	v_ResultStr := 'PInstanceNotFound';
    UPDATE AD_PInstance
    SET Created = SysDate,
        IsProcessing = 'Y'
    WHERE AD_PInstance_ID=p_PInstance_ID;
    COMMIT;

	--	Get Parameters
	v_ResultStr := 'ReadingParameters';
	FOR p IN Cur_Parameter (p_PInstance_ID) LOOP
		v_Record_ID := p.Record_ID;
		IF (p.ParameterName = 'C_Project_ID') THEN
 			p_C_Project_ID := p.P_Number;
			DBMS_OUTPUT.PUT_LINE('  C_Project_ID=' || p_C_Project_ID);
		ELSE
			DBMS_OUTPUT.PUT_LINE('*** Unknown Parameter=' || p.ParameterName);
	 	END IF;
	END LOOP;	--	Get Parameter
	DBMS_OUTPUT.PUT_LINE('  Record_ID=' || v_Record_ID);


	--	Copy Lines from p_C_Project_ID to Record_ID
	DECLARE
		CURSOR CUR_Project IS
			SELECT 	*
			FROM	C_ProjectLine
			WHERE	C_Project_ID=p_C_Project_ID
			  AND	IsActive='Y';
	   	v_NextNo					NUMBER;
	BEGIN
		FOR l IN CUR_Project LOOP
			v_ResultStr := 'CopyLines';
			--	Get SeqNo
			AD_Sequence_Next ('C_ProjectLine', l.AD_Client_ID, v_NextNo);
			--	Insert
			INSERT INTO C_ProjectLine (C_ProjectLine_ID, C_Project_ID,
				AD_Client_ID, AD_Org_ID, IsActive, Created, CreatedBy, Updated, UpdatedBy,
				Line, Description,
				PlannedQty, PlannedPrice, PlannedAmt, PlannedMarginAmt, 
				CommittedAmt, ActualAmt, M_Product_ID, M_Product_Category_ID)
			VALUES	(v_NextNo, v_Record_ID,
				l.AD_Client_ID, l.AD_Org_ID, 'Y', SysDate, 0, SysDate, 0,
				l.Line, l.Description,
				l.PlannedQty, l.PlannedPrice, l.PlannedAmt, l.PlannedMarginAmt, 
				l.CommittedAmt, l.ActualAmt, l.M_Product_ID, l.M_Product_Category_ID);
		END LOOP;
	END;


<<FINISH_PROCESS>>
	--  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Finished ' || v_Message);
    UPDATE  AD_PInstance
    SET Updated = SysDate,
        IsProcessing = 'N',
        Result = 1,                 -- success
        ErrorMsg = v_Message
    WHERE   AD_PInstance_ID=p_PInstance_ID;
    COMMIT;
    RETURN;

EXCEPTION
    WHEN  OTHERS THEN
		v_ResultStr := v_ResultStr || ': ' || SQLERRM || ' - ' || v_Message;
		DBMS_OUTPUT.PUT_LINE(v_ResultStr);
		ROLLBACK;
        UPDATE  AD_PInstance
        SET Updated = SysDate,
            IsProcessing = 'N',
            Result = 0,             -- failure
            ErrorMsg = v_ResultStr
        WHERE   AD_PInstance_ID=p_PInstance_ID;
        COMMIT;
        RETURN;

END C_Project_Copy;
/