c_elementvalue_copy.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE C_ElementValue_Copy
(
    Source_Element_ID   IN  NUMBER,
    Target_Element_ID   IN  NUMBER
)
AS
/******************************************************************************
 * ** Compiere Product **             Copyright (c) 1999-2001 Accorto, Inc. USA
 * Open  Source  Software        Provided "AS IS" without warranty or liability
 * When you use any parts (changed or unchanged), add  "Powered by Compiere" to
 * your product name;  See license details http://www.compiere.org/license.html
 ******************************************************************************
 *  Copies CoA
 *	All element values of Source_Element_ID to Target_Element_ID
 */
    CURSOR Cur_ElementValue IS
        SELECT  * 
        FROM    C_ElementValue
        WHERE   C_Element_ID = Source_Element_ID
          AND   IsActive='Y';
    xAD_Client_ID   NUMBER;
    xAD_Org_ID      NUMBER;
    xUpdated        DATE;
    xUpdatedBy      NUMBER;
    NextNo          NUMBER;
BEGIN
    --  Get target base info
    SELECT  AD_Client_ID, AD_Org_ID, Updated, UpdatedBy
      INTO  xAD_Client_ID, xAD_Org_ID, xUpdated, xUpdatedBy
    FROM    C_Element
    WHERE   C_Element_ID = Target_Element_ID;

    FOR CEV IN Cur_ElementValue LOOP
        AD_Sequence_Next('C_ElementValue', Target_Element_ID, NextNo);

        INSERT INTO C_ElementValue
            (C_ElementValue_ID, C_Element_ID,
            AD_Client_ID, AD_Org_ID, IsActive, Created, CreatedBy, Updated, UpdatedBy,
            Value, Name, Description,
            AccountType, AccountSign, IsDocControlled,
            IsSummary, ValidFrom, ValidTo,
            PostActual, PostBudget, PostEncumbrance, PostStatistical,
            IsForeignCurrency, C_Currency_ID)
        VALUES
            (NextNo, Target_Element_ID,
            xAD_Client_ID, xAD_Org_ID, 'Y', xUpdated, xUpdatedBy, xUpdated, xUpdatedBy,
            cev.Value, cev.Name, cev.Description,
            cev.AccountType, cev.AccountSign, cev.IsDocControlled,
            cev.IsSummary, cev.ValidFrom, cev.ValidTo,
            cev.PostActual, cev.PostBudget, cev.PostEncumbrance, cev.PostStatistical,
            cev.IsForeignCurrency, cev.C_Currency_ID);
    END LOOP;
    COMMIT;
END C_ElementValue_Copy;
/