trayexp.asm

破解很多程序的序列号算法程序

; TrayExplorer v1.0 Key Generator
; By Mr. Wot 1998
;
; Assemble with tasm trayexp.asm, followed by tlink /t trayexp


Code Segment Byte Public
Assume	Ds:Code,Cs:Code
Org 100h
P386

Start:
	mov ah,09
	mov dx,offset Logo
	int 21h				;Display logo

	mov ah,0Ah
	mov dx,offset Input
	int 21h				;Get name

	xor edi,edi
	mov di,offset Input+2
	
	movzx eax,byte ptr [edi-01]     ;Length of name
	add eax,0000000Ch		;Plus length TrayExplorer
			
	xor edx,edx
	xor ebx,ebx
	mov edx,00000001h
	add ebx,000004E4h		;Sum ascii TrayExplorer

;the maths part

loop1:
	mov ecx,edi
	movzx ecx,byte ptr [edx+ecx-01]
	add ebx,ecx
	inc edx
	dec eax
	jnz loop1
	movzx eax,byte ptr [edi-01]     ;Length of name.
	add eax,0000000Ch		;Plus length TrayExplorer.
	imul ebx
	add eax,0002E75Ah
	lea eax,[eax*8+eax]
	sub eax,000D9CBBh               ;EAX contains serial.

	xor esi,esi
	mov si,offset Serial+9
	mov ecx,0Ah

;Output in DECIMAL

going:
	xor edx,edx
	div ecx
	add dl,30h
	cmp dl,3Ah
	jl print
	add dl,7

print:
	dec esi
	mov [esi],dl
	or eax,eax
	jnz going

	mov ah,9
	mov dx,offset Regprompt
	int 21h

	int 20h

Logo	db 13,10,'************************'
	db 13,10,'*  TrayExplorer v1.0   *'
	db 13,10,'*   By Mr. Wot 1998    *'
	db 13,10,'************************',13,10
	db 13,10,'Enter your Registration Name : $'

Regprompt db 13,10,'Your Registration Key is : '
Serial    db 0,0,0,0,0,0,0,0,0,0,13,10,24h

Input	db 18h,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0

Code ends
End Start