c_periodcontrol_process.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE C_PeriodControl_Process
(
	p_PInstance_ID    		IN NUMBER
)
/*************************************************************************
 * The contents of this file are subject to the Compiere License.  You may
 * obtain a copy of the License at    http://www.compiere.org/license.html
 * Software is on an  "AS IS" basis,  WITHOUT WARRANTY OF ANY KIND, either
 * express or implied. See the License for details. Code: Compiere ERP+CRM
 * Copyright (C) 1999-2001 Jorg Janke, ComPiere, Inc. All Rights Reserved.
 *************************************************************************
 * $Id: C_PeriodControl_Process.sql,v 1.2 2002/05/22 02:48:28 jjanke Exp $
 ***
 * Title:	Opens/Close Period Control
 * Description:
 ************************************************************************/
AS
	--	Logistice
	v_ResultStr						VARCHAR2(2000);
	v_Message						VARCHAR2(2000);
	v_Record_ID						NUMBER;
	--	Parameter
	CURSOR Cur_Parameter (pp_PInstance NUMBER) IS
		SELECT i.Record_ID, p.ParameterName, p.P_String, p.P_Number, p.P_Date
		FROM AD_PInstance i, AD_PInstance_Para p
		WHERE i.AD_PInstance_ID=pp_PInstance
		AND i.AD_PInstance_ID=p.AD_PInstance_ID(+)
		ORDER BY p.SeqNo;
	--	Variables
	v_PeriodAction				C_PeriodControl.PeriodAction%TYPE;
BEGIN
    --  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Processing ' || p_PInstance_ID);
	v_ResultStr := 'PInstanceNotFound';
    UPDATE AD_PInstance
    SET Created = SysDate,
        IsProcessing = 'Y'
    WHERE AD_PInstance_ID=p_PInstance_ID;
    COMMIT;

	--	Get Parameters
	v_ResultStr := 'ReadingParameters';
	FOR p IN Cur_Parameter (p_PInstance_ID) LOOP
		v_Record_ID := p.Record_ID;
	END LOOP;	--	Get Parameter
	DBMS_OUTPUT.PUT_LINE('  Record_ID=' || v_Record_ID);


	v_ResultStr := 'ReadingAction';
	SELECT	PeriodAction
	  INTO	v_PeriodAction
	FROM	C_PeriodControl
	WHERE	C_PeriodControl_ID = v_Record_ID
	FOR UPDATE OF PeriodStatus;

	v_ResultStr := 'UpdatingStatus';
	-- Action: Open if not permanently closed
	IF (v_PeriodAction = 'O') THEN
		UPDATE	C_PeriodControl
		  SET	PeriodStatus = 'O',
		  		PeriodAction = 'N'
	  	WHERE	C_PeriodControl_ID = v_Record_ID
		  AND	PeriodStatus <> 'P';
	-- Action: Close if not permanently closed
	ELSIF (v_PeriodAction = 'C') THEN
		UPDATE	C_PeriodControl
		  SET	PeriodStatus = 'C',
		  		PeriodAction = 'N'
	  	WHERE	C_PeriodControl_ID = v_Record_ID
		  AND	PeriodStatus <> 'P';
	-- Action: Permanently Close
	ELSIF (v_PeriodAction = 'P') THEN
		UPDATE	C_PeriodControl
		  SET	PeriodStatus = 'P',
		  		PeriodAction = 'N'
	  	WHERE	C_PeriodControl_ID = v_Record_ID;
	END IF;


<<FINISH_PROCESS>>
	--  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Finished ' || v_Message);
    UPDATE  AD_PInstance
    SET Updated = SysDate,
        IsProcessing = 'N',
        Result = 1,                 -- success
        ErrorMsg = v_Message
    WHERE   AD_PInstance_ID=p_PInstance_ID;
    COMMIT;
    RETURN;

EXCEPTION
    WHEN  OTHERS THEN
		v_ResultStr := v_ResultStr || ': ' || SQLERRM || ' - ' || v_Message;
		DBMS_OUTPUT.PUT_LINE(v_ResultStr);
		ROLLBACK;
        UPDATE  AD_PInstance
        SET Updated = SysDate,
            IsProcessing = 'N',
            Result = 0,             -- failure
            ErrorMsg = v_ResultStr
        WHERE   AD_PInstance_ID=p_PInstance_ID;
        COMMIT;
        RETURN;

END C_PeriodControl_Process;
/