configure.in

对SCSI设备 直接存取的通用库

dnl Process this file with autoconf to produce a configure script.

dnl init

AC_INIT(lib/sc_inquiry.c)
AM_INIT_AUTOMAKE(libscsi, 0.3)

# We want these before the checks, so the checks can modify their values.
test -z "$CFLAGS" && CFLAGS=-g auto_cflags=1


dnl system type

AC_CANONICAL_HOST

dnl amiga specific compile flags

AC_SUBST(MAKEINFO_FLAGS)

case $host_os
in 
	amigados*) MAKEINFO_FLAGS="--amiga"
		LDFLAGS="$LDFLAGS -noixemul";;
esac

dnl programs

AC_PROG_CC

AC_PROG_RANLIB


dnl libraries
dnl header files
dnl typedefs
dnl structures
dnl compiler characteristics

dnl AC_C_BIGENDIAN doesn't do what we want: give us a symbol we can substitue

AC_DEFUN(dlo_C_BIGENDIAN,
[AC_CACHE_CHECK(whether byte ordering is bigendian, ac_cv_c_bigendian,
[ac_cv_c_bigendian=unknown
# See if sys/param.h defines the BYTE_ORDER macro.
AC_TRY_COMPILE([#include <sys/types.h>
#include <sys/param.h>], [
#if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
 bogus endian macros
#endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
AC_TRY_COMPILE([#include <sys/types.h>
#include <sys/param.h>], [
#if BYTE_ORDER != BIG_ENDIAN
 not big endian
#endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
if test $ac_cv_c_bigendian = unknown; then
AC_TRY_RUN([main () {
  /* Are we little or big endian?  From Harbison&Steele.  */
  union
  {
    long l;
    char c[sizeof (long)];
  } u;
  u.l = 1;
  exit (u.c[sizeof (long) - 1] == 1);
}], ac_cv_c_bigendian=no, ac_cv_c_bigendian=yes)
fi])
AC_SUBST(WORDS_BIGENDIAN)
if test $ac_cv_c_bigendian = yes; then
  AC_DEFINE(WORDS_BIGENDIAN)
  WORDS_BIGENDIAN=1
else
  WORDS_BIGENDIAN=0
fi
])

dlo_C_BIGENDIAN


dnl library functions

dnl AC_REPLACE_FUNCS(strdup strerror)
AC_CHECK_FUNC(getpass, , ZIPLOCK_LDADD=getpass.o)
AC_SUBST(ZIPLOCK_LDADD)

dnl system services

dnl which interface

AC_SUBST(INTERFACE)

AC_MSG_CHECKING(which interface to use)
if test "X$INTERFACE" = "X"
then
	case $host_os
	in 
		netbsd*)   INTERFACE=netbsd; true;;
		amigados*) INTERFACE=amiga; true;;
	esac
fi
if test "X$INTERFACE" = "X"
then
   AC_MSG_ERROR([can't determine interface type])
fi
AC_MSG_RESULT($INTERFACE)


dnl output
AC_OUTPUT(Makefile lib/Makefile scsi/Makefile scsi/scsi.h examples/Makefile docs/Makefile)