bracket.vtc

Unix下的MUD客户端程序

if (!depend_loaded) Load("depend");
register_file("bracket");
file_depends_on("rmtio");

MUSH ?:= alloc(5, Twtype);
UNTER ?:= alloc(5, Twtype);
MOO ?:= alloc(5, Twtype);

prefix = "#mark PREFIX";
suffix = "#mark SUFFIX";
 
func tiny_bracket(cmd / rmt) {
	sendf(rmt ? : cur_rmt,
	 "OUTPUTPREFIX %s\nOUTPUTSUFFIX %s\n%s\nOUTPUTPREFIX\nOUTPUTSUFFIX",
	 prefix, suffix, cmd);
}
MUD->bracket = .tiny_bracket;
MUSH->bracket = .tiny_bracket;
 
func unter_bracket(cmd / rmt) {
	rmt ?:= cur_rmt;
	sendf(r, "@_mark %s\n%s\n@_mark %s", prefix + 6, cmd, suffix + 6);
}
UNTER->bracket = .unter_bracket;
 
func moo_bracket(cmd / rmt) {
	sendf(rmt ? : cur_rmt, "PREFIX %s\nSUFFIX %s\n%s\nPREFIX\nSUFFIX",
	 prefix, suffix, cmd);
}
MOO->bracket = .moo_bracket;

func bracket(cmd / rmt) {
	rmt ?:= cur_rmt;
	if (!rmt || !rmt->type->bracket)
		abort();
	(*rmt->type->bracket)(cmd, rmt);
}

func get_bracketed(/ rmt) [response, line] {
	rmt ?:= cur_rmt;
	response = new_list();
	waitfor_and_suppress(prefix, rmt);
	while (strcmp(line = getline(rmt), suffix))
		add_list(response, line);
	return response;
}
 
func get_cmd_response(cmd / rmt) {
	bracket(cmd, rmt);
	return get_bracketed(rmt);
}
 
func silent_cmd(cmd / rmt) {
	bracket(cmd, rmt);
	waitfor_and_suppress(prefix, rmt);
	suppress_until(suffix, rmt);
}