m_discountschema_reseq.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE M_DiscountSchema_ReSeq
(
	p_PInstance_ID    		IN NUMBER
)
/*************************************************************************
 * The contents of this file are subject to the Compiere License.  You may
 * obtain a copy of the License at    http://www.compiere.org/license.html 
 * Software is on an  "AS IS" basis,  WITHOUT WARRANTY OF ANY KIND, either 
 * express or implied. See the License for details. Code: Compiere ERP+CPM
 * Copyright (C) 1999-2001 Jorg Janke, ComPiere, Inc. All Rights Reserved.
 *************************************************************************
 * $Id: M_DiscountSchema_ReSeq.sql,v 1.2 2002/10/21 04:49:46 jjanke Exp $
 ***
 * Title:	Resequence Discount entries
 * Description:
 ************************************************************************/
AS
	--	Logistice
	v_ResultStr						VARCHAR2(2000);
	v_Message						VARCHAR2(2000);
	v_Result						NUMBER := 1;	-- 0=failure
	v_Record_ID						NUMBER;
	v_AD_User_ID					NUMBER;
	--	Parameter
	CURSOR Cur_Parameter (pp_PInstance NUMBER) IS
		SELECT i.Record_ID, i.AD_User_ID,
			p.ParameterName, p.P_String, p.P_Number, p.P_Date
		FROM AD_PInstance i, AD_PInstance_Para p
		WHERE i.AD_PInstance_ID=pp_PInstance
		AND i.AD_PInstance_ID=p.AD_PInstance_ID(+)
		ORDER BY p.SeqNo;
	--	Parameter Variables
	--
	v_NextNo 						NUMBER;
	v_Count 						NUMBER := 0;
BEGIN
    --  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Processing ' || p_PInstance_ID);
	v_ResultStr := 'PInstanceNotFound';
    UPDATE AD_PInstance
    SET Created = SysDate,
        IsProcessing = 'Y'
    WHERE AD_PInstance_ID=p_PInstance_ID;
    COMMIT;

	--	Get Parameters
	v_ResultStr := 'ReadingParameters';
	FOR p IN Cur_Parameter (p_PInstance_ID) LOOP
		v_Record_ID := p.Record_ID;
		v_AD_User_ID := p.AD_User_ID;
	END LOOP;	--	Get Parameter
	DBMS_OUTPUT.PUT_LINE('  Record_ID=' || v_Record_ID);

	--	Line
	v_ResultStr := 'ResequenceLine';
	DECLARE
		CURSOR Cur_Line IS
			SELECT	M_DiscountSchemaLine_ID
			FROM	M_DiscountSchemaLine
			WHERE	M_DiscountSchema_ID=v_Record_ID
			ORDER BY SeqNo
			FOR UPDATE OF SeqNo;
	BEGIN
		v_NextNo := 10;
		FOR l IN Cur_Line LOOP
			UPDATE	M_DiscountSchemaLine
			  SET	SeqNo = v_NextNo
			WHERE CURRENT OF Cur_Line;
			v_NextNo := v_NextNo + 10;
			v_Count := v_Count + 1;
		END LOOP;
	END;	--	Line

	--	Break
	v_ResultStr := 'ResequenceBreak';
	DECLARE
		CURSOR Cur_Break IS
			SELECT	M_DiscountSchemaBreak_ID
			FROM	M_DiscountSchemaBreak
			WHERE	M_DiscountSchema_ID=v_Record_ID
			ORDER BY SeqNo
			FOR UPDATE OF SeqNo;
	BEGIN
		v_NextNo := 10;
		FOR b IN Cur_Break LOOP
			UPDATE	M_DiscountSchemaLine
			  SET	SeqNo = v_NextNo
			WHERE CURRENT OF Cur_Break;
			v_NextNo := v_NextNo + 10;
			v_Count := v_Count + 1;
		END LOOP;
	END;	--	Line

	v_Message := '@Updated@ ' || v_Count;


<<FINISH_PROCESS>>
	--  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Finished ' || v_Message);
    UPDATE  AD_PInstance
    SET Updated = SysDate,
        IsProcessing = 'N',
        Result = v_Result,			-- 1=success
        ErrorMsg = v_Message
    WHERE   AD_PInstance_ID=p_PInstance_ID;
    COMMIT;
    RETURN;

EXCEPTION
    WHEN  OTHERS THEN
		v_ResultStr := v_ResultStr || ': ' || SQLERRM || ' - ' || v_Message;
		DBMS_OUTPUT.PUT_LINE(v_ResultStr);
		ROLLBACK;
        UPDATE  AD_PInstance
        SET Updated = SysDate,
            IsProcessing = 'N',
            Result = 0,             -- failure
            ErrorMsg = v_ResultStr
        WHERE   AD_PInstance_ID=p_PInstance_ID;
        COMMIT;
        RETURN;

END M_DiscountSchema_ReSeq;
/