c_invoice_cancel.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE C_Invoice_Cancel
(
	PInstance_ID    		IN NUMBER,
	Order_ID				IN NUMBER	DEFAULT NULL
)
AS
/******************************************************************************
 * ** Compiere Product **             Copyright (c) 1999-2001 Accorto, Inc. USA
 * Open  Source  Software        Provided "AS IS" without warranty or liability
 * When you use any parts (changed or unchanged), add  "Powered by Compiere" to
 * your product name;  See license details http://www.compiere.org/license.html
 ******************************************************************************
 *	Cancel Invoices of order by reversing it
 */
	--	Logistice
	ResultStr						VARCHAR2(2000);
	Message							VARCHAR2(2000);
	Record_ID						NUMBER;
	--	Parameter
	CURSOR Cur_Parameter (PInstance NUMBER) IS
		SELECT i.Record_ID, p.ParameterName, p.P_String, p.P_Number, p.P_Date
		FROM AD_PInstance i, AD_PInstance_Para p
		WHERE i.AD_PInstance_ID=PInstance
		AND i.AD_PInstance_ID=p.AD_PInstance_ID(+)
		ORDER BY p.SeqNo;
	--	Parameter Variables

	--
	CURSOR Cur_Invoice (OrderID NUMBER) IS
		SELECT 	*
		FROM	C_Invoice
		WHERE	C_Order_ID = OrderID
		  AND	DocStatus <> 'RE'		--	Not the existing reversal trx
		FOR UPDATE;

BEGIN
    --  Update AD_PInstance
	IF (PInstance_ID IS NOT NULL) THEN
		DBMS_OUTPUT.PUT_LINE('Updating PInstance - Processing ' || PInstance_ID);
    	ResultStr := 'PInstanceNotFound';
	    UPDATE AD_PInstance
    	SET Created = SysDate,
	        IsProcessing = 'Y'
    	WHERE AD_PInstance_ID=PInstance_ID;
	    COMMIT;
		--	Get Parameters
		ResultStr := 'ReadingParameters';
		FOR p IN Cur_Parameter (PInstance_ID) LOOP
			Record_ID := p.Record_ID;
		END LOOP;	--	Get Parameter
		DBMS_OUTPUT.PUT_LINE('  Record_ID=' || Record_ID);
	ELSE
		Record_ID := Order_ID;
	END IF;
	IF (Record_ID IS NULL) THEN
		RETURN;
  	END IF;


	--	For all invoices of order
	FOR i IN Cur_Invoice (Record_ID) LOOP
		DBMS_OUTPUT.PUT_LINE('Cancel Invoice ' || i.DocumentNo || ', ID=' || i.C_Invoice_ID);
		
		UPDATE	C_Invoice
		  SET	DocAction = 'RC',		--	Reverse Correction
		  		Processed = 'N',
		  		Updated = SysDate
		WHERE CURRENT OF Cur_Invoice;
		C_Invoice_Post (NULL, i.C_Invoice_ID); 

	END LOOP;	--	Order Loop


<<FINISH_PROCESS>>
	IF (PInstance_ID IS NOT NULL) THEN
		--  Update AD_PInstance
		DBMS_OUTPUT.PUT_LINE('Updating PInstance - Finished ' || Message);
	    UPDATE  AD_PInstance
    	SET Updated = SysDate,
        	IsProcessing = 'N',
	        Result = 1,                 -- success
    	    ErrorMsg = Message
	    WHERE   AD_PInstance_ID=PInstance_ID;
	    COMMIT;
	END IF;
    RETURN;

EXCEPTION
    WHEN  OTHERS THEN
		ResultStr := ResultStr || ': ' || SQLErrM || ' - ' || Message;
		DBMS_OUTPUT.PUT_LINE(ResultStr);
		IF (PInstance_ID IS NOT NULL) THEN
	        UPDATE  AD_PInstance
    	    SET Updated = SysDate,
        	    IsProcessing = 'N',
            	Result = 0,             -- failure
	            ErrorMsg = ResultStr
    	    WHERE   AD_PInstance_ID=PInstance_ID;
        	COMMIT;
		ELSE
			DECLARE
				v_Code 	NUMBER 			:= SQLCode;
			BEGIN
				INSERT INTO DBA_ErrorLog (DBA_ErrorLog_ID,Created,Code,Msg,Info)
				VALUES (DBA_ErrorLog_Seq.NextVal,SysDate,v_Code,ResultStr,'C_Invoice_Cancel');
			END;
	   	END IF;
        RETURN;

END C_Invoice_Cancel;
/