m_product_category_acct_copy.sql

Java写的ERP系统

CREATE OR REPLACE PROCEDURE M_Product_Category_Acct_Copy
(
	PInstance_ID    		IN NUMBER,
	Product_Category_ID		IN NUMBER 	DEFAULT NULL	--	direct call
)
/*************************************************************************
 * The contents of this file are subject to the Compiere License.  You may
 * obtain a copy of the License at    http://www.compiere.org/license.html
 * Software is on an  "AS IS" basis,  WITHOUT WARRANTY OF ANY KIND, either
 * express or implied. See the License for details. Code: Compiere ERP+CRM
 * Copyright (C) 1999-2001 Jorg Janke, ComPiere, Inc. All Rights Reserved.
 *************************************************************************
 * $Id: M_Product_Category_Acct_Copy.sql,v 1.3 2002/10/28 15:14:35 jjanke Exp $
 ***
 * Title:	Copy Accounts
 * Description:
 ************************************************************************/
AS
	--	Logistice
	ResultStr						VARCHAR2(2000);
	Message							VARCHAR2(2000);
	Record_ID						NUMBER;
	--	Parameter
	CURSOR Cur_Parameter (PInstance NUMBER) IS
		SELECT i.Record_ID, p.ParameterName, p.P_String, p.P_Number, p.P_Date
		FROM AD_PInstance i, AD_PInstance_Para p
		WHERE i.AD_PInstance_ID=PInstance
		AND i.AD_PInstance_ID=p.AD_PInstance_ID(+)
		ORDER BY p.SeqNo;
	--
	M_Product_Category_ID			NUMBER;
	--	Product Category is unique to Client
 	CURSOR	Cur_Acct (Product_Category_ID NUMBER)	IS
		SELECT 	*
		FROM	M_Product_Category_Acct
		WHERE	M_Product_Category_ID = Product_Category_ID;
  	--
	Updated							NUMBER := 0;
	Created							NUMBER := 0;
	Updated_Total					NUMBER := 0;
	Created_Total					NUMBER := 0;

BEGIN
    --  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Processing ' || PInstance_ID);
    ResultStr := 'PInstanceNotFound';
    UPDATE AD_PInstance
    SET Created = SysDate,
        IsProcessing = 'Y'
    WHERE AD_PInstance_ID=PInstance_ID;
    COMMIT;

	--	Get Parameters
	ResultStr := 'ReadingParameters';
	FOR p IN Cur_Parameter (PInstance_ID) LOOP
		Record_ID := p.Record_ID;
		IF (p.ParameterName = 'M_Product_Category_ID') THEN
 			M_Product_Category_ID := p.P_Number;
			DBMS_OUTPUT.PUT_LINE('  M_Product_Category_ID=' || M_Product_Category_ID);
		ELSE
			DBMS_OUTPUT.PUT_LINE('*** Unknown Parameter=' || p.ParameterName);
	 	END IF;
	END LOOP;	--	Get Parameter
	DBMS_OUTPUT.PUT_LINE('  Record_ID=' || Record_ID);

	--	Direct Call
	IF (Product_Category_ID IS NOT NULL) THEN
		M_Product_Category_ID := Product_Category_ID;
		DBMS_OUTPUT.PUT_LINE('  M_Product_Category_ID=' || M_Product_Category_ID);
	END IF;

	/**
	 *	For all Accounting Schema of the Category
	 */
	FOR acct IN Cur_Acct (M_Product_Category_ID) LOOP
		--	Update existing Products
		UPDATE M_Product_Acct pa
			SET P_Revenue_Acct=acct.P_Revenue_Acct, 
				P_Expense_Acct=acct.P_Expense_Acct, 
				P_Asset_Acct=acct.P_Asset_Acct, 
				P_CoGs_Acct=acct.P_CoGs_Acct, 
				P_PurchasePriceVariance_Acct=acct.P_PurchasePriceVariance_Acct,
				P_InvoicePriceVariance_Acct=acct.P_InvoicePriceVariance_Acct,
				P_TradeDiscountRec_Acct=acct.P_TradeDiscountRec_Acct,
				P_TradeDiscountGrant_Acct=acct.P_TradeDiscountGrant_Acct,
				Updated=SysDate,
				UpdatedBy=0
		WHERE pa.C_AcctSchema_ID=acct.C_AcctSchema_ID 
			AND EXISTS (SELECT * FROM M_Product p 
				WHERE p.M_Product_ID=pa.M_Product_ID 
					AND p.M_Product_Category_ID=acct.M_Product_Category_ID);
		Updated := SQL%ROWCOUNT;
		--	Insert new Products
		INSERT INTO M_Product_Acct
			(M_Product_ID, C_AcctSchema_ID,
			AD_Client_ID, AD_Org_ID, IsActive, Created, CreatedBy, Updated, UpdatedBy,
			P_Revenue_Acct, P_Expense_Acct, P_Asset_Acct, P_CoGs_Acct, 
			P_PurchasePriceVariance_Acct, P_InvoicePriceVariance_Acct,
			P_TradeDiscountRec_Acct, P_TradeDiscountGrant_Acct)
		SELECT p.M_Product_ID, acct.C_AcctSchema_ID,
			p.AD_Client_ID, p.AD_Org_ID, 'Y', SysDate, 0, SysDate, 0,
			acct.P_Revenue_Acct, acct.P_Expense_Acct, acct.P_Asset_Acct, acct.P_CoGs_Acct, 
			acct.P_PurchasePriceVariance_Acct, acct.P_InvoicePriceVariance_Acct,
			acct.P_TradeDiscountRec_Acct, acct.P_TradeDiscountGrant_Acct
		FROM	M_Product p
		WHERE	p.M_Product_Category_ID=acct.M_Product_Category_ID
			AND NOT EXISTS (SELECT * FROM M_Product_Acct pa 
				WHERE pa.M_Product_ID=p.M_Product_ID 
					AND pa.C_AcctSchema_ID=acct.C_AcctSchema_ID);
		Created := SQL%ROWCOUNT;
		DBMS_OUTPUT.PUT_LINE('Product = ' || Updated || ' / ' || Created);
		Updated_Total := Updated_Total + Updated;
		Created_Total := Created_Total + Created;
	END LOOP;
	Message := '@Created@=' || Created_Total || ', @Updated@=' || Updated_Total;


<<FINISH_PROCESS>>
	--  Update AD_PInstance
	DBMS_OUTPUT.PUT_LINE('Updating PInstance - Finished ' || Message);
    UPDATE  AD_PInstance
    SET Updated = SysDate,
        IsProcessing = 'N',
        Result = 1,                 -- success
        ErrorMsg = Message
    WHERE   AD_PInstance_ID=PInstance_ID;
    COMMIT;
    RETURN;

EXCEPTION
    WHEN  OTHERS THEN
		ResultStr := ResultStr || ': ' || SQLERRM || ' - ' || Message;
		DBMS_OUTPUT.PUT_LINE(ResultStr);
        UPDATE  AD_PInstance
        SET Updated = SysDate,
            IsProcessing = 'N',
            Result = 0,             -- failure
            ErrorMsg = ResultStr
        WHERE   AD_PInstance_ID=PInstance_ID;
        COMMIT;
        RETURN;

END M_Product_Category_Acct_Copy;
/