misc.vtc

Unix下的MUD客户端程序

// misc.vtc: Miscellaneous commands

func Receive(s) { receive(s); }
add_cmd("receive", -1, .Receive, "/receive <line>");

func Beep(s) [n] { n = atoi(s) ? : 1; while (n-- > 0) write("\7"); }
add_cmd("beep", -1, .Beep, "/beep [<times>]");

func Echo(s) { output(s + "\n"); }
add_cmd("echo", -1, .Echo, "/echo <text>");

func Send(s) { dispatch(s); }
add_cmd("send", -1, .Send, "/send <text>");

func Parse(s) { parse(s); }
add_cmd("parse", -1, .Parse, "/parse <VTC code>");

func Quit() { quit(); }
add_cmd("quit", 0, .Quit, "/quit");

func Sh(s) {
	scroll(0, rows - 1);
	cmove(0, rows - 1);
	system(s ? : getenv("SHELL") ? : "/bin/sh");
	write("Press a key...");
	getch(INTR);
	redraw_hook();
}
add_cmd("sh", -1, .Sh, "/sh <cmd>");

func Shw(s) { echo(""); system(s ? : getenv("SHELL") ? : "/bin/sh"); }
add_cmd("shw", -1, .Shw, "/shw <cmd>");

save_hook ?:= make_hook(.save_worlds, .save_macros, .save_trigs);
default_save_file ?:= "~/.settings.vtc";
func Save(s) [fname, fp, i] {
	fname = *s ? strdup(s) : default_save_file;
	fp = fopen(fname, "w");
	if (!fp)
		return printf("Cannot open file %s: %s\n", fname, errmsg);
	default_save_file = fname;
	exec_hook(save_hook, fp);
	fclose(fp);
}
add_cmd("save", -1, .Save, "/save [<filename>]");

func save_one(funcptr, fname) [fp] {
	fp = fopen(fname, "w");
	if (!fp)
		return printf("Cannot open file %s: %s\n", fname, errmsg);
	(*funcptr)(fp);
	fclose(fp);
}

func Path(s) { load_file_path = strdup(s); }
add_cmd("path", -1, .Path, "/path <path string>");

func Version() { output(version + "\n" + DIST_VERSION + "\n"); }
add_cmd("version", 0, .Version, "/version");